git.squeep.com Git - akkoma/blob - test/web/mastodon_api/controllers/search_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.SearchControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Web
  10   alias Pleroma.Web.CommonAPI
  11   import Pleroma.Factory
  12   import ExUnit.CaptureLog
  13   import Tesla.Mock
  14   import Mock
  15
  16   setup do
  17     mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  18     :ok
  19   end
  20
  21   describe ".search2" do
  22     test "it returns empty result if user or status search return undefined error", %{conn: conn} do
  23       with_mocks [
  24         {Pleroma.User, [], [search: fn _q, _o -> raise "Oops" end]},
  25         {Pleroma.Activity, [], [search: fn _u, _q, _o -> raise "Oops" end]}
  26       ] do
  27         capture_log(fn ->
  28           results =
  29             conn
  30             |> get("/api/v2/search", %{"q" => "2hu"})
  31             |> json_response(200)
  32
  33           assert results["accounts"] == []
  34           assert results["statuses"] == []
  35         end) =~
  36           "[error] Elixir.Pleroma.Web.MastodonAPI.SearchController search error: %RuntimeError{message: \"Oops\"}"
  37       end
  38     end
  39
  40     test "search", %{conn: conn} do
  41       user = insert(:user)
  42       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
  43       user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu 天子"})
  44
  45       {:ok, activity} = CommonAPI.post(user, %{"status" => "This is about 2hu private"})
  46
  47       {:ok, _activity} =
  48         CommonAPI.post(user, %{
  49           "status" => "This is about 2hu, but private",
  50           "visibility" => "private"
  51         })
  52
  53       {:ok, _} = CommonAPI.post(user_two, %{"status" => "This isn't"})
  54
  55       results =
  56         get(conn, "/api/v2/search", %{"q" => "2hu #private"})
  57         |> json_response(200)
  58
  59       [account | _] = results["accounts"]
  60       assert account["id"] == to_string(user_three.id)
  61
  62       assert results["hashtags"] == [
  63                %{"name" => "private", "url" => "#{Web.base_url()}/tag/private"}
  64              ]
  65
  66       [status] = results["statuses"]
  67       assert status["id"] == to_string(activity.id)
  68
  69       results =
  70         get(conn, "/api/v2/search", %{"q" => "天子"})
  71         |> json_response(200)
  72
  73       assert account["id"] == to_string(user_three.id)
  74     end
  75   end
  76
  77   describe ".account_search" do
  78     test "account search", %{conn: conn} do
  79       user = insert(:user)
  80       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
  81       user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
  82
  83       results =
  84         conn
  85         |> assign(:user, user)
  86         |> get("/api/v1/accounts/search", %{"q" => "shp"})
  87         |> json_response(200)
  88
  89       result_ids = for result <- results, do: result["acct"]
  90
  91       assert user_two.nickname in result_ids
  92       assert user_three.nickname in result_ids
  93
  94       results =
  95         conn
  96         |> assign(:user, user)
  97         |> get("/api/v1/accounts/search", %{"q" => "2hu"})
  98         |> json_response(200)
  99
 100       result_ids = for result <- results, do: result["acct"]
 101
 102       assert user_three.nickname in result_ids
 103     end
 104
 105     test "returns account if query contains a space", %{conn: conn} do
 106       user = insert(:user, %{nickname: "shp@shitposter.club"})
 107
 108       results =
 109         conn
 110         |> assign(:user, user)
 111         |> get("/api/v1/accounts/search", %{"q" => "shp@shitposter.club xxx "})
 112         |> json_response(200)
 113
 114       assert length(results) == 1
 115     end
 116   end
 117
 118   describe ".search" do
 119     test "it returns empty result if user or status search return undefined error", %{conn: conn} do
 120       with_mocks [
 121         {Pleroma.User, [], [search: fn _q, _o -> raise "Oops" end]},
 122         {Pleroma.Activity, [], [search: fn _u, _q, _o -> raise "Oops" end]}
 123       ] do
 124         capture_log(fn ->
 125           results =
 126             conn
 127             |> get("/api/v1/search", %{"q" => "2hu"})
 128             |> json_response(200)
 129
 130           assert results["accounts"] == []
 131           assert results["statuses"] == []
 132         end) =~
 133           "[error] Elixir.Pleroma.Web.MastodonAPI.SearchController search error: %RuntimeError{message: \"Oops\"}"
 134       end
 135     end
 136
 137     test "search", %{conn: conn} do
 138       user = insert(:user)
 139       user_two = insert(:user, %{nickname: "shp@shitposter.club"})
 140       user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 141
 142       {:ok, activity} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 143
 144       {:ok, _activity} =
 145         CommonAPI.post(user, %{
 146           "status" => "This is about 2hu, but private",
 147           "visibility" => "private"
 148         })
 149
 150       {:ok, _} = CommonAPI.post(user_two, %{"status" => "This isn't"})
 151
 152       conn =
 153         conn
 154         |> get("/api/v1/search", %{"q" => "2hu"})
 155
 156       assert results = json_response(conn, 200)
 157
 158       [account | _] = results["accounts"]
 159       assert account["id"] == to_string(user_three.id)
 160
 161       assert results["hashtags"] == []
 162
 163       [status] = results["statuses"]
 164       assert status["id"] == to_string(activity.id)
 165     end
 166
 167     test "search fetches remote statuses", %{conn: conn} do
 168       capture_log(fn ->
 169         conn =
 170           conn
 171           |> get("/api/v1/search", %{"q" => "https://shitposter.club/notice/2827873"})
 172
 173         assert results = json_response(conn, 200)
 174
 175         [status] = results["statuses"]
 176
 177         assert status["uri"] ==
 178                  "tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment"
 179       end)
 180     end
 181
 182     test "search doesn't show statuses that it shouldn't", %{conn: conn} do
 183       {:ok, activity} =
 184         CommonAPI.post(insert(:user), %{
 185           "status" => "This is about 2hu, but private",
 186           "visibility" => "private"
 187         })
 188
 189       capture_log(fn ->
 190         conn =
 191           conn
 192           |> get("/api/v1/search", %{"q" => Object.normalize(activity).data["id"]})
 193
 194         assert results = json_response(conn, 200)
 195
 196         [] = results["statuses"]
 197       end)
 198     end
 199
 200     test "search fetches remote accounts", %{conn: conn} do
 201       user = insert(:user)
 202
 203       conn =
 204         conn
 205         |> assign(:user, user)
 206         |> get("/api/v1/search", %{"q" => "shp@social.heldscal.la", "resolve" => "true"})
 207
 208       assert results = json_response(conn, 200)
 209       [account] = results["accounts"]
 210       assert account["acct"] == "shp@social.heldscal.la"
 211     end
 212
 213     test "search doesn't fetch remote accounts if resolve is false", %{conn: conn} do
 214       conn =
 215         conn
 216         |> get("/api/v1/search", %{"q" => "shp@social.heldscal.la", "resolve" => "false"})
 217
 218       assert results = json_response(conn, 200)
 219       assert [] == results["accounts"]
 220     end
 221
 222     test "search with limit and offset", %{conn: conn} do
 223       user = insert(:user)
 224       _user_two = insert(:user, %{nickname: "shp@shitposter.club"})
 225       _user_three = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 226
 227       {:ok, _activity1} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 228       {:ok, _activity2} = CommonAPI.post(user, %{"status" => "This is also about 2hu"})
 229
 230       result =
 231         conn
 232         |> get("/api/v1/search", %{"q" => "2hu", "limit" => 1})
 233
 234       assert results = json_response(result, 200)
 235       assert [%{"id" => activity_id1}] = results["statuses"]
 236       assert [_] = results["accounts"]
 237
 238       results =
 239         conn
 240         |> get("/api/v1/search", %{"q" => "2hu", "limit" => 1, "offset" => 1})
 241         |> json_response(200)
 242
 243       assert [%{"id" => activity_id2}] = results["statuses"]
 244       assert [] = results["accounts"]
 245
 246       assert activity_id1 != activity_id2
 247     end
 248
 249     test "search returns results only for the given type", %{conn: conn} do
 250       user = insert(:user)
 251       _user_two = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 252
 253       {:ok, _activity} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 254
 255       assert %{"statuses" => [_activity], "accounts" => [], "hashtags" => []} =
 256                conn
 257                |> get("/api/v1/search", %{"q" => "2hu", "type" => "statuses"})
 258                |> json_response(200)
 259
 260       assert %{"statuses" => [], "accounts" => [_user_two], "hashtags" => []} =
 261                conn
 262                |> get("/api/v1/search", %{"q" => "2hu", "type" => "accounts"})
 263                |> json_response(200)
 264     end
 265
 266     test "search uses account_id to filter statuses by the author", %{conn: conn} do
 267       user = insert(:user, %{nickname: "shp@shitposter.club"})
 268       user_two = insert(:user, %{nickname: "shp@heldscal.la", name: "I love 2hu"})
 269
 270       {:ok, activity1} = CommonAPI.post(user, %{"status" => "This is about 2hu"})
 271       {:ok, activity2} = CommonAPI.post(user_two, %{"status" => "This is also about 2hu"})
 272
 273       results =
 274         conn
 275         |> get("/api/v1/search", %{"q" => "2hu", "account_id" => user.id})
 276         |> json_response(200)
 277
 278       assert [%{"id" => activity_id1}] = results["statuses"]
 279       assert activity_id1 == activity1.id
 280       assert [_] = results["accounts"]
 281
 282       results =
 283         conn
 284         |> get("/api/v1/search", %{"q" => "2hu", "account_id" => user_two.id})
 285         |> json_response(200)
 286
 287       assert [%{"id" => activity_id2}] = results["statuses"]
 288       assert activity_id2 == activity2.id
 289     end
 290   end
 291 end