git.squeep.com Git - akkoma/blob - test/web/mastodon_api/controllers/account_controller/update_credentials_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.MastodonAPIController.UpdateCredentialsTest do
   6   alias Pleroma.Repo
   7   alias Pleroma.User
   8
   9   use Pleroma.Web.ConnCase
  10
  11   import Mock
  12   import Pleroma.Factory
  13
  14   setup do: clear_config([:instance, :max_account_fields])
  15
  16   describe "updating credentials" do
  17     setup do: oauth_access(["write:accounts"])
  18     setup :request_content_type
  19
  20     test "sets user settings in a generic way", %{conn: conn} do
  21       res_conn =
  22         patch(conn, "/api/v1/accounts/update_credentials", %{
  23           "pleroma_settings_store" => %{
  24             pleroma_fe: %{
  25               theme: "bla"
  26             }
  27           }
  28         })
  29
  30       assert user_data = json_response_and_validate_schema(res_conn, 200)
  31       assert user_data["pleroma"]["settings_store"] == %{"pleroma_fe" => %{"theme" => "bla"}}
  32
  33       user = Repo.get(User, user_data["id"])
  34
  35       res_conn =
  36         conn
  37         |> assign(:user, user)
  38         |> patch("/api/v1/accounts/update_credentials", %{
  39           "pleroma_settings_store" => %{
  40             masto_fe: %{
  41               theme: "bla"
  42             }
  43           }
  44         })
  45
  46       assert user_data = json_response_and_validate_schema(res_conn, 200)
  47
  48       assert user_data["pleroma"]["settings_store"] ==
  49                %{
  50                  "pleroma_fe" => %{"theme" => "bla"},
  51                  "masto_fe" => %{"theme" => "bla"}
  52                }
  53
  54       user = Repo.get(User, user_data["id"])
  55
  56       clear_config([:instance, :federating], true)
  57
  58       with_mock Pleroma.Web.Federator,
  59         publish: fn _activity -> :ok end do
  60         res_conn =
  61           conn
  62           |> assign(:user, user)
  63           |> patch("/api/v1/accounts/update_credentials", %{
  64             "pleroma_settings_store" => %{
  65               masto_fe: %{
  66                 theme: "blub"
  67               }
  68             }
  69           })
  70
  71         assert user_data = json_response_and_validate_schema(res_conn, 200)
  72
  73         assert user_data["pleroma"]["settings_store"] ==
  74                  %{
  75                    "pleroma_fe" => %{"theme" => "bla"},
  76                    "masto_fe" => %{"theme" => "blub"}
  77                  }
  78
  79         assert_called(Pleroma.Web.Federator.publish(:_))
  80       end
  81     end
  82
  83     test "updates the user's bio", %{conn: conn} do
  84       user2 = insert(:user)
  85
  86       raw_bio = "I drink #cofe with @#{user2.nickname}\n\nsuya.."
  87
  88       conn = patch(conn, "/api/v1/accounts/update_credentials", %{"note" => raw_bio})
  89
  90       assert user_data = json_response_and_validate_schema(conn, 200)
  91
  92       assert user_data["note"] ==
  93                ~s(I drink <a class="hashtag" data-tag="cofe" href="http://localhost:4001/tag/cofe">#cofe</a> with <span class="h-card"><a class="u-url mention" data-user="#{
  94                  user2.id
  95                }" href="#{user2.ap_id}" rel="ugc">@<span>#{user2.nickname}</span></a></span><br/><br/>suya..)
  96
  97       assert user_data["source"]["note"] == raw_bio
  98
  99       user = Repo.get(User, user_data["id"])
 100
 101       assert user.raw_bio == raw_bio
 102     end
 103
 104     test "updates the user's locking status", %{conn: conn} do
 105       conn = patch(conn, "/api/v1/accounts/update_credentials", %{locked: "true"})
 106
 107       assert user_data = json_response_and_validate_schema(conn, 200)
 108       assert user_data["locked"] == true
 109     end
 110
 111     test "updates the user's allow_following_move", %{user: user, conn: conn} do
 112       assert user.allow_following_move == true
 113
 114       conn = patch(conn, "/api/v1/accounts/update_credentials", %{allow_following_move: "false"})
 115
 116       assert refresh_record(user).allow_following_move == false
 117       assert user_data = json_response_and_validate_schema(conn, 200)
 118       assert user_data["pleroma"]["allow_following_move"] == false
 119     end
 120
 121     test "updates the user's default scope", %{conn: conn} do
 122       conn = patch(conn, "/api/v1/accounts/update_credentials", %{default_scope: "unlisted"})
 123
 124       assert user_data = json_response_and_validate_schema(conn, 200)
 125       assert user_data["source"]["privacy"] == "unlisted"
 126     end
 127
 128     test "updates the user's privacy", %{conn: conn} do
 129       conn = patch(conn, "/api/v1/accounts/update_credentials", %{source: %{privacy: "unlisted"}})
 130
 131       assert user_data = json_response_and_validate_schema(conn, 200)
 132       assert user_data["source"]["privacy"] == "unlisted"
 133     end
 134
 135     test "updates the user's hide_followers status", %{conn: conn} do
 136       conn = patch(conn, "/api/v1/accounts/update_credentials", %{hide_followers: "true"})
 137
 138       assert user_data = json_response_and_validate_schema(conn, 200)
 139       assert user_data["pleroma"]["hide_followers"] == true
 140     end
 141
 142     test "updates the user's discoverable status", %{conn: conn} do
 143       assert %{"source" => %{"pleroma" => %{"discoverable" => true}}} =
 144                conn
 145                |> patch("/api/v1/accounts/update_credentials", %{discoverable: "true"})
 146                |> json_response_and_validate_schema(:ok)
 147
 148       assert %{"source" => %{"pleroma" => %{"discoverable" => false}}} =
 149                conn
 150                |> patch("/api/v1/accounts/update_credentials", %{discoverable: "false"})
 151                |> json_response_and_validate_schema(:ok)
 152     end
 153
 154     test "updates the user's hide_followers_count and hide_follows_count", %{conn: conn} do
 155       conn =
 156         patch(conn, "/api/v1/accounts/update_credentials", %{
 157           hide_followers_count: "true",
 158           hide_follows_count: "true"
 159         })
 160
 161       assert user_data = json_response_and_validate_schema(conn, 200)
 162       assert user_data["pleroma"]["hide_followers_count"] == true
 163       assert user_data["pleroma"]["hide_follows_count"] == true
 164     end
 165
 166     test "updates the user's skip_thread_containment option", %{user: user, conn: conn} do
 167       response =
 168         conn
 169         |> patch("/api/v1/accounts/update_credentials", %{skip_thread_containment: "true"})
 170         |> json_response_and_validate_schema(200)
 171
 172       assert response["pleroma"]["skip_thread_containment"] == true
 173       assert refresh_record(user).skip_thread_containment
 174     end
 175
 176     test "updates the user's hide_follows status", %{conn: conn} do
 177       conn = patch(conn, "/api/v1/accounts/update_credentials", %{hide_follows: "true"})
 178
 179       assert user_data = json_response_and_validate_schema(conn, 200)
 180       assert user_data["pleroma"]["hide_follows"] == true
 181     end
 182
 183     test "updates the user's hide_favorites status", %{conn: conn} do
 184       conn = patch(conn, "/api/v1/accounts/update_credentials", %{hide_favorites: "true"})
 185
 186       assert user_data = json_response_and_validate_schema(conn, 200)
 187       assert user_data["pleroma"]["hide_favorites"] == true
 188     end
 189
 190     test "updates the user's show_role status", %{conn: conn} do
 191       conn = patch(conn, "/api/v1/accounts/update_credentials", %{show_role: "false"})
 192
 193       assert user_data = json_response_and_validate_schema(conn, 200)
 194       assert user_data["source"]["pleroma"]["show_role"] == false
 195     end
 196
 197     test "updates the user's no_rich_text status", %{conn: conn} do
 198       conn = patch(conn, "/api/v1/accounts/update_credentials", %{no_rich_text: "true"})
 199
 200       assert user_data = json_response_and_validate_schema(conn, 200)
 201       assert user_data["source"]["pleroma"]["no_rich_text"] == true
 202     end
 203
 204     test "updates the user's name", %{conn: conn} do
 205       conn =
 206         patch(conn, "/api/v1/accounts/update_credentials", %{"display_name" => "markorepairs"})
 207
 208       assert user_data = json_response_and_validate_schema(conn, 200)
 209       assert user_data["display_name"] == "markorepairs"
 210     end
 211
 212     test "updates the user's avatar", %{user: user, conn: conn} do
 213       new_avatar = %Plug.Upload{
 214         content_type: "image/jpg",
 215         path: Path.absname("test/fixtures/image.jpg"),
 216         filename: "an_image.jpg"
 217       }
 218
 219       conn = patch(conn, "/api/v1/accounts/update_credentials", %{"avatar" => new_avatar})
 220
 221       assert user_response = json_response_and_validate_schema(conn, 200)
 222       assert user_response["avatar"] != User.avatar_url(user)
 223     end
 224
 225     test "updates the user's banner", %{user: user, conn: conn} do
 226       new_header = %Plug.Upload{
 227         content_type: "image/jpg",
 228         path: Path.absname("test/fixtures/image.jpg"),
 229         filename: "an_image.jpg"
 230       }
 231
 232       conn = patch(conn, "/api/v1/accounts/update_credentials", %{"header" => new_header})
 233
 234       assert user_response = json_response_and_validate_schema(conn, 200)
 235       assert user_response["header"] != User.banner_url(user)
 236     end
 237
 238     test "updates the user's background", %{conn: conn} do
 239       new_header = %Plug.Upload{
 240         content_type: "image/jpg",
 241         path: Path.absname("test/fixtures/image.jpg"),
 242         filename: "an_image.jpg"
 243       }
 244
 245       conn =
 246         patch(conn, "/api/v1/accounts/update_credentials", %{
 247           "pleroma_background_image" => new_header
 248         })
 249
 250       assert user_response = json_response_and_validate_schema(conn, 200)
 251       assert user_response["pleroma"]["background_image"]
 252     end
 253
 254     test "requires 'write:accounts' permission" do
 255       token1 = insert(:oauth_token, scopes: ["read"])
 256       token2 = insert(:oauth_token, scopes: ["write", "follow"])
 257
 258       for token <- [token1, token2] do
 259         conn =
 260           build_conn()
 261           |> put_req_header("content-type", "multipart/form-data")
 262           |> put_req_header("authorization", "Bearer #{token.token}")
 263           |> patch("/api/v1/accounts/update_credentials", %{})
 264
 265         if token == token1 do
 266           assert %{"error" => "Insufficient permissions: write:accounts."} ==
 267                    json_response_and_validate_schema(conn, 403)
 268         else
 269           assert json_response_and_validate_schema(conn, 200)
 270         end
 271       end
 272     end
 273
 274     test "updates profile emojos", %{user: user, conn: conn} do
 275       note = "*sips :blank:*"
 276       name = "I am :firefox:"
 277
 278       ret_conn =
 279         patch(conn, "/api/v1/accounts/update_credentials", %{
 280           "note" => note,
 281           "display_name" => name
 282         })
 283
 284       assert json_response_and_validate_schema(ret_conn, 200)
 285
 286       conn = get(conn, "/api/v1/accounts/#{user.id}")
 287
 288       assert user_data = json_response_and_validate_schema(conn, 200)
 289
 290       assert user_data["note"] == note
 291       assert user_data["display_name"] == name
 292       assert [%{"shortcode" => "blank"}, %{"shortcode" => "firefox"}] = user_data["emojis"]
 293     end
 294
 295     test "update fields", %{conn: conn} do
 296       fields = [
 297         %{"name" => "<a href=\"http://google.com\">foo</a>", "value" => "<script>bar</script>"},
 298         %{"name" => "link.io", "value" => "cofe.io"}
 299       ]
 300
 301       account_data =
 302         conn
 303         |> patch("/api/v1/accounts/update_credentials", %{"fields_attributes" => fields})
 304         |> json_response_and_validate_schema(200)
 305
 306       assert account_data["fields"] == [
 307                %{"name" => "<a href=\"http://google.com\">foo</a>", "value" => "bar"},
 308                %{
 309                  "name" => "link.io",
 310                  "value" => ~S(<a href="http://cofe.io" rel="ugc">cofe.io</a>)
 311                }
 312              ]
 313
 314       assert account_data["source"]["fields"] == [
 315                %{
 316                  "name" => "<a href=\"http://google.com\">foo</a>",
 317                  "value" => "<script>bar</script>"
 318                },
 319                %{"name" => "link.io", "value" => "cofe.io"}
 320              ]
 321     end
 322
 323     test "update fields via x-www-form-urlencoded", %{conn: conn} do
 324       fields =
 325         [
 326           "fields_attributes[1][name]=link",
 327           "fields_attributes[1][value]=http://cofe.io",
 328           "fields_attributes[0][name]=foo",
 329           "fields_attributes[0][value]=bar"
 330         ]
 331         |> Enum.join("&")
 332
 333       account =
 334         conn
 335         |> put_req_header("content-type", "application/x-www-form-urlencoded")
 336         |> patch("/api/v1/accounts/update_credentials", fields)
 337         |> json_response_and_validate_schema(200)
 338
 339       assert account["fields"] == [
 340                %{"name" => "foo", "value" => "bar"},
 341                %{
 342                  "name" => "link",
 343                  "value" => ~S(<a href="http://cofe.io" rel="ugc">http://cofe.io</a>)
 344                }
 345              ]
 346
 347       assert account["source"]["fields"] == [
 348                %{"name" => "foo", "value" => "bar"},
 349                %{"name" => "link", "value" => "http://cofe.io"}
 350              ]
 351     end
 352
 353     test "update fields with empty name", %{conn: conn} do
 354       fields = [
 355         %{"name" => "foo", "value" => ""},
 356         %{"name" => "", "value" => "bar"}
 357       ]
 358
 359       account =
 360         conn
 361         |> patch("/api/v1/accounts/update_credentials", %{"fields_attributes" => fields})
 362         |> json_response_and_validate_schema(200)
 363
 364       assert account["fields"] == [
 365                %{"name" => "foo", "value" => ""}
 366              ]
 367     end
 368
 369     test "update fields when invalid request", %{conn: conn} do
 370       name_limit = Pleroma.Config.get([:instance, :account_field_name_length])
 371       value_limit = Pleroma.Config.get([:instance, :account_field_value_length])
 372
 373       long_name = Enum.map(0..name_limit, fn _ -> "x" end) |> Enum.join()
 374       long_value = Enum.map(0..value_limit, fn _ -> "x" end) |> Enum.join()
 375
 376       fields = [%{"name" => "foo", "value" => long_value}]
 377
 378       assert %{"error" => "Invalid request"} ==
 379                conn
 380                |> patch("/api/v1/accounts/update_credentials", %{"fields_attributes" => fields})
 381                |> json_response_and_validate_schema(403)
 382
 383       fields = [%{"name" => long_name, "value" => "bar"}]
 384
 385       assert %{"error" => "Invalid request"} ==
 386                conn
 387                |> patch("/api/v1/accounts/update_credentials", %{"fields_attributes" => fields})
 388                |> json_response_and_validate_schema(403)
 389
 390       Pleroma.Config.put([:instance, :max_account_fields], 1)
 391
 392       fields = [
 393         %{"name" => "foo", "value" => "bar"},
 394         %{"name" => "link", "value" => "cofe.io"}
 395       ]
 396
 397       assert %{"error" => "Invalid request"} ==
 398                conn
 399                |> patch("/api/v1/accounts/update_credentials", %{"fields_attributes" => fields})
 400                |> json_response_and_validate_schema(403)
 401     end
 402   end
 403
 404   describe "Mark account as bot" do
 405     setup do: oauth_access(["write:accounts"])
 406     setup :request_content_type
 407
 408     test "changing actor_type to Service makes account a bot", %{conn: conn} do
 409       account =
 410         conn
 411         |> patch("/api/v1/accounts/update_credentials", %{actor_type: "Service"})
 412         |> json_response_and_validate_schema(200)
 413
 414       assert account["bot"]
 415       assert account["source"]["pleroma"]["actor_type"] == "Service"
 416     end
 417
 418     test "changing actor_type to Person makes account a human", %{conn: conn} do
 419       account =
 420         conn
 421         |> patch("/api/v1/accounts/update_credentials", %{actor_type: "Person"})
 422         |> json_response_and_validate_schema(200)
 423
 424       refute account["bot"]
 425       assert account["source"]["pleroma"]["actor_type"] == "Person"
 426     end
 427
 428     test "changing actor_type to Application causes error", %{conn: conn} do
 429       response =
 430         conn
 431         |> patch("/api/v1/accounts/update_credentials", %{actor_type: "Application"})
 432         |> json_response_and_validate_schema(403)
 433
 434       assert %{"error" => "Invalid request"} == response
 435     end
 436
 437     test "changing bot field to true changes actor_type to Service", %{conn: conn} do
 438       account =
 439         conn
 440         |> patch("/api/v1/accounts/update_credentials", %{bot: "true"})
 441         |> json_response_and_validate_schema(200)
 442
 443       assert account["bot"]
 444       assert account["source"]["pleroma"]["actor_type"] == "Service"
 445     end
 446
 447     test "changing bot field to false changes actor_type to Person", %{conn: conn} do
 448       account =
 449         conn
 450         |> patch("/api/v1/accounts/update_credentials", %{bot: "false"})
 451         |> json_response_and_validate_schema(200)
 452
 453       refute account["bot"]
 454       assert account["source"]["pleroma"]["actor_type"] == "Person"
 455     end
 456
 457     test "actor_type field has a higher priority than bot", %{conn: conn} do
 458       account =
 459         conn
 460         |> patch("/api/v1/accounts/update_credentials", %{
 461           actor_type: "Person",
 462           bot: "true"
 463         })
 464         |> json_response_and_validate_schema(200)
 465
 466       refute account["bot"]
 467       assert account["source"]["pleroma"]["actor_type"] == "Person"
 468     end
 469   end
 470 end