git.squeep.com Git - akkoma/blob - test/web/media_proxy/media_proxy_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxyTest do
   6   use ExUnit.Case
   7   use Pleroma.Tests.Helpers
   8   import Pleroma.Web.MediaProxy
   9   alias Pleroma.Web.MediaProxy.MediaProxyController
  10
  11   clear_config([:media_proxy, :enabled])
  12   clear_config(Pleroma.Upload)
  13
  14   describe "when enabled" do
  15     setup do
  16       Pleroma.Config.put([:media_proxy, :enabled], true)
  17       :ok
  18     end
  19
  20     test "ignores invalid url" do
  21       assert url(nil) == nil
  22       assert url("") == nil
  23     end
  24
  25     test "ignores relative url" do
  26       assert url("/local") == "/local"
  27       assert url("/") == "/"
  28     end
  29
  30     test "ignores local url" do
  31       local_url = Pleroma.Web.Endpoint.url() <> "/hello"
  32       local_root = Pleroma.Web.Endpoint.url()
  33       assert url(local_url) == local_url
  34       assert url(local_root) == local_root
  35     end
  36
  37     test "encodes and decodes URL" do
  38       url = "https://pleroma.soykaf.com/static/logo.png"
  39       encoded = url(url)
  40
  41       assert String.starts_with?(
  42                encoded,
  43                Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url())
  44              )
  45
  46       assert String.ends_with?(encoded, "/logo.png")
  47
  48       assert decode_result(encoded) == url
  49     end
  50
  51     test "encodes and decodes URL without a path" do
  52       url = "https://pleroma.soykaf.com"
  53       encoded = url(url)
  54       assert decode_result(encoded) == url
  55     end
  56
  57     test "encodes and decodes URL without an extension" do
  58       url = "https://pleroma.soykaf.com/path/"
  59       encoded = url(url)
  60       assert String.ends_with?(encoded, "/path")
  61       assert decode_result(encoded) == url
  62     end
  63
  64     test "encodes and decodes URL and ignores query params for the path" do
  65       url = "https://pleroma.soykaf.com/static/logo.png?93939393939&bunny=true"
  66       encoded = url(url)
  67       assert String.ends_with?(encoded, "/logo.png")
  68       assert decode_result(encoded) == url
  69     end
  70
  71     test "validates signature" do
  72       secret_key_base = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  73
  74       on_exit(fn ->
  75         Pleroma.Config.put([Pleroma.Web.Endpoint, :secret_key_base], secret_key_base)
  76       end)
  77
  78       encoded = url("https://pleroma.social")
  79
  80       Pleroma.Config.put(
  81         [Pleroma.Web.Endpoint, :secret_key_base],
  82         "00000000000000000000000000000000000000000000000"
  83       )
  84
  85       [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  86       assert decode_url(sig, base64) == {:error, :invalid_signature}
  87     end
  88
  89     test "filename_matches preserves the encoded or decoded path" do
  90       assert MediaProxyController.filename_matches(
  91                %{"filename" => "/Hello world.jpg"},
  92                "/Hello world.jpg",
  93                "http://pleroma.social/Hello world.jpg"
  94              ) == :ok
  95
  96       assert MediaProxyController.filename_matches(
  97                %{"filename" => "/Hello%20world.jpg"},
  98                "/Hello%20world.jpg",
  99                "http://pleroma.social/Hello%20world.jpg"
 100              ) == :ok
 101
 102       assert MediaProxyController.filename_matches(
 103                %{"filename" => "/my%2Flong%2Furl%2F2019%2F07%2FS.jpg"},
 104                "/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 105                "http://pleroma.social/my%2Flong%2Furl%2F2019%2F07%2FS.jpg"
 106              ) == :ok
 107
 108       assert MediaProxyController.filename_matches(
 109                %{"filename" => "/my%2Flong%2Furl%2F2019%2F07%2FS.jp"},
 110                "/my%2Flong%2Furl%2F2019%2F07%2FS.jp",
 111                "http://pleroma.social/my%2Flong%2Furl%2F2019%2F07%2FS.jpg"
 112              ) == {:wrong_filename, "my%2Flong%2Furl%2F2019%2F07%2FS.jpg"}
 113     end
 114
 115     test "encoded url are tried to match for proxy as `conn.request_path` encodes the url" do
 116       # conn.request_path will return encoded url
 117       request_path = "/ANALYSE-DAI-_-LE-STABLECOIN-100-D%C3%89CENTRALIS%C3%89-BQ.jpg"
 118
 119       assert MediaProxyController.filename_matches(
 120                true,
 121                request_path,
 122                "https://mydomain.com/uploads/2019/07/ANALYSE-DAI-_-LE-STABLECOIN-100-DÉCENTRALISÉ-BQ.jpg"
 123              ) == :ok
 124     end
 125
 126     test "uses the configured base_url" do
 127       base_url = Pleroma.Config.get([:media_proxy, :base_url])
 128
 129       if base_url do
 130         on_exit(fn ->
 131           Pleroma.Config.put([:media_proxy, :base_url], base_url)
 132         end)
 133       end
 134
 135       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 136
 137       url = "https://pleroma.soykaf.com/static/logo.png"
 138       encoded = url(url)
 139
 140       assert String.starts_with?(encoded, Pleroma.Config.get([:media_proxy, :base_url]))
 141     end
 142
 143     # Some sites expect ASCII encoded characters in the URL to be preserved even if
 144     # unnecessary.
 145     # Issues: https://git.pleroma.social/pleroma/pleroma/issues/580
 146     #         https://git.pleroma.social/pleroma/pleroma/issues/1055
 147     test "preserve ASCII encoding" do
 148       url =
 149         "https://pleroma.com/%20/%21/%22/%23/%24/%25/%26/%27/%28/%29/%2A/%2B/%2C/%2D/%2E/%2F/%30/%31/%32/%33/%34/%35/%36/%37/%38/%39/%3A/%3B/%3C/%3D/%3E/%3F/%40/%41/%42/%43/%44/%45/%46/%47/%48/%49/%4A/%4B/%4C/%4D/%4E/%4F/%50/%51/%52/%53/%54/%55/%56/%57/%58/%59/%5A/%5B/%5C/%5D/%5E/%5F/%60/%61/%62/%63/%64/%65/%66/%67/%68/%69/%6A/%6B/%6C/%6D/%6E/%6F/%70/%71/%72/%73/%74/%75/%76/%77/%78/%79/%7A/%7B/%7C/%7D/%7E/%7F/%80/%81/%82/%83/%84/%85/%86/%87/%88/%89/%8A/%8B/%8C/%8D/%8E/%8F/%90/%91/%92/%93/%94/%95/%96/%97/%98/%99/%9A/%9B/%9C/%9D/%9E/%9F/%C2%A0/%A1/%A2/%A3/%A4/%A5/%A6/%A7/%A8/%A9/%AA/%AB/%AC/%C2%AD/%AE/%AF/%B0/%B1/%B2/%B3/%B4/%B5/%B6/%B7/%B8/%B9/%BA/%BB/%BC/%BD/%BE/%BF/%C0/%C1/%C2/%C3/%C4/%C5/%C6/%C7/%C8/%C9/%CA/%CB/%CC/%CD/%CE/%CF/%D0/%D1/%D2/%D3/%D4/%D5/%D6/%D7/%D8/%D9/%DA/%DB/%DC/%DD/%DE/%DF/%E0/%E1/%E2/%E3/%E4/%E5/%E6/%E7/%E8/%E9/%EA/%EB/%EC/%ED/%EE/%EF/%F0/%F1/%F2/%F3/%F4/%F5/%F6/%F7/%F8/%F9/%FA/%FB/%FC/%FD/%FE/%FF"
 150
 151       encoded = url(url)
 152       assert decode_result(encoded) == url
 153     end
 154
 155     # This includes unsafe/reserved characters which are not interpreted as part of the URL
 156     # and would otherwise have to be ASCII encoded. It is our role to ensure the proxied URL
 157     # is unmodified, so we are testing these characters anyway.
 158     test "preserve non-unicode characters per RFC3986" do
 159       url =
 160         "https://pleroma.com/ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890-._~:/?#[]@!$&'()*+,;=|^`{}"
 161
 162       encoded = url(url)
 163       assert decode_result(encoded) == url
 164     end
 165
 166     test "preserve unicode characters" do
 167       url = "https://ko.wikipedia.org/wiki/위키백과:대문"
 168
 169       encoded = url(url)
 170       assert decode_result(encoded) == url
 171     end
 172   end
 173
 174   describe "when disabled" do
 175     setup do
 176       enabled = Pleroma.Config.get([:media_proxy, :enabled])
 177
 178       if enabled do
 179         Pleroma.Config.put([:media_proxy, :enabled], false)
 180
 181         on_exit(fn ->
 182           Pleroma.Config.put([:media_proxy, :enabled], enabled)
 183           :ok
 184         end)
 185       end
 186
 187       :ok
 188     end
 189
 190     test "does not encode remote urls" do
 191       assert url("https://google.fr") == "https://google.fr"
 192     end
 193   end
 194
 195   defp decode_result(encoded) do
 196     [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
 197     {:ok, decoded} = decode_url(sig, base64)
 198     decoded
 199   end
 200
 201   describe "whitelist" do
 202     setup do
 203       Pleroma.Config.put([:media_proxy, :enabled], true)
 204       :ok
 205     end
 206
 207     test "mediaproxy whitelist" do
 208       Pleroma.Config.put([:media_proxy, :whitelist], ["google.com", "feld.me"])
 209       url = "https://feld.me/foo.png"
 210
 211       unencoded = url(url)
 212       assert unencoded == url
 213     end
 214
 215     test "does not change whitelisted urls" do
 216       Pleroma.Config.put([:media_proxy, :whitelist], ["mycdn.akamai.com"])
 217       Pleroma.Config.put([:media_proxy, :base_url], "https://cache.pleroma.social")
 218
 219       media_url = "https://mycdn.akamai.com"
 220
 221       url = "#{media_url}/static/logo.png"
 222       encoded = url(url)
 223
 224       assert String.starts_with?(encoded, media_url)
 225     end
 226
 227     test "ensure Pleroma.Upload base_url is always whitelisted" do
 228       media_url = "https://media.pleroma.social"
 229       Pleroma.Config.put([Pleroma.Upload, :base_url], media_url)
 230
 231       url = "#{media_url}/static/logo.png"
 232       encoded = url(url)
 233
 234       assert String.starts_with?(encoded, media_url)
 235     end
 236   end
 237 end