git.squeep.com Git - akkoma/blob - test/web/mastodon_api/status_view_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusViewTest do
   6   use Pleroma.DataCase
   7
   8   alias Pleroma.Web.MastodonAPI.AccountView
   9   alias Pleroma.Web.MastodonAPI.StatusView
  10   alias Pleroma.User
  11   alias Pleroma.Web.OStatus
  12   alias Pleroma.Web.CommonAPI
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Activity
  15   import Pleroma.Factory
  16   import Tesla.Mock
  17
  18   setup do
  19     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  20     :ok
  21   end
  22
  23   test "returns a temporary ap_id based user for activities missing db users" do
  24     user = insert(:user)
  25
  26     {:ok, activity} = CommonAPI.post(user, %{"status" => "Hey @shp!", "visibility" => "direct"})
  27
  28     Repo.delete(user)
  29     Cachex.clear(:user_cache)
  30
  31     %{account: ms_user} = StatusView.render("status.json", activity: activity)
  32
  33     assert ms_user.acct == "erroruser@example.com"
  34   end
  35
  36   test "tries to get a user by nickname if fetching by ap_id doesn't work" do
  37     user = insert(:user)
  38
  39     {:ok, activity} = CommonAPI.post(user, %{"status" => "Hey @shp!", "visibility" => "direct"})
  40
  41     {:ok, user} =
  42       user
  43       |> Ecto.Changeset.change(%{ap_id: "#{user.ap_id}/extension/#{user.nickname}"})
  44       |> Repo.update()
  45
  46     Cachex.clear(:user_cache)
  47
  48     result = StatusView.render("status.json", activity: activity)
  49
  50     assert result[:account][:id] == to_string(user.id)
  51   end
  52
  53   test "a note with null content" do
  54     note = insert(:note_activity)
  55
  56     data =
  57       note.data
  58       |> put_in(["object", "content"], nil)
  59
  60     note =
  61       note
  62       |> Map.put(:data, data)
  63
  64     User.get_cached_by_ap_id(note.data["actor"])
  65
  66     status = StatusView.render("status.json", %{activity: note})
  67
  68     assert status.content == ""
  69   end
  70
  71   test "a note activity" do
  72     note = insert(:note_activity)
  73     user = User.get_cached_by_ap_id(note.data["actor"])
  74
  75     status = StatusView.render("status.json", %{activity: note})
  76
  77     created_at =
  78       (note.data["object"]["published"] || "")
  79       |> String.replace(~r/\.\d+Z/, ".000Z")
  80
  81     expected = %{
  82       id: to_string(note.id),
  83       uri: note.data["object"]["id"],
  84       url: note.data["object"]["id"],
  85       account: AccountView.render("account.json", %{user: user}),
  86       in_reply_to_id: nil,
  87       in_reply_to_account_id: nil,
  88       card: nil,
  89       reblog: nil,
  90       content: HtmlSanitizeEx.basic_html(note.data["object"]["content"]),
  91       created_at: created_at,
  92       reblogs_count: 0,
  93       replies_count: 0,
  94       favourites_count: 0,
  95       reblogged: false,
  96       bookmarked: false,
  97       favourited: false,
  98       muted: false,
  99       pinned: false,
 100       sensitive: false,
 101       spoiler_text: note.data["object"]["summary"],
 102       visibility: "public",
 103       media_attachments: [],
 104       mentions: [],
 105       tags: [
 106         %{
 107           name: "#{note.data["object"]["tag"]}",
 108           url: "/tag/#{note.data["object"]["tag"]}"
 109         }
 110       ],
 111       application: %{
 112         name: "Web",
 113         website: nil
 114       },
 115       language: nil,
 116       emojis: [
 117         %{
 118           shortcode: "2hu",
 119           url: "corndog.png",
 120           static_url: "corndog.png",
 121           visible_in_picker: false
 122         }
 123       ]
 124     }
 125
 126     assert status == expected
 127   end
 128
 129   test "a reply" do
 130     note = insert(:note_activity)
 131     user = insert(:user)
 132
 133     {:ok, activity} =
 134       CommonAPI.post(user, %{"status" => "he", "in_reply_to_status_id" => note.id})
 135
 136     status = StatusView.render("status.json", %{activity: activity})
 137
 138     assert status.in_reply_to_id == to_string(note.id)
 139
 140     [status] = StatusView.render("index.json", %{activities: [activity], as: :activity})
 141
 142     assert status.in_reply_to_id == to_string(note.id)
 143   end
 144
 145   test "contains mentions" do
 146     incoming = File.read!("test/fixtures/incoming_reply_mastodon.xml")
 147     # a user with this ap id might be in the cache.
 148     recipient = "https://pleroma.soykaf.com/users/lain"
 149     user = insert(:user, %{ap_id: recipient})
 150
 151     {:ok, [activity]} = OStatus.handle_incoming(incoming)
 152
 153     status = StatusView.render("status.json", %{activity: activity})
 154
 155     actor = Repo.get_by(User, ap_id: activity.actor)
 156
 157     assert status.mentions ==
 158              Enum.map([user, actor], fn u -> AccountView.render("mention.json", %{user: u}) end)
 159   end
 160
 161   test "attachments" do
 162     object = %{
 163       "type" => "Image",
 164       "url" => [
 165         %{
 166           "mediaType" => "image/png",
 167           "href" => "someurl"
 168         }
 169       ],
 170       "uuid" => 6
 171     }
 172
 173     expected = %{
 174       id: "1638338801",
 175       type: "image",
 176       url: "someurl",
 177       remote_url: "someurl",
 178       preview_url: "someurl",
 179       text_url: "someurl",
 180       description: nil
 181     }
 182
 183     assert expected == StatusView.render("attachment.json", %{attachment: object})
 184
 185     # If theres a "id", use that instead of the generated one
 186     object = Map.put(object, "id", 2)
 187     assert %{id: "2"} = StatusView.render("attachment.json", %{attachment: object})
 188   end
 189
 190   test "a reblog" do
 191     user = insert(:user)
 192     activity = insert(:note_activity)
 193
 194     {:ok, reblog, _} = CommonAPI.repeat(activity.id, user)
 195
 196     represented = StatusView.render("status.json", %{for: user, activity: reblog})
 197
 198     assert represented[:id] == to_string(reblog.id)
 199     assert represented[:reblog][:id] == to_string(activity.id)
 200     assert represented[:emojis] == []
 201   end
 202
 203   test "a peertube video" do
 204     user = insert(:user)
 205
 206     {:ok, object} =
 207       ActivityPub.fetch_object_from_id(
 208         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 209       )
 210
 211     %Activity{} = activity = Activity.get_create_by_object_ap_id(object.data["id"])
 212
 213     represented = StatusView.render("status.json", %{for: user, activity: activity})
 214
 215     assert represented[:id] == to_string(activity.id)
 216     assert length(represented[:media_attachments]) == 1
 217   end
 218
 219   describe "build_tags/1" do
 220     test "it returns a a dictionary tags" do
 221       object_tags = [
 222         "fediverse",
 223         "mastodon",
 224         "nextcloud",
 225         %{
 226           "href" => "https://kawen.space/users/lain",
 227           "name" => "@lain@kawen.space",
 228           "type" => "Mention"
 229         }
 230       ]
 231
 232       assert StatusView.build_tags(object_tags) == [
 233                %{name: "fediverse", url: "/tag/fediverse"},
 234                %{name: "mastodon", url: "/tag/mastodon"},
 235                %{name: "nextcloud", url: "/tag/nextcloud"}
 236              ]
 237     end
 238   end
 239
 240   describe "rich media cards" do
 241     test "a rich media card without a site name renders correctly" do
 242       page_url = "http://example.com"
 243
 244       card = %{
 245         url: page_url,
 246         image: page_url <> "/example.jpg",
 247         title: "Example website"
 248       }
 249
 250       %{provider_name: "example.com"} =
 251         StatusView.render("card.json", %{page_url: page_url, rich_media: card})
 252     end
 253
 254     test "a rich media card without a site name or image renders correctly" do
 255       page_url = "http://example.com"
 256
 257       card = %{
 258         url: page_url,
 259         title: "Example website"
 260       }
 261
 262       %{provider_name: "example.com"} =
 263         StatusView.render("card.json", %{page_url: page_url, rich_media: card})
 264     end
 265
 266     test "a rich media card without an image renders correctly" do
 267       page_url = "http://example.com"
 268
 269       card = %{
 270         url: page_url,
 271         site_name: "Example site name",
 272         title: "Example website"
 273       }
 274
 275       %{provider_name: "Example site name"} =
 276         StatusView.render("card.json", %{page_url: page_url, rich_media: card})
 277     end
 278
 279     test "a rich media card with all relevant data renders correctly" do
 280       page_url = "http://example.com"
 281
 282       card = %{
 283         url: page_url,
 284         site_name: "Example site name",
 285         title: "Example website",
 286         image: page_url <> "/example.jpg",
 287         description: "Example description"
 288       }
 289
 290       %{provider_name: "Example site name"} =
 291         StatusView.render("card.json", %{page_url: page_url, rich_media: card})
 292     end
 293   end
 294 end