git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   clear_config([:instance, :safe_dm_mentions])
  18   clear_config([:instance, :limit])
  19   clear_config([:instance, :max_pinned_statuses])
  20
  21   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  22     user = insert(:user)
  23     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  24
  25     [participation] = Participation.for_user(user)
  26
  27     {:ok, convo_reply} =
  28       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  29
  30     assert Visibility.is_direct?(convo_reply)
  31
  32     assert activity.data["context"] == convo_reply.data["context"]
  33   end
  34
  35   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  36     har = insert(:user)
  37     jafnhar = insert(:user)
  38     tridi = insert(:user)
  39
  40     {:ok, activity} =
  41       CommonAPI.post(har, %{
  42         "status" => "@#{jafnhar.nickname} hey",
  43         "visibility" => "direct"
  44       })
  45
  46     assert har.ap_id in activity.recipients
  47     assert jafnhar.ap_id in activity.recipients
  48
  49     [participation] = Participation.for_user(har)
  50
  51     {:ok, activity} =
  52       CommonAPI.post(har, %{
  53         "status" => "I don't really like @#{tridi.nickname}",
  54         "visibility" => "direct",
  55         "in_reply_to_status_id" => activity.id,
  56         "in_reply_to_conversation_id" => participation.id
  57       })
  58
  59     assert har.ap_id in activity.recipients
  60     assert jafnhar.ap_id in activity.recipients
  61     refute tridi.ap_id in activity.recipients
  62   end
  63
  64   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  65     har = insert(:user)
  66     jafnhar = insert(:user)
  67     tridi = insert(:user)
  68     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  69
  70     {:ok, activity} =
  71       CommonAPI.post(har, %{
  72         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  73         "visibility" => "direct"
  74       })
  75
  76     refute tridi.ap_id in activity.recipients
  77     assert jafnhar.ap_id in activity.recipients
  78   end
  79
  80   test "it de-duplicates tags" do
  81     user = insert(:user)
  82     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  83
  84     object = Object.normalize(activity)
  85
  86     assert object.data["tag"] == ["2hu"]
  87   end
  88
  89   test "it adds emoji in the object" do
  90     user = insert(:user)
  91     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  92
  93     assert Object.normalize(activity).data["emoji"]["firefox"]
  94   end
  95
  96   test "it adds emoji when updating profiles" do
  97     user = insert(:user, %{name: ":firefox:"})
  98
  99     CommonAPI.update(user)
 100     user = User.get_cached_by_ap_id(user.ap_id)
 101     [firefox] = user.info.source_data["tag"]
 102
 103     assert firefox["name"] == ":firefox:"
 104   end
 105
 106   describe "posting" do
 107     test "it supports explicit addressing" do
 108       user = insert(:user)
 109       user_two = insert(:user)
 110       user_three = insert(:user)
 111       user_four = insert(:user)
 112
 113       {:ok, activity} =
 114         CommonAPI.post(user, %{
 115           "status" =>
 116             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 117           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 118         })
 119
 120       assert user.ap_id in activity.recipients
 121       assert user_two.ap_id in activity.recipients
 122       assert user_four.ap_id in activity.recipients
 123       refute user_three.ap_id in activity.recipients
 124     end
 125
 126     test "it filters out obviously bad tags when accepting a post as HTML" do
 127       user = insert(:user)
 128
 129       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 130
 131       {:ok, activity} =
 132         CommonAPI.post(user, %{
 133           "status" => post,
 134           "content_type" => "text/html"
 135         })
 136
 137       object = Object.normalize(activity)
 138
 139       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 140     end
 141
 142     test "it filters out obviously bad tags when accepting a post as Markdown" do
 143       user = insert(:user)
 144
 145       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 146
 147       {:ok, activity} =
 148         CommonAPI.post(user, %{
 149           "status" => post,
 150           "content_type" => "text/markdown"
 151         })
 152
 153       object = Object.normalize(activity)
 154
 155       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 156     end
 157
 158     test "it does not allow replies to direct messages that are not direct messages themselves" do
 159       user = insert(:user)
 160
 161       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 162
 163       assert {:ok, _} =
 164                CommonAPI.post(user, %{
 165                  "status" => "suya..",
 166                  "visibility" => "direct",
 167                  "in_reply_to_status_id" => activity.id
 168                })
 169
 170       Enum.each(["public", "private", "unlisted"], fn visibility ->
 171         assert {:error, "The message visibility must be direct"} =
 172                  CommonAPI.post(user, %{
 173                    "status" => "suya..",
 174                    "visibility" => visibility,
 175                    "in_reply_to_status_id" => activity.id
 176                  })
 177       end)
 178     end
 179
 180     test "it allows to address a list" do
 181       user = insert(:user)
 182       {:ok, list} = Pleroma.List.create("foo", user)
 183
 184       {:ok, activity} =
 185         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 186
 187       assert activity.data["bcc"] == [list.ap_id]
 188       assert activity.recipients == [list.ap_id, user.ap_id]
 189       assert activity.data["listMessage"] == list.ap_id
 190     end
 191
 192     test "it returns error when status is empty and no attachments" do
 193       user = insert(:user)
 194
 195       assert {:error, "Cannot post an empty status without attachments"} =
 196                CommonAPI.post(user, %{"status" => ""})
 197     end
 198
 199     test "it returns error when character limit is exceeded" do
 200       Pleroma.Config.put([:instance, :limit], 5)
 201
 202       user = insert(:user)
 203
 204       assert {:error, "The status is over the character limit"} =
 205                CommonAPI.post(user, %{"status" => "foobar"})
 206     end
 207
 208     test "it can handle activities that expire" do
 209       user = insert(:user)
 210
 211       expires_at =
 212         NaiveDateTime.utc_now()
 213         |> NaiveDateTime.truncate(:second)
 214         |> NaiveDateTime.add(1_000_000, :second)
 215
 216       assert {:ok, activity} =
 217                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 218
 219       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 220       assert expiration.scheduled_at == expires_at
 221     end
 222   end
 223
 224   describe "reactions" do
 225     test "reacting to a status with an emoji" do
 226       user = insert(:user)
 227       other_user = insert(:user)
 228
 229       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 230
 231       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 232
 233       assert reaction.data["actor"] == user.ap_id
 234       assert reaction.data["content"] == "👍"
 235
 236       # TODO: test error case.
 237     end
 238
 239     test "repeating a status" do
 240       user = insert(:user)
 241       other_user = insert(:user)
 242
 243       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 244
 245       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 246     end
 247
 248     test "favoriting a status" do
 249       user = insert(:user)
 250       other_user = insert(:user)
 251
 252       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 253
 254       {:ok, %Activity{}, _} = CommonAPI.favorite(activity.id, user)
 255     end
 256
 257     test "retweeting a status twice returns an error" do
 258       user = insert(:user)
 259       other_user = insert(:user)
 260
 261       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 262       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 263       {:error, _} = CommonAPI.repeat(activity.id, user)
 264     end
 265
 266     test "favoriting a status twice returns an error" do
 267       user = insert(:user)
 268       other_user = insert(:user)
 269
 270       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 271       {:ok, %Activity{}, _object} = CommonAPI.favorite(activity.id, user)
 272       {:error, _} = CommonAPI.favorite(activity.id, user)
 273     end
 274   end
 275
 276   describe "pinned statuses" do
 277     setup do
 278       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 279
 280       user = insert(:user)
 281       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 282
 283       [user: user, activity: activity]
 284     end
 285
 286     test "pin status", %{user: user, activity: activity} do
 287       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 288
 289       id = activity.id
 290       user = refresh_record(user)
 291
 292       assert %User{info: %{pinned_activities: [^id]}} = user
 293     end
 294
 295     test "unlisted statuses can be pinned", %{user: user} do
 296       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 297       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 298     end
 299
 300     test "only self-authored can be pinned", %{activity: activity} do
 301       user = insert(:user)
 302
 303       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 304     end
 305
 306     test "max pinned statuses", %{user: user, activity: activity_one} do
 307       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 308
 309       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 310
 311       user = refresh_record(user)
 312
 313       assert {:error, "You have already pinned the maximum number of statuses"} =
 314                CommonAPI.pin(activity_two.id, user)
 315     end
 316
 317     test "unpin status", %{user: user, activity: activity} do
 318       {:ok, activity} = CommonAPI.pin(activity.id, user)
 319
 320       user = refresh_record(user)
 321
 322       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 323
 324       user = refresh_record(user)
 325
 326       assert %User{info: %{pinned_activities: []}} = user
 327     end
 328
 329     test "should unpin when deleting a status", %{user: user, activity: activity} do
 330       {:ok, activity} = CommonAPI.pin(activity.id, user)
 331
 332       user = refresh_record(user)
 333
 334       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 335
 336       user = refresh_record(user)
 337
 338       assert %User{info: %{pinned_activities: []}} = user
 339     end
 340   end
 341
 342   describe "mute tests" do
 343     setup do
 344       user = insert(:user)
 345
 346       activity = insert(:note_activity)
 347
 348       [user: user, activity: activity]
 349     end
 350
 351     test "add mute", %{user: user, activity: activity} do
 352       {:ok, _} = CommonAPI.add_mute(user, activity)
 353       assert CommonAPI.thread_muted?(user, activity)
 354     end
 355
 356     test "remove mute", %{user: user, activity: activity} do
 357       CommonAPI.add_mute(user, activity)
 358       {:ok, _} = CommonAPI.remove_mute(user, activity)
 359       refute CommonAPI.thread_muted?(user, activity)
 360     end
 361
 362     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 363       CommonAPI.add_mute(user, activity)
 364       {:error, _} = CommonAPI.add_mute(user, activity)
 365     end
 366   end
 367
 368   describe "reports" do
 369     test "creates a report" do
 370       reporter = insert(:user)
 371       target_user = insert(:user)
 372
 373       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 374
 375       reporter_ap_id = reporter.ap_id
 376       target_ap_id = target_user.ap_id
 377       activity_ap_id = activity.data["id"]
 378       comment = "foobar"
 379
 380       report_data = %{
 381         "account_id" => target_user.id,
 382         "comment" => comment,
 383         "status_ids" => [activity.id]
 384       }
 385
 386       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 387
 388       assert %Activity{
 389                actor: ^reporter_ap_id,
 390                data: %{
 391                  "type" => "Flag",
 392                  "content" => ^comment,
 393                  "object" => [^target_ap_id, ^activity_ap_id],
 394                  "state" => "open"
 395                }
 396              } = flag_activity
 397     end
 398
 399     test "updates report state" do
 400       [reporter, target_user] = insert_pair(:user)
 401       activity = insert(:note_activity, user: target_user)
 402
 403       {:ok, %Activity{id: report_id}} =
 404         CommonAPI.report(reporter, %{
 405           "account_id" => target_user.id,
 406           "comment" => "I feel offended",
 407           "status_ids" => [activity.id]
 408         })
 409
 410       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 411
 412       assert report.data["state"] == "resolved"
 413     end
 414
 415     test "does not update report state when state is unsupported" do
 416       [reporter, target_user] = insert_pair(:user)
 417       activity = insert(:note_activity, user: target_user)
 418
 419       {:ok, %Activity{id: report_id}} =
 420         CommonAPI.report(reporter, %{
 421           "account_id" => target_user.id,
 422           "comment" => "I feel offended",
 423           "status_ids" => [activity.id]
 424         })
 425
 426       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 427     end
 428   end
 429
 430   describe "reblog muting" do
 431     setup do
 432       muter = insert(:user)
 433
 434       muted = insert(:user)
 435
 436       [muter: muter, muted: muted]
 437     end
 438
 439     test "add a reblog mute", %{muter: muter, muted: muted} do
 440       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 441
 442       assert User.showing_reblogs?(muter, muted) == false
 443     end
 444
 445     test "remove a reblog mute", %{muter: muter, muted: muted} do
 446       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 447       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 448
 449       assert User.showing_reblogs?(muter, muted) == true
 450     end
 451   end
 452
 453   describe "unfollow/2" do
 454     test "also unsubscribes a user" do
 455       [follower, followed] = insert_pair(:user)
 456       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 457       {:ok, followed} = User.subscribe(follower, followed)
 458
 459       assert User.subscribed_to?(follower, followed)
 460
 461       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 462
 463       refute User.subscribed_to?(follower, followed)
 464     end
 465   end
 466
 467   describe "accept_follow_request/2" do
 468     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 469       user = insert(:user, info: %{locked: true})
 470       follower = insert(:user)
 471       follower_two = insert(:user)
 472
 473       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 474       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 475       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 476
 477       assert follow_activity.data["state"] == "pending"
 478       assert follow_activity_two.data["state"] == "pending"
 479       assert follow_activity_three.data["state"] == "pending"
 480
 481       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 482
 483       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 484       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 485       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 486     end
 487
 488     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 489       user = insert(:user, info: %{locked: true})
 490       follower = insert(:user)
 491       follower_two = insert(:user)
 492
 493       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 494       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 495       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 496
 497       assert follow_activity.data["state"] == "pending"
 498       assert follow_activity_two.data["state"] == "pending"
 499       assert follow_activity_three.data["state"] == "pending"
 500
 501       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 502
 503       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 504       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 505       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 506     end
 507   end
 508
 509   describe "vote/3" do
 510     test "does not allow to vote twice" do
 511       user = insert(:user)
 512       other_user = insert(:user)
 513
 514       {:ok, activity} =
 515         CommonAPI.post(user, %{
 516           "status" => "Am I cute?",
 517           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 518         })
 519
 520       object = Object.normalize(activity)
 521
 522       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 523
 524       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 525     end
 526   end
 527
 528   describe "listen/2" do
 529     test "returns a valid activity" do
 530       user = insert(:user)
 531
 532       {:ok, activity} =
 533         CommonAPI.listen(user, %{
 534           "title" => "lain radio episode 1",
 535           "album" => "lain radio",
 536           "artist" => "lain",
 537           "length" => 180_000
 538         })
 539
 540       object = Object.normalize(activity)
 541
 542       assert object.data["title"] == "lain radio episode 1"
 543
 544       assert Visibility.get_visibility(activity) == "public"
 545     end
 546
 547     test "respects visibility=private" do
 548       user = insert(:user)
 549
 550       {:ok, activity} =
 551         CommonAPI.listen(user, %{
 552           "title" => "lain radio episode 1",
 553           "album" => "lain radio",
 554           "artist" => "lain",
 555           "length" => 180_000,
 556           "visibility" => "private"
 557         })
 558
 559       object = Object.normalize(activity)
 560
 561       assert object.data["title"] == "lain radio episode 1"
 562
 563       assert Visibility.get_visibility(activity) == "private"
 564     end
 565   end
 566 end