git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   clear_config([:instance, :safe_dm_mentions])
  18   clear_config([:instance, :limit])
  19   clear_config([:instance, :max_pinned_statuses])
  20
  21   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  22     user = insert(:user)
  23     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  24
  25     [participation] = Participation.for_user(user)
  26
  27     {:ok, convo_reply} =
  28       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  29
  30     assert Visibility.is_direct?(convo_reply)
  31
  32     assert activity.data["context"] == convo_reply.data["context"]
  33   end
  34
  35   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  36     har = insert(:user)
  37     jafnhar = insert(:user)
  38     tridi = insert(:user)
  39
  40     {:ok, activity} =
  41       CommonAPI.post(har, %{
  42         "status" => "@#{jafnhar.nickname} hey",
  43         "visibility" => "direct"
  44       })
  45
  46     assert har.ap_id in activity.recipients
  47     assert jafnhar.ap_id in activity.recipients
  48
  49     [participation] = Participation.for_user(har)
  50
  51     {:ok, activity} =
  52       CommonAPI.post(har, %{
  53         "status" => "I don't really like @#{tridi.nickname}",
  54         "visibility" => "direct",
  55         "in_reply_to_status_id" => activity.id,
  56         "in_reply_to_conversation_id" => participation.id
  57       })
  58
  59     assert har.ap_id in activity.recipients
  60     assert jafnhar.ap_id in activity.recipients
  61     refute tridi.ap_id in activity.recipients
  62   end
  63
  64   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  65     har = insert(:user)
  66     jafnhar = insert(:user)
  67     tridi = insert(:user)
  68     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  69
  70     {:ok, activity} =
  71       CommonAPI.post(har, %{
  72         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  73         "visibility" => "direct"
  74       })
  75
  76     refute tridi.ap_id in activity.recipients
  77     assert jafnhar.ap_id in activity.recipients
  78   end
  79
  80   test "it de-duplicates tags" do
  81     user = insert(:user)
  82     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  83
  84     object = Object.normalize(activity)
  85
  86     assert object.data["tag"] == ["2hu"]
  87   end
  88
  89   test "it adds emoji in the object" do
  90     user = insert(:user)
  91     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  92
  93     assert Object.normalize(activity).data["emoji"]["firefox"]
  94   end
  95
  96   test "it adds emoji when updating profiles" do
  97     user = insert(:user, %{name: ":firefox:"})
  98
  99     CommonAPI.update(user)
 100     user = User.get_cached_by_ap_id(user.ap_id)
 101     [firefox] = user.info.source_data["tag"]
 102
 103     assert firefox["name"] == ":firefox:"
 104   end
 105
 106   describe "posting" do
 107     test "it supports explicit addressing" do
 108       user = insert(:user)
 109       user_two = insert(:user)
 110       user_three = insert(:user)
 111       user_four = insert(:user)
 112
 113       {:ok, activity} =
 114         CommonAPI.post(user, %{
 115           "status" =>
 116             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 117           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 118         })
 119
 120       assert user.ap_id in activity.recipients
 121       assert user_two.ap_id in activity.recipients
 122       assert user_four.ap_id in activity.recipients
 123       refute user_three.ap_id in activity.recipients
 124     end
 125
 126     test "it filters out obviously bad tags when accepting a post as HTML" do
 127       user = insert(:user)
 128
 129       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 130
 131       {:ok, activity} =
 132         CommonAPI.post(user, %{
 133           "status" => post,
 134           "content_type" => "text/html"
 135         })
 136
 137       object = Object.normalize(activity)
 138
 139       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 140     end
 141
 142     test "it filters out obviously bad tags when accepting a post as Markdown" do
 143       user = insert(:user)
 144
 145       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 146
 147       {:ok, activity} =
 148         CommonAPI.post(user, %{
 149           "status" => post,
 150           "content_type" => "text/markdown"
 151         })
 152
 153       object = Object.normalize(activity)
 154
 155       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 156     end
 157
 158     test "it does not allow replies to direct messages that are not direct messages themselves" do
 159       user = insert(:user)
 160
 161       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 162
 163       assert {:ok, _} =
 164                CommonAPI.post(user, %{
 165                  "status" => "suya..",
 166                  "visibility" => "direct",
 167                  "in_reply_to_status_id" => activity.id
 168                })
 169
 170       Enum.each(["public", "private", "unlisted"], fn visibility ->
 171         assert {:error, "The message visibility must be direct"} =
 172                  CommonAPI.post(user, %{
 173                    "status" => "suya..",
 174                    "visibility" => visibility,
 175                    "in_reply_to_status_id" => activity.id
 176                  })
 177       end)
 178     end
 179
 180     test "it allows to address a list" do
 181       user = insert(:user)
 182       {:ok, list} = Pleroma.List.create("foo", user)
 183
 184       {:ok, activity} =
 185         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 186
 187       assert activity.data["bcc"] == [list.ap_id]
 188       assert activity.recipients == [list.ap_id, user.ap_id]
 189       assert activity.data["listMessage"] == list.ap_id
 190     end
 191
 192     test "it returns error when status is empty and no attachments" do
 193       user = insert(:user)
 194
 195       assert {:error, "Cannot post an empty status without attachments"} =
 196                CommonAPI.post(user, %{"status" => ""})
 197     end
 198
 199     test "it returns error when character limit is exceeded" do
 200       Pleroma.Config.put([:instance, :limit], 5)
 201
 202       user = insert(:user)
 203
 204       assert {:error, "The status is over the character limit"} =
 205                CommonAPI.post(user, %{"status" => "foobar"})
 206     end
 207
 208     test "it can handle activities that expire" do
 209       user = insert(:user)
 210
 211       expires_at =
 212         NaiveDateTime.utc_now()
 213         |> NaiveDateTime.truncate(:second)
 214         |> NaiveDateTime.add(1_000_000, :second)
 215
 216       assert {:ok, activity} =
 217                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 218
 219       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 220       assert expiration.scheduled_at == expires_at
 221     end
 222   end
 223
 224   describe "reactions" do
 225     test "reacting to a status with an emoji" do
 226       user = insert(:user)
 227       other_user = insert(:user)
 228
 229       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 230
 231       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 232
 233       assert reaction.data["actor"] == user.ap_id
 234       assert reaction.data["content"] == "👍"
 235
 236       # TODO: test error case.
 237     end
 238
 239     test "unreacting to a status with an emoji" do
 240       user = insert(:user)
 241       other_user = insert(:user)
 242
 243       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 244       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 245
 246       {:ok, unreaction, _} = CommonAPI.unreact_with_emoji(activity.id, user, "👍")
 247
 248       assert unreaction.data["type"] == "Undo"
 249       assert unreaction.data["object"] == reaction.data["id"]
 250     end
 251
 252     test "repeating a status" do
 253       user = insert(:user)
 254       other_user = insert(:user)
 255
 256       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 257
 258       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 259     end
 260
 261     test "repeating a status privately" do
 262       user = insert(:user)
 263       other_user = insert(:user)
 264
 265       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 266
 267       {:ok, %Activity{} = announce_activity, _} =
 268         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 269
 270       assert Visibility.is_private?(announce_activity)
 271     end
 272
 273     test "favoriting a status" do
 274       user = insert(:user)
 275       other_user = insert(:user)
 276
 277       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 278
 279       {:ok, %Activity{}, _} = CommonAPI.favorite(activity.id, user)
 280     end
 281
 282     test "retweeting a status twice returns an error" do
 283       user = insert(:user)
 284       other_user = insert(:user)
 285
 286       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 287       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 288       {:error, _} = CommonAPI.repeat(activity.id, user)
 289     end
 290
 291     test "favoriting a status twice returns an error" do
 292       user = insert(:user)
 293       other_user = insert(:user)
 294
 295       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 296       {:ok, %Activity{}, _object} = CommonAPI.favorite(activity.id, user)
 297       {:error, _} = CommonAPI.favorite(activity.id, user)
 298     end
 299   end
 300
 301   describe "pinned statuses" do
 302     setup do
 303       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 304
 305       user = insert(:user)
 306       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 307
 308       [user: user, activity: activity]
 309     end
 310
 311     test "pin status", %{user: user, activity: activity} do
 312       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 313
 314       id = activity.id
 315       user = refresh_record(user)
 316
 317       assert %User{info: %{pinned_activities: [^id]}} = user
 318     end
 319
 320     test "unlisted statuses can be pinned", %{user: user} do
 321       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 322       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 323     end
 324
 325     test "only self-authored can be pinned", %{activity: activity} do
 326       user = insert(:user)
 327
 328       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 329     end
 330
 331     test "max pinned statuses", %{user: user, activity: activity_one} do
 332       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 333
 334       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 335
 336       user = refresh_record(user)
 337
 338       assert {:error, "You have already pinned the maximum number of statuses"} =
 339                CommonAPI.pin(activity_two.id, user)
 340     end
 341
 342     test "unpin status", %{user: user, activity: activity} do
 343       {:ok, activity} = CommonAPI.pin(activity.id, user)
 344
 345       user = refresh_record(user)
 346
 347       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 348
 349       user = refresh_record(user)
 350
 351       assert %User{info: %{pinned_activities: []}} = user
 352     end
 353
 354     test "should unpin when deleting a status", %{user: user, activity: activity} do
 355       {:ok, activity} = CommonAPI.pin(activity.id, user)
 356
 357       user = refresh_record(user)
 358
 359       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 360
 361       user = refresh_record(user)
 362
 363       assert %User{info: %{pinned_activities: []}} = user
 364     end
 365   end
 366
 367   describe "mute tests" do
 368     setup do
 369       user = insert(:user)
 370
 371       activity = insert(:note_activity)
 372
 373       [user: user, activity: activity]
 374     end
 375
 376     test "add mute", %{user: user, activity: activity} do
 377       {:ok, _} = CommonAPI.add_mute(user, activity)
 378       assert CommonAPI.thread_muted?(user, activity)
 379     end
 380
 381     test "remove mute", %{user: user, activity: activity} do
 382       CommonAPI.add_mute(user, activity)
 383       {:ok, _} = CommonAPI.remove_mute(user, activity)
 384       refute CommonAPI.thread_muted?(user, activity)
 385     end
 386
 387     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 388       CommonAPI.add_mute(user, activity)
 389       {:error, _} = CommonAPI.add_mute(user, activity)
 390     end
 391   end
 392
 393   describe "reports" do
 394     test "creates a report" do
 395       reporter = insert(:user)
 396       target_user = insert(:user)
 397
 398       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 399
 400       reporter_ap_id = reporter.ap_id
 401       target_ap_id = target_user.ap_id
 402       activity_ap_id = activity.data["id"]
 403       comment = "foobar"
 404
 405       report_data = %{
 406         "account_id" => target_user.id,
 407         "comment" => comment,
 408         "status_ids" => [activity.id]
 409       }
 410
 411       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 412
 413       assert %Activity{
 414                actor: ^reporter_ap_id,
 415                data: %{
 416                  "type" => "Flag",
 417                  "content" => ^comment,
 418                  "object" => [^target_ap_id, ^activity_ap_id],
 419                  "state" => "open"
 420                }
 421              } = flag_activity
 422     end
 423
 424     test "updates report state" do
 425       [reporter, target_user] = insert_pair(:user)
 426       activity = insert(:note_activity, user: target_user)
 427
 428       {:ok, %Activity{id: report_id}} =
 429         CommonAPI.report(reporter, %{
 430           "account_id" => target_user.id,
 431           "comment" => "I feel offended",
 432           "status_ids" => [activity.id]
 433         })
 434
 435       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 436
 437       assert report.data["state"] == "resolved"
 438     end
 439
 440     test "does not update report state when state is unsupported" do
 441       [reporter, target_user] = insert_pair(:user)
 442       activity = insert(:note_activity, user: target_user)
 443
 444       {:ok, %Activity{id: report_id}} =
 445         CommonAPI.report(reporter, %{
 446           "account_id" => target_user.id,
 447           "comment" => "I feel offended",
 448           "status_ids" => [activity.id]
 449         })
 450
 451       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 452     end
 453   end
 454
 455   describe "reblog muting" do
 456     setup do
 457       muter = insert(:user)
 458
 459       muted = insert(:user)
 460
 461       [muter: muter, muted: muted]
 462     end
 463
 464     test "add a reblog mute", %{muter: muter, muted: muted} do
 465       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 466
 467       assert User.showing_reblogs?(muter, muted) == false
 468     end
 469
 470     test "remove a reblog mute", %{muter: muter, muted: muted} do
 471       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 472       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 473
 474       assert User.showing_reblogs?(muter, muted) == true
 475     end
 476   end
 477
 478   describe "unfollow/2" do
 479     test "also unsubscribes a user" do
 480       [follower, followed] = insert_pair(:user)
 481       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 482       {:ok, followed} = User.subscribe(follower, followed)
 483
 484       assert User.subscribed_to?(follower, followed)
 485
 486       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 487
 488       refute User.subscribed_to?(follower, followed)
 489     end
 490   end
 491
 492   describe "accept_follow_request/2" do
 493     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 494       user = insert(:user, info: %{locked: true})
 495       follower = insert(:user)
 496       follower_two = insert(:user)
 497
 498       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 499       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 500       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 501
 502       assert follow_activity.data["state"] == "pending"
 503       assert follow_activity_two.data["state"] == "pending"
 504       assert follow_activity_three.data["state"] == "pending"
 505
 506       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 507
 508       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 509       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 510       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 511     end
 512
 513     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 514       user = insert(:user, info: %{locked: true})
 515       follower = insert(:user)
 516       follower_two = insert(:user)
 517
 518       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 519       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 520       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 521
 522       assert follow_activity.data["state"] == "pending"
 523       assert follow_activity_two.data["state"] == "pending"
 524       assert follow_activity_three.data["state"] == "pending"
 525
 526       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 527
 528       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 529       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 530       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 531     end
 532   end
 533
 534   describe "vote/3" do
 535     test "does not allow to vote twice" do
 536       user = insert(:user)
 537       other_user = insert(:user)
 538
 539       {:ok, activity} =
 540         CommonAPI.post(user, %{
 541           "status" => "Am I cute?",
 542           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 543         })
 544
 545       object = Object.normalize(activity)
 546
 547       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 548
 549       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 550     end
 551   end
 552
 553   describe "listen/2" do
 554     test "returns a valid activity" do
 555       user = insert(:user)
 556
 557       {:ok, activity} =
 558         CommonAPI.listen(user, %{
 559           "title" => "lain radio episode 1",
 560           "album" => "lain radio",
 561           "artist" => "lain",
 562           "length" => 180_000
 563         })
 564
 565       object = Object.normalize(activity)
 566
 567       assert object.data["title"] == "lain radio episode 1"
 568
 569       assert Visibility.get_visibility(activity) == "public"
 570     end
 571
 572     test "respects visibility=private" do
 573       user = insert(:user)
 574
 575       {:ok, activity} =
 576         CommonAPI.listen(user, %{
 577           "title" => "lain radio episode 1",
 578           "album" => "lain radio",
 579           "artist" => "lain",
 580           "length" => 180_000,
 581           "visibility" => "private"
 582         })
 583
 584       object = Object.normalize(activity)
 585
 586       assert object.data["title"] == "lain radio episode 1"
 587
 588       assert Visibility.get_visibility(activity) == "private"
 589     end
 590   end
 591 end