git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   clear_config([:instance, :safe_dm_mentions])
  18   clear_config([:instance, :limit])
  19   clear_config([:instance, :max_pinned_statuses])
  20
  21   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  22     user = insert(:user)
  23     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  24
  25     [participation] = Participation.for_user(user)
  26
  27     {:ok, convo_reply} =
  28       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  29
  30     assert Visibility.is_direct?(convo_reply)
  31
  32     assert activity.data["context"] == convo_reply.data["context"]
  33   end
  34
  35   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  36     har = insert(:user)
  37     jafnhar = insert(:user)
  38     tridi = insert(:user)
  39
  40     {:ok, activity} =
  41       CommonAPI.post(har, %{
  42         "status" => "@#{jafnhar.nickname} hey",
  43         "visibility" => "direct"
  44       })
  45
  46     assert har.ap_id in activity.recipients
  47     assert jafnhar.ap_id in activity.recipients
  48
  49     [participation] = Participation.for_user(har)
  50
  51     {:ok, activity} =
  52       CommonAPI.post(har, %{
  53         "status" => "I don't really like @#{tridi.nickname}",
  54         "visibility" => "direct",
  55         "in_reply_to_status_id" => activity.id,
  56         "in_reply_to_conversation_id" => participation.id
  57       })
  58
  59     assert har.ap_id in activity.recipients
  60     assert jafnhar.ap_id in activity.recipients
  61     refute tridi.ap_id in activity.recipients
  62   end
  63
  64   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  65     har = insert(:user)
  66     jafnhar = insert(:user)
  67     tridi = insert(:user)
  68     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  69
  70     {:ok, activity} =
  71       CommonAPI.post(har, %{
  72         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  73         "visibility" => "direct"
  74       })
  75
  76     refute tridi.ap_id in activity.recipients
  77     assert jafnhar.ap_id in activity.recipients
  78   end
  79
  80   test "it de-duplicates tags" do
  81     user = insert(:user)
  82     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  83
  84     object = Object.normalize(activity)
  85
  86     assert object.data["tag"] == ["2hu"]
  87   end
  88
  89   test "it adds emoji in the object" do
  90     user = insert(:user)
  91     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  92
  93     assert Object.normalize(activity).data["emoji"]["firefox"]
  94   end
  95
  96   test "it adds emoji when updating profiles" do
  97     user = insert(:user, %{name: ":firefox:"})
  98
  99     CommonAPI.update(user)
 100     user = User.get_cached_by_ap_id(user.ap_id)
 101     [firefox] = user.info.source_data["tag"]
 102
 103     assert firefox["name"] == ":firefox:"
 104   end
 105
 106   describe "posting" do
 107     test "it supports explicit addressing" do
 108       user = insert(:user)
 109       user_two = insert(:user)
 110       user_three = insert(:user)
 111       user_four = insert(:user)
 112
 113       {:ok, activity} =
 114         CommonAPI.post(user, %{
 115           "status" =>
 116             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 117           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 118         })
 119
 120       assert user.ap_id in activity.recipients
 121       assert user_two.ap_id in activity.recipients
 122       assert user_four.ap_id in activity.recipients
 123       refute user_three.ap_id in activity.recipients
 124     end
 125
 126     test "it filters out obviously bad tags when accepting a post as HTML" do
 127       user = insert(:user)
 128
 129       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 130
 131       {:ok, activity} =
 132         CommonAPI.post(user, %{
 133           "status" => post,
 134           "content_type" => "text/html"
 135         })
 136
 137       object = Object.normalize(activity)
 138
 139       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 140     end
 141
 142     test "it filters out obviously bad tags when accepting a post as Markdown" do
 143       user = insert(:user)
 144
 145       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 146
 147       {:ok, activity} =
 148         CommonAPI.post(user, %{
 149           "status" => post,
 150           "content_type" => "text/markdown"
 151         })
 152
 153       object = Object.normalize(activity)
 154
 155       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 156     end
 157
 158     test "it does not allow replies to direct messages that are not direct messages themselves" do
 159       user = insert(:user)
 160
 161       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 162
 163       assert {:ok, _} =
 164                CommonAPI.post(user, %{
 165                  "status" => "suya..",
 166                  "visibility" => "direct",
 167                  "in_reply_to_status_id" => activity.id
 168                })
 169
 170       Enum.each(["public", "private", "unlisted"], fn visibility ->
 171         assert {:error, "The message visibility must be direct"} =
 172                  CommonAPI.post(user, %{
 173                    "status" => "suya..",
 174                    "visibility" => visibility,
 175                    "in_reply_to_status_id" => activity.id
 176                  })
 177       end)
 178     end
 179
 180     test "it allows to address a list" do
 181       user = insert(:user)
 182       {:ok, list} = Pleroma.List.create("foo", user)
 183
 184       {:ok, activity} =
 185         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 186
 187       assert activity.data["bcc"] == [list.ap_id]
 188       assert activity.recipients == [list.ap_id, user.ap_id]
 189       assert activity.data["listMessage"] == list.ap_id
 190     end
 191
 192     test "it returns error when status is empty and no attachments" do
 193       user = insert(:user)
 194
 195       assert {:error, "Cannot post an empty status without attachments"} =
 196                CommonAPI.post(user, %{"status" => ""})
 197     end
 198
 199     test "it returns error when character limit is exceeded" do
 200       Pleroma.Config.put([:instance, :limit], 5)
 201
 202       user = insert(:user)
 203
 204       assert {:error, "The status is over the character limit"} =
 205                CommonAPI.post(user, %{"status" => "foobar"})
 206     end
 207
 208     test "it can handle activities that expire" do
 209       user = insert(:user)
 210
 211       expires_at =
 212         NaiveDateTime.utc_now()
 213         |> NaiveDateTime.truncate(:second)
 214         |> NaiveDateTime.add(1_000_000, :second)
 215
 216       assert {:ok, activity} =
 217                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 218
 219       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 220       assert expiration.scheduled_at == expires_at
 221     end
 222   end
 223
 224   describe "reactions" do
 225     test "repeating a status" do
 226       user = insert(:user)
 227       other_user = insert(:user)
 228
 229       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 230
 231       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 232     end
 233
 234     test "repeating a status privately" do
 235       user = insert(:user)
 236       other_user = insert(:user)
 237
 238       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 239
 240       {:ok, %Activity{} = announce_activity, _} =
 241         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 242
 243       assert Visibility.is_private?(announce_activity)
 244     end
 245
 246     test "favoriting a status" do
 247       user = insert(:user)
 248       other_user = insert(:user)
 249
 250       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 251
 252       {:ok, %Activity{}, _} = CommonAPI.favorite(activity.id, user)
 253     end
 254
 255     test "retweeting a status twice returns an error" do
 256       user = insert(:user)
 257       other_user = insert(:user)
 258
 259       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 260       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 261       {:error, _} = CommonAPI.repeat(activity.id, user)
 262     end
 263
 264     test "favoriting a status twice returns an error" do
 265       user = insert(:user)
 266       other_user = insert(:user)
 267
 268       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 269       {:ok, %Activity{}, _object} = CommonAPI.favorite(activity.id, user)
 270       {:error, _} = CommonAPI.favorite(activity.id, user)
 271     end
 272   end
 273
 274   describe "pinned statuses" do
 275     setup do
 276       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 277
 278       user = insert(:user)
 279       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 280
 281       [user: user, activity: activity]
 282     end
 283
 284     test "pin status", %{user: user, activity: activity} do
 285       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 286
 287       id = activity.id
 288       user = refresh_record(user)
 289
 290       assert %User{info: %{pinned_activities: [^id]}} = user
 291     end
 292
 293     test "unlisted statuses can be pinned", %{user: user} do
 294       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 295       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 296     end
 297
 298     test "only self-authored can be pinned", %{activity: activity} do
 299       user = insert(:user)
 300
 301       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 302     end
 303
 304     test "max pinned statuses", %{user: user, activity: activity_one} do
 305       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 306
 307       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 308
 309       user = refresh_record(user)
 310
 311       assert {:error, "You have already pinned the maximum number of statuses"} =
 312                CommonAPI.pin(activity_two.id, user)
 313     end
 314
 315     test "unpin status", %{user: user, activity: activity} do
 316       {:ok, activity} = CommonAPI.pin(activity.id, user)
 317
 318       user = refresh_record(user)
 319
 320       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 321
 322       user = refresh_record(user)
 323
 324       assert %User{info: %{pinned_activities: []}} = user
 325     end
 326
 327     test "should unpin when deleting a status", %{user: user, activity: activity} do
 328       {:ok, activity} = CommonAPI.pin(activity.id, user)
 329
 330       user = refresh_record(user)
 331
 332       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 333
 334       user = refresh_record(user)
 335
 336       assert %User{info: %{pinned_activities: []}} = user
 337     end
 338   end
 339
 340   describe "mute tests" do
 341     setup do
 342       user = insert(:user)
 343
 344       activity = insert(:note_activity)
 345
 346       [user: user, activity: activity]
 347     end
 348
 349     test "add mute", %{user: user, activity: activity} do
 350       {:ok, _} = CommonAPI.add_mute(user, activity)
 351       assert CommonAPI.thread_muted?(user, activity)
 352     end
 353
 354     test "remove mute", %{user: user, activity: activity} do
 355       CommonAPI.add_mute(user, activity)
 356       {:ok, _} = CommonAPI.remove_mute(user, activity)
 357       refute CommonAPI.thread_muted?(user, activity)
 358     end
 359
 360     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 361       CommonAPI.add_mute(user, activity)
 362       {:error, _} = CommonAPI.add_mute(user, activity)
 363     end
 364   end
 365
 366   describe "reports" do
 367     test "creates a report" do
 368       reporter = insert(:user)
 369       target_user = insert(:user)
 370
 371       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 372
 373       reporter_ap_id = reporter.ap_id
 374       target_ap_id = target_user.ap_id
 375       activity_ap_id = activity.data["id"]
 376       comment = "foobar"
 377
 378       report_data = %{
 379         "account_id" => target_user.id,
 380         "comment" => comment,
 381         "status_ids" => [activity.id]
 382       }
 383
 384       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 385
 386       assert %Activity{
 387                actor: ^reporter_ap_id,
 388                data: %{
 389                  "type" => "Flag",
 390                  "content" => ^comment,
 391                  "object" => [^target_ap_id, ^activity_ap_id],
 392                  "state" => "open"
 393                }
 394              } = flag_activity
 395     end
 396
 397     test "updates report state" do
 398       [reporter, target_user] = insert_pair(:user)
 399       activity = insert(:note_activity, user: target_user)
 400
 401       {:ok, %Activity{id: report_id}} =
 402         CommonAPI.report(reporter, %{
 403           "account_id" => target_user.id,
 404           "comment" => "I feel offended",
 405           "status_ids" => [activity.id]
 406         })
 407
 408       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 409
 410       assert report.data["state"] == "resolved"
 411     end
 412
 413     test "does not update report state when state is unsupported" do
 414       [reporter, target_user] = insert_pair(:user)
 415       activity = insert(:note_activity, user: target_user)
 416
 417       {:ok, %Activity{id: report_id}} =
 418         CommonAPI.report(reporter, %{
 419           "account_id" => target_user.id,
 420           "comment" => "I feel offended",
 421           "status_ids" => [activity.id]
 422         })
 423
 424       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 425     end
 426   end
 427
 428   describe "reblog muting" do
 429     setup do
 430       muter = insert(:user)
 431
 432       muted = insert(:user)
 433
 434       [muter: muter, muted: muted]
 435     end
 436
 437     test "add a reblog mute", %{muter: muter, muted: muted} do
 438       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 439
 440       assert User.showing_reblogs?(muter, muted) == false
 441     end
 442
 443     test "remove a reblog mute", %{muter: muter, muted: muted} do
 444       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 445       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 446
 447       assert User.showing_reblogs?(muter, muted) == true
 448     end
 449   end
 450
 451   describe "unfollow/2" do
 452     test "also unsubscribes a user" do
 453       [follower, followed] = insert_pair(:user)
 454       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 455       {:ok, followed} = User.subscribe(follower, followed)
 456
 457       assert User.subscribed_to?(follower, followed)
 458
 459       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 460
 461       refute User.subscribed_to?(follower, followed)
 462     end
 463   end
 464
 465   describe "accept_follow_request/2" do
 466     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 467       user = insert(:user, info: %{locked: true})
 468       follower = insert(:user)
 469       follower_two = insert(:user)
 470
 471       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 472       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 473       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 474
 475       assert follow_activity.data["state"] == "pending"
 476       assert follow_activity_two.data["state"] == "pending"
 477       assert follow_activity_three.data["state"] == "pending"
 478
 479       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 480
 481       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 482       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 483       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 484     end
 485
 486     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 487       user = insert(:user, info: %{locked: true})
 488       follower = insert(:user)
 489       follower_two = insert(:user)
 490
 491       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 492       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 493       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 494
 495       assert follow_activity.data["state"] == "pending"
 496       assert follow_activity_two.data["state"] == "pending"
 497       assert follow_activity_three.data["state"] == "pending"
 498
 499       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 500
 501       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 502       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 503       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 504     end
 505   end
 506
 507   describe "vote/3" do
 508     test "does not allow to vote twice" do
 509       user = insert(:user)
 510       other_user = insert(:user)
 511
 512       {:ok, activity} =
 513         CommonAPI.post(user, %{
 514           "status" => "Am I cute?",
 515           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 516         })
 517
 518       object = Object.normalize(activity)
 519
 520       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 521
 522       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 523     end
 524   end
 525
 526   describe "listen/2" do
 527     test "returns a valid activity" do
 528       user = insert(:user)
 529
 530       {:ok, activity} =
 531         CommonAPI.listen(user, %{
 532           "title" => "lain radio episode 1",
 533           "album" => "lain radio",
 534           "artist" => "lain",
 535           "length" => 180_000
 536         })
 537
 538       object = Object.normalize(activity)
 539
 540       assert object.data["title"] == "lain radio episode 1"
 541
 542       assert Visibility.get_visibility(activity) == "public"
 543     end
 544
 545     test "respects visibility=private" do
 546       user = insert(:user)
 547
 548       {:ok, activity} =
 549         CommonAPI.listen(user, %{
 550           "title" => "lain radio episode 1",
 551           "album" => "lain radio",
 552           "artist" => "lain",
 553           "length" => 180_000,
 554           "visibility" => "private"
 555         })
 556
 557       object = Object.normalize(activity)
 558
 559       assert object.data["title"] == "lain radio episode 1"
 560
 561       assert Visibility.get_visibility(activity) == "private"
 562     end
 563   end
 564 end