git.squeep.com Git - akkoma/blob - test/web/mastodon_api/search_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.SearchControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Web
  10   alias Pleroma.Web.CommonAPI
  11   import Pleroma.Factory
  12   import ExUnit.CaptureLog
  13   import Tesla.Mock
  14   import Mock
  15
  16   setup do
  17     mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  18     :ok
  19   end
  20
  21   describe ".search2" do
  22     test "it returns empty result if user or status search return undefined error", %{conn: conn} do
  23       with_mocks [
  24         {Pleroma.User, [], [search: fn _q, _o -> raise "Oops" end]},
  25         {Pleroma.Activity, [], [search: fn _u, _q, _o -> raise "Oops" end]}
  26       ] do
  27         capture_log(fn ->
  28           results =
  29             conn
  30             |> get("/api/v2/search", %{"q" => "2hu"})
  31             |> json_response(200)
  32
  33           assert results["accounts"] == []
  34           assert results["statuses"] == []
  35         end) =~
  36           "[error] Elixir.Pleroma.Web.MastodonAPI.SearchController search error: %RuntimeError{message: \"Oops\"}"
  37       end
  38     end
  39
  40     test "search", %{conn: conn} do
  41       user = insert(:user)
  42       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
  43       user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
  44
  45       {:ok, activity} = CommonAPI.post(user, %{"status" => "This is about 2hu private"})
  46
  47       {:ok, _activity} =
  48         CommonAPI.post(user, %{
  49           "status" => "This is about 2hu, but private",
  50           "visibility" => "private"
  51         })
  52
  53       {:ok, _} = CommonAPI.post(user_two, %{"status" => "This isn't"})
  54
  55       conn = get(conn, "/api/v2/search", %{"q" => "2hu #private"})
  56
  57       assert results = json_response(conn, 200)
  58
  59       [account | _] = results["accounts"]
  60       assert account["id"] == to_string(user_three.id)
  61
  62       assert results["hashtags"] == [
  63                %{"name" => "private", "url" => "#{Web.base_url()}/tag/private"}
  64              ]
  65
  66       [status] = results["statuses"]
  67       assert status["id"] == to_string(activity.id)
  68     end
  69   end
  70
  71   describe ".account_search" do
  72     test "account search", %{conn: conn} do
  73       user = insert(:user)
  74       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
  75       user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
  76
  77       results =
  78         conn
  79         |> assign(:user, user)
  80         |> get("/api/v1/accounts/search", %{"q" => "shp"})
  81         |> json_response(200)
  82
  83       result_ids = for result <- results, do: result["acct"]
  84
  85       assert user_two.nickname in result_ids
  86       assert user_three.nickname in result_ids
  87
  88       results =
  89         conn
  90         |> assign(:user, user)
  91         |> get("/api/v1/accounts/search", %{"q" => "2hu"})
  92         |> json_response(200)
  93
  94       result_ids = for result <- results, do: result["acct"]
  95
  96       assert user_three.nickname in result_ids
  97     end
  98   end
  99
 100   describe ".search" do
 101     test "it returns empty result if user or status search return undefined error", %{conn: conn} do
 102       with_mocks [
 103         {Pleroma.User, [], [search: fn _q, _o -> raise "Oops" end]},
 104         {Pleroma.Activity, [], [search: fn _u, _q, _o -> raise "Oops" end]}
 105       ] do
 106         capture_log(fn ->
 107           results =
 108             conn
 109             |> get("/api/v1/search", %{"q" => "2hu"})
 110             |> json_response(200)
 111
 112           assert results["accounts"] == []
 113           assert results["statuses"] == []
 114         end) =~
 115           "[error] Elixir.Pleroma.Web.MastodonAPI.SearchController search error: %RuntimeError{message: \"Oops\"}"
 116       end
 117     end
 118
 119     test "search", %{conn: conn} do
 120       user = insert(:user)
 121       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
 122       user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 123
 124       {:ok, activity} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 125
 126       {:ok, _activity} =
 127         CommonAPI.post(user, %{
 128           "status" => "This is about 2hu, but private",
 129           "visibility" => "private"
 130         })
 131
 132       {:ok, _} = CommonAPI.post(user_two, %{"status" => "This isn't"})
 133
 134       conn =
 135         conn
 136         |> get("/api/v1/search", %{"q" => "2hu"})
 137
 138       assert results = json_response(conn, 200)
 139
 140       [account | _] = results["accounts"]
 141       assert account["id"] == to_string(user_three.id)
 142
 143       assert results["hashtags"] == []
 144
 145       [status] = results["statuses"]
 146       assert status["id"] == to_string(activity.id)
 147     end
 148
 149     test "search fetches remote statuses", %{conn: conn} do
 150       capture_log(fn ->
 151         conn =
 152           conn
 153           |> get("/api/v1/search", %{"q" => "https://shitposter.club/notice/2827873"})
 154
 155         assert results = json_response(conn, 200)
 156
 157         [status] = results["statuses"]
 158
 159         assert status["uri"] ==
 160                  "tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment"
 161       end)
 162     end
 163
 164     test "search doesn't show statuses that it shouldn't", %{conn: conn} do
 165       {:ok, activity} =
 166         CommonAPI.post(insert(:user), %{
 167           "status" => "This is about 2hu, but private",
 168           "visibility" => "private"
 169         })
 170
 171       capture_log(fn ->
 172         conn =
 173           conn
 174           |> get("/api/v1/search", %{"q" => Object.normalize(activity).data["id"]})
 175
 176         assert results = json_response(conn, 200)
 177
 178         [] = results["statuses"]
 179       end)
 180     end
 181
 182     test "search fetches remote accounts", %{conn: conn} do
 183       user = insert(:user)
 184
 185       conn =
 186         conn
 187         |> assign(:user, user)
 188         |> get("/api/v1/search", %{"q" => "shp@social.heldscal.la", "resolve" => "true"})
 189
 190       assert results = json_response(conn, 200)
 191       [account] = results["accounts"]
 192       assert account["acct"] == "shp@social.heldscal.la"
 193     end
 194
 195     test "search doesn't fetch remote accounts if resolve is false", %{conn: conn} do
 196       conn =
 197         conn
 198         |> get("/api/v1/search", %{"q" => "shp@social.heldscal.la", "resolve" => "false"})
 199
 200       assert results = json_response(conn, 200)
 201       assert [] == results["accounts"]
 202     end
 203
 204     test "search with limit and offset", %{conn: conn} do
 205       user = insert(:user)
 206       _user_two = insert(:user, %{nickname: "shp@shitposter.club"})
 207       _user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 208
 209       {:ok, _activity1} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 210       {:ok, _activity2} = CommonAPI.post(user, %{"status" => "This is also about 2hu"})
 211
 212       result =
 213         conn
 214         |> get("/api/v1/search", %{"q" => "2hu", "limit" => 1})
 215
 216       assert results = json_response(result, 200)
 217       assert [%{"id" => activity_id1}] = results["statuses"]
 218       assert [_] = results["accounts"]
 219
 220       results =
 221         conn
 222         |> get("/api/v1/search", %{"q" => "2hu", "limit" => 1, "offset" => 1})
 223         |> json_response(200)
 224
 225       assert [%{"id" => activity_id2}] = results["statuses"]
 226       assert [] = results["accounts"]
 227
 228       assert activity_id1 != activity_id2
 229     end
 230
 231     test "search returns results only for the given type", %{conn: conn} do
 232       user = insert(:user)
 233       _user_two = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 234
 235       {:ok, _activity} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 236
 237       assert %{"statuses" => [_activity], "accounts" => [], "hashtags" => []} =
 238                conn
 239                |> get("/api/v1/search", %{"q" => "2hu", "type" => "statuses"})
 240                |> json_response(200)
 241
 242       assert %{"statuses" => [], "accounts" => [_user_two], "hashtags" => []} =
 243                conn
 244                |> get("/api/v1/search", %{"q" => "2hu", "type" => "accounts"})
 245                |> json_response(200)
 246     end
 247
 248     test "search uses account_id to filter statuses by the author", %{conn: conn} do
 249       user = insert(:user, %{nickname: "shp@shitposter.club"})
 250       user_two = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 251
 252       {:ok, activity1} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 253       {:ok, activity2} = CommonAPI.post(user_two, %{"status" => "This is also about 2hu"})
 254
 255       results =
 256         conn
 257         |> get("/api/v1/search", %{"q" => "2hu", "account_id" => user.id})
 258         |> json_response(200)
 259
 260       assert [%{"id" => activity_id1}] = results["statuses"]
 261       assert activity_id1 == activity1.id
 262       assert [_] = results["accounts"]
 263
 264       results =
 265         conn
 266         |> get("/api/v1/search", %{"q" => "2hu", "account_id" => user_two.id})
 267         |> json_response(200)
 268
 269       assert [%{"id" => activity_id2}] = results["statuses"]
 270       assert activity_id2 == activity2.id
 271     end
 272   end
 273 end