git.squeep.com Git - akkoma/blob - test/web/mastodon_api/status_view_test.exs

   1 defmodule Pleroma.Web.MastodonAPI.StatusViewTest do
   2   use Pleroma.DataCase
   3
   4   alias Pleroma.Web.MastodonAPI.{StatusView, AccountView}
   5   alias Pleroma.User
   6   alias Pleroma.Web.OStatus
   7   alias Pleroma.Web.CommonAPI
   8   import Pleroma.Factory
   9
  10   test "a note activity" do
  11     note = insert(:note_activity)
  12     user = User.get_cached_by_ap_id(note.data["actor"])
  13
  14     status = StatusView.render("status.json", %{activity: note})
  15
  16     created_at = (note.data["object"]["published"] || "")
  17     |> String.replace(~r/\.\d+Z/, ".000Z")
  18
  19     expected = %{
  20       id: to_string(note.id),
  21       uri: note.data["object"]["id"],
  22       url: note.data["object"]["id"],
  23       account: AccountView.render("account.json", %{user: user}),
  24       in_reply_to_id: nil,
  25       in_reply_to_account_id: nil,
  26       reblog: nil,
  27       content: HtmlSanitizeEx.basic_html(note.data["object"]["content"]),
  28       created_at: created_at,
  29       reblogs_count: 0,
  30       favourites_count: 0,
  31       reblogged: false,
  32       favourited: false,
  33       muted: false,
  34       sensitive: false,
  35       spoiler_text: note.data["object"]["summary"],
  36       visibility: "public",
  37       media_attachments: [],
  38       mentions: [],
  39       tags: [],
  40       application: %{
  41         name: "Web",
  42         website: nil
  43       },
  44       language: nil,
  45       emojis: [
  46         %{
  47           shortcode: "2hu",
  48           url: "corndog.png",
  49           static_url: "corndog.png"
  50         }
  51       ]
  52     }
  53
  54     assert status == expected
  55   end
  56
  57   test "contains mentions" do
  58     incoming = File.read!("test/fixtures/incoming_reply_mastodon.xml")
  59     # a user with this ap id might be in the cache.
  60     recipient = "https://pleroma.soykaf.com/users/lain"
  61     user = User.get_cached_by_ap_id(recipient) || insert(:user, %{ap_id: recipient})
  62
  63     # invalidate the cache
  64     User.invalidate_cache(user)
  65
  66     {:ok, [activity]} = OStatus.handle_incoming(incoming)
  67
  68     status = StatusView.render("status.json", %{activity: activity})
  69
  70     assert status.mentions == [AccountView.render("mention.json", %{user: user})]
  71   end
  72
  73   test "attachments" do
  74     object = %{
  75       "type" => "Image",
  76       "url" => [
  77         %{
  78           "mediaType" => "image/png",
  79           "href" => "someurl"
  80         }
  81       ],
  82       "uuid" => 6
  83     }
  84
  85     expected = %{
  86       id: "1638338801",
  87       type: "image",
  88       url: "someurl",
  89       remote_url: "someurl",
  90       preview_url: "someurl",
  91       text_url: "someurl"
  92     }
  93
  94     assert expected == StatusView.render("attachment.json", %{attachment: object})
  95
  96     # If theres a "id", use that instead of the generated one
  97     object = Map.put(object, "id", 2)
  98     assert %{id: "2"} = StatusView.render("attachment.json", %{attachment: object})
  99   end
 100
 101   test "a reblog" do
 102     user = insert(:user)
 103     activity = insert(:note_activity)
 104
 105     {:ok, reblog, _} = CommonAPI.repeat(activity.id, user)
 106
 107     represented = StatusView.render("status.json", %{for: user, activity: reblog})
 108
 109     assert represented[:id] == to_string(reblog.id)
 110     assert represented[:reblog][:id] == to_string(activity.id)
 111     assert represented[:emojis] == []
 112   end
 113 end