git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   require Pleroma.Constants
  18
  19   clear_config([:instance, :safe_dm_mentions])
  20   clear_config([:instance, :limit])
  21   clear_config([:instance, :max_pinned_statuses])
  22
  23   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  24     user = insert(:user)
  25     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  26
  27     [participation] = Participation.for_user(user)
  28
  29     {:ok, convo_reply} =
  30       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  31
  32     assert Visibility.is_direct?(convo_reply)
  33
  34     assert activity.data["context"] == convo_reply.data["context"]
  35   end
  36
  37   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  38     har = insert(:user)
  39     jafnhar = insert(:user)
  40     tridi = insert(:user)
  41
  42     {:ok, activity} =
  43       CommonAPI.post(har, %{
  44         "status" => "@#{jafnhar.nickname} hey",
  45         "visibility" => "direct"
  46       })
  47
  48     assert har.ap_id in activity.recipients
  49     assert jafnhar.ap_id in activity.recipients
  50
  51     [participation] = Participation.for_user(har)
  52
  53     {:ok, activity} =
  54       CommonAPI.post(har, %{
  55         "status" => "I don't really like @#{tridi.nickname}",
  56         "visibility" => "direct",
  57         "in_reply_to_status_id" => activity.id,
  58         "in_reply_to_conversation_id" => participation.id
  59       })
  60
  61     assert har.ap_id in activity.recipients
  62     assert jafnhar.ap_id in activity.recipients
  63     refute tridi.ap_id in activity.recipients
  64   end
  65
  66   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  67     har = insert(:user)
  68     jafnhar = insert(:user)
  69     tridi = insert(:user)
  70     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  71
  72     {:ok, activity} =
  73       CommonAPI.post(har, %{
  74         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  75         "visibility" => "direct"
  76       })
  77
  78     refute tridi.ap_id in activity.recipients
  79     assert jafnhar.ap_id in activity.recipients
  80   end
  81
  82   test "it de-duplicates tags" do
  83     user = insert(:user)
  84     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  85
  86     object = Object.normalize(activity)
  87
  88     assert object.data["tag"] == ["2hu"]
  89   end
  90
  91   test "it adds emoji in the object" do
  92     user = insert(:user)
  93     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  94
  95     assert Object.normalize(activity).data["emoji"]["firefox"]
  96   end
  97
  98   test "it adds emoji when updating profiles" do
  99     user = insert(:user, %{name: ":firefox:"})
 100
 101     {:ok, activity} = CommonAPI.update(user)
 102     user = User.get_cached_by_ap_id(user.ap_id)
 103     [firefox] = user.source_data["tag"]
 104
 105     assert firefox["name"] == ":firefox:"
 106
 107     assert Pleroma.Constants.as_public() in activity.recipients
 108   end
 109
 110   describe "posting" do
 111     test "it supports explicit addressing" do
 112       user = insert(:user)
 113       user_two = insert(:user)
 114       user_three = insert(:user)
 115       user_four = insert(:user)
 116
 117       {:ok, activity} =
 118         CommonAPI.post(user, %{
 119           "status" =>
 120             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 121           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 122         })
 123
 124       assert user.ap_id in activity.recipients
 125       assert user_two.ap_id in activity.recipients
 126       assert user_four.ap_id in activity.recipients
 127       refute user_three.ap_id in activity.recipients
 128     end
 129
 130     test "it filters out obviously bad tags when accepting a post as HTML" do
 131       user = insert(:user)
 132
 133       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 134
 135       {:ok, activity} =
 136         CommonAPI.post(user, %{
 137           "status" => post,
 138           "content_type" => "text/html"
 139         })
 140
 141       object = Object.normalize(activity)
 142
 143       assert object.data["content"] == "<p><b>2hu</b></p>alert(&#39;xss&#39;)"
 144     end
 145
 146     test "it filters out obviously bad tags when accepting a post as Markdown" do
 147       user = insert(:user)
 148
 149       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 150
 151       {:ok, activity} =
 152         CommonAPI.post(user, %{
 153           "status" => post,
 154           "content_type" => "text/markdown"
 155         })
 156
 157       object = Object.normalize(activity)
 158
 159       assert object.data["content"] == "<p><b>2hu</b></p>alert(&#39;xss&#39;)"
 160     end
 161
 162     test "it does not allow replies to direct messages that are not direct messages themselves" do
 163       user = insert(:user)
 164
 165       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 166
 167       assert {:ok, _} =
 168                CommonAPI.post(user, %{
 169                  "status" => "suya..",
 170                  "visibility" => "direct",
 171                  "in_reply_to_status_id" => activity.id
 172                })
 173
 174       Enum.each(["public", "private", "unlisted"], fn visibility ->
 175         assert {:error, "The message visibility must be direct"} =
 176                  CommonAPI.post(user, %{
 177                    "status" => "suya..",
 178                    "visibility" => visibility,
 179                    "in_reply_to_status_id" => activity.id
 180                  })
 181       end)
 182     end
 183
 184     test "it allows to address a list" do
 185       user = insert(:user)
 186       {:ok, list} = Pleroma.List.create("foo", user)
 187
 188       {:ok, activity} =
 189         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 190
 191       assert activity.data["bcc"] == [list.ap_id]
 192       assert activity.recipients == [list.ap_id, user.ap_id]
 193       assert activity.data["listMessage"] == list.ap_id
 194     end
 195
 196     test "it returns error when status is empty and no attachments" do
 197       user = insert(:user)
 198
 199       assert {:error, "Cannot post an empty status without attachments"} =
 200                CommonAPI.post(user, %{"status" => ""})
 201     end
 202
 203     test "it returns error when character limit is exceeded" do
 204       Pleroma.Config.put([:instance, :limit], 5)
 205
 206       user = insert(:user)
 207
 208       assert {:error, "The status is over the character limit"} =
 209                CommonAPI.post(user, %{"status" => "foobar"})
 210     end
 211
 212     test "it can handle activities that expire" do
 213       user = insert(:user)
 214
 215       expires_at =
 216         NaiveDateTime.utc_now()
 217         |> NaiveDateTime.truncate(:second)
 218         |> NaiveDateTime.add(1_000_000, :second)
 219
 220       assert {:ok, activity} =
 221                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 222
 223       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 224       assert expiration.scheduled_at == expires_at
 225     end
 226   end
 227
 228   describe "reactions" do
 229     test "repeating a status" do
 230       user = insert(:user)
 231       other_user = insert(:user)
 232
 233       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 234
 235       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 236     end
 237
 238     test "repeating a status privately" do
 239       user = insert(:user)
 240       other_user = insert(:user)
 241
 242       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 243
 244       {:ok, %Activity{} = announce_activity, _} =
 245         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 246
 247       assert Visibility.is_private?(announce_activity)
 248     end
 249
 250     test "favoriting a status" do
 251       user = insert(:user)
 252       other_user = insert(:user)
 253
 254       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 255
 256       {:ok, %Activity{}, _} = CommonAPI.favorite(activity.id, user)
 257     end
 258
 259     test "retweeting a status twice returns an error" do
 260       user = insert(:user)
 261       other_user = insert(:user)
 262
 263       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 264       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 265       {:error, _} = CommonAPI.repeat(activity.id, user)
 266     end
 267
 268     test "favoriting a status twice returns an error" do
 269       user = insert(:user)
 270       other_user = insert(:user)
 271
 272       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 273       {:ok, %Activity{}, _object} = CommonAPI.favorite(activity.id, user)
 274       {:error, _} = CommonAPI.favorite(activity.id, user)
 275     end
 276   end
 277
 278   describe "pinned statuses" do
 279     setup do
 280       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 281
 282       user = insert(:user)
 283       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 284
 285       [user: user, activity: activity]
 286     end
 287
 288     test "pin status", %{user: user, activity: activity} do
 289       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 290
 291       id = activity.id
 292       user = refresh_record(user)
 293
 294       assert %User{pinned_activities: [^id]} = user
 295     end
 296
 297     test "unlisted statuses can be pinned", %{user: user} do
 298       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 299       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 300     end
 301
 302     test "only self-authored can be pinned", %{activity: activity} do
 303       user = insert(:user)
 304
 305       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 306     end
 307
 308     test "max pinned statuses", %{user: user, activity: activity_one} do
 309       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 310
 311       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 312
 313       user = refresh_record(user)
 314
 315       assert {:error, "You have already pinned the maximum number of statuses"} =
 316                CommonAPI.pin(activity_two.id, user)
 317     end
 318
 319     test "unpin status", %{user: user, activity: activity} do
 320       {:ok, activity} = CommonAPI.pin(activity.id, user)
 321
 322       user = refresh_record(user)
 323
 324       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 325
 326       user = refresh_record(user)
 327
 328       assert %User{pinned_activities: []} = user
 329     end
 330
 331     test "should unpin when deleting a status", %{user: user, activity: activity} do
 332       {:ok, activity} = CommonAPI.pin(activity.id, user)
 333
 334       user = refresh_record(user)
 335
 336       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 337
 338       user = refresh_record(user)
 339
 340       assert %User{pinned_activities: []} = user
 341     end
 342   end
 343
 344   describe "mute tests" do
 345     setup do
 346       user = insert(:user)
 347
 348       activity = insert(:note_activity)
 349
 350       [user: user, activity: activity]
 351     end
 352
 353     test "add mute", %{user: user, activity: activity} do
 354       {:ok, _} = CommonAPI.add_mute(user, activity)
 355       assert CommonAPI.thread_muted?(user, activity)
 356     end
 357
 358     test "remove mute", %{user: user, activity: activity} do
 359       CommonAPI.add_mute(user, activity)
 360       {:ok, _} = CommonAPI.remove_mute(user, activity)
 361       refute CommonAPI.thread_muted?(user, activity)
 362     end
 363
 364     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 365       CommonAPI.add_mute(user, activity)
 366       {:error, _} = CommonAPI.add_mute(user, activity)
 367     end
 368   end
 369
 370   describe "reports" do
 371     test "creates a report" do
 372       reporter = insert(:user)
 373       target_user = insert(:user)
 374
 375       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 376
 377       reporter_ap_id = reporter.ap_id
 378       target_ap_id = target_user.ap_id
 379       activity_ap_id = activity.data["id"]
 380       comment = "foobar"
 381
 382       report_data = %{
 383         "account_id" => target_user.id,
 384         "comment" => comment,
 385         "status_ids" => [activity.id]
 386       }
 387
 388       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 389
 390       assert %Activity{
 391                actor: ^reporter_ap_id,
 392                data: %{
 393                  "type" => "Flag",
 394                  "content" => ^comment,
 395                  "object" => [^target_ap_id, ^activity_ap_id],
 396                  "state" => "open"
 397                }
 398              } = flag_activity
 399     end
 400
 401     test "updates report state" do
 402       [reporter, target_user] = insert_pair(:user)
 403       activity = insert(:note_activity, user: target_user)
 404
 405       {:ok, %Activity{id: report_id}} =
 406         CommonAPI.report(reporter, %{
 407           "account_id" => target_user.id,
 408           "comment" => "I feel offended",
 409           "status_ids" => [activity.id]
 410         })
 411
 412       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 413
 414       assert report.data["state"] == "resolved"
 415     end
 416
 417     test "does not update report state when state is unsupported" do
 418       [reporter, target_user] = insert_pair(:user)
 419       activity = insert(:note_activity, user: target_user)
 420
 421       {:ok, %Activity{id: report_id}} =
 422         CommonAPI.report(reporter, %{
 423           "account_id" => target_user.id,
 424           "comment" => "I feel offended",
 425           "status_ids" => [activity.id]
 426         })
 427
 428       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 429     end
 430   end
 431
 432   describe "reblog muting" do
 433     setup do
 434       muter = insert(:user)
 435
 436       muted = insert(:user)
 437
 438       [muter: muter, muted: muted]
 439     end
 440
 441     test "add a reblog mute", %{muter: muter, muted: muted} do
 442       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 443
 444       assert User.showing_reblogs?(muter, muted) == false
 445     end
 446
 447     test "remove a reblog mute", %{muter: muter, muted: muted} do
 448       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 449       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 450
 451       assert User.showing_reblogs?(muter, muted) == true
 452     end
 453   end
 454
 455   describe "unfollow/2" do
 456     test "also unsubscribes a user" do
 457       [follower, followed] = insert_pair(:user)
 458       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 459       {:ok, followed} = User.subscribe(follower, followed)
 460
 461       assert User.subscribed_to?(follower, followed)
 462
 463       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 464
 465       refute User.subscribed_to?(follower, followed)
 466     end
 467   end
 468
 469   describe "accept_follow_request/2" do
 470     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 471       user = insert(:user, locked: true)
 472       follower = insert(:user)
 473       follower_two = insert(:user)
 474
 475       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 476       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 477       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 478
 479       assert follow_activity.data["state"] == "pending"
 480       assert follow_activity_two.data["state"] == "pending"
 481       assert follow_activity_three.data["state"] == "pending"
 482
 483       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 484
 485       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 486       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 487       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 488     end
 489
 490     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 491       user = insert(:user, locked: true)
 492       follower = insert(:user)
 493       follower_two = insert(:user)
 494
 495       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 496       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 497       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 498
 499       assert follow_activity.data["state"] == "pending"
 500       assert follow_activity_two.data["state"] == "pending"
 501       assert follow_activity_three.data["state"] == "pending"
 502
 503       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 504
 505       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 506       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 507       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 508     end
 509   end
 510
 511   describe "vote/3" do
 512     test "does not allow to vote twice" do
 513       user = insert(:user)
 514       other_user = insert(:user)
 515
 516       {:ok, activity} =
 517         CommonAPI.post(user, %{
 518           "status" => "Am I cute?",
 519           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 520         })
 521
 522       object = Object.normalize(activity)
 523
 524       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 525
 526       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 527     end
 528   end
 529
 530   describe "listen/2" do
 531     test "returns a valid activity" do
 532       user = insert(:user)
 533
 534       {:ok, activity} =
 535         CommonAPI.listen(user, %{
 536           "title" => "lain radio episode 1",
 537           "album" => "lain radio",
 538           "artist" => "lain",
 539           "length" => 180_000
 540         })
 541
 542       object = Object.normalize(activity)
 543
 544       assert object.data["title"] == "lain radio episode 1"
 545
 546       assert Visibility.get_visibility(activity) == "public"
 547     end
 548
 549     test "respects visibility=private" do
 550       user = insert(:user)
 551
 552       {:ok, activity} =
 553         CommonAPI.listen(user, %{
 554           "title" => "lain radio episode 1",
 555           "album" => "lain radio",
 556           "artist" => "lain",
 557           "length" => 180_000,
 558           "visibility" => "private"
 559         })
 560
 561       object = Object.normalize(activity)
 562
 563       assert object.data["title"] == "lain radio episode 1"
 564
 565       assert Visibility.get_visibility(activity) == "private"
 566     end
 567   end
 568 end