git.squeep.com Git - akkoma/blob - test/web/instances/instances_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.InstancesTest do
   6   alias Pleroma.Instances
   7
   8   use Pleroma.DataCase
   9
  10   clear_config_all([:instance, :federation_reachability_timeout_days]) do
  11     Pleroma.Config.put([:instance, :federation_reachability_timeout_days], 1)
  12   end
  13
  14   describe "reachable?/1" do
  15     test "returns `true` for host / url with unknown reachability status" do
  16       assert Instances.reachable?("unknown.site")
  17       assert Instances.reachable?("http://unknown.site")
  18     end
  19
  20     test "returns `false` for host / url marked unreachable for at least `reachability_datetime_threshold()`" do
  21       host = "consistently-unreachable.name"
  22       Instances.set_consistently_unreachable(host)
  23
  24       refute Instances.reachable?(host)
  25       refute Instances.reachable?("http://#{host}/path")
  26     end
  27
  28     test "returns `true` for host / url marked unreachable for less than `reachability_datetime_threshold()`" do
  29       url = "http://eventually-unreachable.name/path"
  30
  31       Instances.set_unreachable(url)
  32
  33       assert Instances.reachable?(url)
  34       assert Instances.reachable?(URI.parse(url).host)
  35     end
  36
  37     test "returns true on non-binary input" do
  38       assert Instances.reachable?(nil)
  39       assert Instances.reachable?(1)
  40     end
  41   end
  42
  43   describe "filter_reachable/1" do
  44     setup do
  45       host = "consistently-unreachable.name"
  46       url1 = "http://eventually-unreachable.com/path"
  47       url2 = "http://domain.com/path"
  48
  49       Instances.set_consistently_unreachable(host)
  50       Instances.set_unreachable(url1)
  51
  52       result = Instances.filter_reachable([host, url1, url2, nil])
  53       %{result: result, url1: url1, url2: url2}
  54     end
  55
  56     test "returns a map with keys containing 'not marked consistently unreachable' elements of supplied list",
  57          %{result: result, url1: url1, url2: url2} do
  58       assert is_map(result)
  59       assert Enum.sort([url1, url2]) == result |> Map.keys() |> Enum.sort()
  60     end
  61
  62     test "returns a map with `unreachable_since` values for keys",
  63          %{result: result, url1: url1, url2: url2} do
  64       assert is_map(result)
  65       assert %NaiveDateTime{} = result[url1]
  66       assert is_nil(result[url2])
  67     end
  68
  69     test "returns an empty map for empty list or list containing no hosts / url" do
  70       assert %{} == Instances.filter_reachable([])
  71       assert %{} == Instances.filter_reachable([nil])
  72     end
  73   end
  74
  75   describe "set_reachable/1" do
  76     test "sets unreachable url or host reachable" do
  77       host = "domain.com"
  78       Instances.set_consistently_unreachable(host)
  79       refute Instances.reachable?(host)
  80
  81       Instances.set_reachable(host)
  82       assert Instances.reachable?(host)
  83     end
  84
  85     test "keeps reachable url or host reachable" do
  86       url = "https://site.name?q="
  87       assert Instances.reachable?(url)
  88
  89       Instances.set_reachable(url)
  90       assert Instances.reachable?(url)
  91     end
  92
  93     test "returns error status on non-binary input" do
  94       assert {:error, _} = Instances.set_reachable(nil)
  95       assert {:error, _} = Instances.set_reachable(1)
  96     end
  97   end
  98
  99   # Note: implementation-specific (e.g. Instance) details of set_unreachable/1
 100   # should be tested in implementation-specific tests
 101   describe "set_unreachable/1" do
 102     test "returns error status on non-binary input" do
 103       assert {:error, _} = Instances.set_unreachable(nil)
 104       assert {:error, _} = Instances.set_unreachable(1)
 105     end
 106   end
 107
 108   describe "set_consistently_unreachable/1" do
 109     test "sets reachable url or host unreachable" do
 110       url = "http://domain.com?q="
 111       assert Instances.reachable?(url)
 112
 113       Instances.set_consistently_unreachable(url)
 114       refute Instances.reachable?(url)
 115     end
 116
 117     test "keeps unreachable url or host unreachable" do
 118       host = "site.name"
 119       Instances.set_consistently_unreachable(host)
 120       refute Instances.reachable?(host)
 121
 122       Instances.set_consistently_unreachable(host)
 123       refute Instances.reachable?(host)
 124     end
 125   end
 126 end