git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   require Pleroma.Constants
  18
  19   clear_config([:instance, :safe_dm_mentions])
  20   clear_config([:instance, :limit])
  21   clear_config([:instance, :max_pinned_statuses])
  22
  23   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  24     user = insert(:user)
  25     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  26
  27     [participation] = Participation.for_user(user)
  28
  29     {:ok, convo_reply} =
  30       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  31
  32     assert Visibility.is_direct?(convo_reply)
  33
  34     assert activity.data["context"] == convo_reply.data["context"]
  35   end
  36
  37   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  38     har = insert(:user)
  39     jafnhar = insert(:user)
  40     tridi = insert(:user)
  41
  42     {:ok, activity} =
  43       CommonAPI.post(har, %{
  44         "status" => "@#{jafnhar.nickname} hey",
  45         "visibility" => "direct"
  46       })
  47
  48     assert har.ap_id in activity.recipients
  49     assert jafnhar.ap_id in activity.recipients
  50
  51     [participation] = Participation.for_user(har)
  52
  53     {:ok, activity} =
  54       CommonAPI.post(har, %{
  55         "status" => "I don't really like @#{tridi.nickname}",
  56         "visibility" => "direct",
  57         "in_reply_to_status_id" => activity.id,
  58         "in_reply_to_conversation_id" => participation.id
  59       })
  60
  61     assert har.ap_id in activity.recipients
  62     assert jafnhar.ap_id in activity.recipients
  63     refute tridi.ap_id in activity.recipients
  64   end
  65
  66   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  67     har = insert(:user)
  68     jafnhar = insert(:user)
  69     tridi = insert(:user)
  70     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  71
  72     {:ok, activity} =
  73       CommonAPI.post(har, %{
  74         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  75         "visibility" => "direct"
  76       })
  77
  78     refute tridi.ap_id in activity.recipients
  79     assert jafnhar.ap_id in activity.recipients
  80   end
  81
  82   test "it de-duplicates tags" do
  83     user = insert(:user)
  84     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  85
  86     object = Object.normalize(activity)
  87
  88     assert object.data["tag"] == ["2hu"]
  89   end
  90
  91   test "it adds emoji in the object" do
  92     user = insert(:user)
  93     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  94
  95     assert Object.normalize(activity).data["emoji"]["firefox"]
  96   end
  97
  98   test "it adds emoji when updating profiles" do
  99     user = insert(:user, %{name: ":firefox:"})
 100
 101     {:ok, activity} = CommonAPI.update(user)
 102     user = User.get_cached_by_ap_id(user.ap_id)
 103     [firefox] = user.info.source_data["tag"]
 104
 105     assert firefox["name"] == ":firefox:"
 106
 107     assert Pleroma.Constants.as_public() in activity.recipients
 108   end
 109
 110   describe "posting" do
 111     test "it supports explicit addressing" do
 112       user = insert(:user)
 113       user_two = insert(:user)
 114       user_three = insert(:user)
 115       user_four = insert(:user)
 116
 117       {:ok, activity} =
 118         CommonAPI.post(user, %{
 119           "status" =>
 120             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 121           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 122         })
 123
 124       assert user.ap_id in activity.recipients
 125       assert user_two.ap_id in activity.recipients
 126       assert user_four.ap_id in activity.recipients
 127       refute user_three.ap_id in activity.recipients
 128     end
 129
 130     test "it filters out obviously bad tags when accepting a post as HTML" do
 131       user = insert(:user)
 132
 133       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 134
 135       {:ok, activity} =
 136         CommonAPI.post(user, %{
 137           "status" => post,
 138           "content_type" => "text/html"
 139         })
 140
 141       object = Object.normalize(activity)
 142
 143       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 144     end
 145
 146     test "it filters out obviously bad tags when accepting a post as Markdown" do
 147       user = insert(:user)
 148
 149       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 150
 151       {:ok, activity} =
 152         CommonAPI.post(user, %{
 153           "status" => post,
 154           "content_type" => "text/markdown"
 155         })
 156
 157       object = Object.normalize(activity)
 158
 159       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 160     end
 161
 162     test "it does not allow replies to direct messages that are not direct messages themselves" do
 163       user = insert(:user)
 164
 165       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 166
 167       assert {:ok, _} =
 168                CommonAPI.post(user, %{
 169                  "status" => "suya..",
 170                  "visibility" => "direct",
 171                  "in_reply_to_status_id" => activity.id
 172                })
 173
 174       Enum.each(["public", "private", "unlisted"], fn visibility ->
 175         assert {:error, "The message visibility must be direct"} =
 176                  CommonAPI.post(user, %{
 177                    "status" => "suya..",
 178                    "visibility" => visibility,
 179                    "in_reply_to_status_id" => activity.id
 180                  })
 181       end)
 182     end
 183
 184     test "it allows to address a list" do
 185       user = insert(:user)
 186       {:ok, list} = Pleroma.List.create("foo", user)
 187
 188       {:ok, activity} =
 189         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 190
 191       assert activity.data["bcc"] == [list.ap_id]
 192       assert activity.recipients == [list.ap_id, user.ap_id]
 193       assert activity.data["listMessage"] == list.ap_id
 194     end
 195
 196     test "it returns error when status is empty and no attachments" do
 197       user = insert(:user)
 198
 199       assert {:error, "Cannot post an empty status without attachments"} =
 200                CommonAPI.post(user, %{"status" => ""})
 201     end
 202
 203     test "it returns error when character limit is exceeded" do
 204       Pleroma.Config.put([:instance, :limit], 5)
 205
 206       user = insert(:user)
 207
 208       assert {:error, "The status is over the character limit"} =
 209                CommonAPI.post(user, %{"status" => "foobar"})
 210     end
 211
 212     test "it can handle activities that expire" do
 213       user = insert(:user)
 214
 215       expires_at =
 216         NaiveDateTime.utc_now()
 217         |> NaiveDateTime.truncate(:second)
 218         |> NaiveDateTime.add(1_000_000, :second)
 219
 220       assert {:ok, activity} =
 221                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 222
 223       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 224       assert expiration.scheduled_at == expires_at
 225     end
 226   end
 227
 228   describe "reactions" do
 229     test "reacting to a status with an emoji" do
 230       user = insert(:user)
 231       other_user = insert(:user)
 232
 233       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 234
 235       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 236
 237       assert reaction.data["actor"] == user.ap_id
 238       assert reaction.data["content"] == "👍"
 239
 240       # TODO: test error case.
 241     end
 242
 243     test "unreacting to a status with an emoji" do
 244       user = insert(:user)
 245       other_user = insert(:user)
 246
 247       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 248       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 249
 250       {:ok, unreaction, _} = CommonAPI.unreact_with_emoji(activity.id, user, "👍")
 251
 252       assert unreaction.data["type"] == "Undo"
 253       assert unreaction.data["object"] == reaction.data["id"]
 254     end
 255
 256     test "repeating a status" do
 257       user = insert(:user)
 258       other_user = insert(:user)
 259
 260       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 261
 262       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 263     end
 264
 265     test "repeating a status privately" do
 266       user = insert(:user)
 267       other_user = insert(:user)
 268
 269       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 270
 271       {:ok, %Activity{} = announce_activity, _} =
 272         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 273
 274       assert Visibility.is_private?(announce_activity)
 275     end
 276
 277     test "favoriting a status" do
 278       user = insert(:user)
 279       other_user = insert(:user)
 280
 281       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 282
 283       {:ok, %Activity{}, _} = CommonAPI.favorite(activity.id, user)
 284     end
 285
 286     test "retweeting a status twice returns an error" do
 287       user = insert(:user)
 288       other_user = insert(:user)
 289
 290       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 291       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 292       {:error, _} = CommonAPI.repeat(activity.id, user)
 293     end
 294
 295     test "favoriting a status twice returns an error" do
 296       user = insert(:user)
 297       other_user = insert(:user)
 298
 299       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 300       {:ok, %Activity{}, _object} = CommonAPI.favorite(activity.id, user)
 301       {:error, _} = CommonAPI.favorite(activity.id, user)
 302     end
 303   end
 304
 305   describe "pinned statuses" do
 306     setup do
 307       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 308
 309       user = insert(:user)
 310       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 311
 312       [user: user, activity: activity]
 313     end
 314
 315     test "pin status", %{user: user, activity: activity} do
 316       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 317
 318       id = activity.id
 319       user = refresh_record(user)
 320
 321       assert %User{info: %{pinned_activities: [^id]}} = user
 322     end
 323
 324     test "unlisted statuses can be pinned", %{user: user} do
 325       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 326       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 327     end
 328
 329     test "only self-authored can be pinned", %{activity: activity} do
 330       user = insert(:user)
 331
 332       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 333     end
 334
 335     test "max pinned statuses", %{user: user, activity: activity_one} do
 336       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 337
 338       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 339
 340       user = refresh_record(user)
 341
 342       assert {:error, "You have already pinned the maximum number of statuses"} =
 343                CommonAPI.pin(activity_two.id, user)
 344     end
 345
 346     test "unpin status", %{user: user, activity: activity} do
 347       {:ok, activity} = CommonAPI.pin(activity.id, user)
 348
 349       user = refresh_record(user)
 350
 351       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 352
 353       user = refresh_record(user)
 354
 355       assert %User{info: %{pinned_activities: []}} = user
 356     end
 357
 358     test "should unpin when deleting a status", %{user: user, activity: activity} do
 359       {:ok, activity} = CommonAPI.pin(activity.id, user)
 360
 361       user = refresh_record(user)
 362
 363       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 364
 365       user = refresh_record(user)
 366
 367       assert %User{info: %{pinned_activities: []}} = user
 368     end
 369   end
 370
 371   describe "mute tests" do
 372     setup do
 373       user = insert(:user)
 374
 375       activity = insert(:note_activity)
 376
 377       [user: user, activity: activity]
 378     end
 379
 380     test "add mute", %{user: user, activity: activity} do
 381       {:ok, _} = CommonAPI.add_mute(user, activity)
 382       assert CommonAPI.thread_muted?(user, activity)
 383     end
 384
 385     test "remove mute", %{user: user, activity: activity} do
 386       CommonAPI.add_mute(user, activity)
 387       {:ok, _} = CommonAPI.remove_mute(user, activity)
 388       refute CommonAPI.thread_muted?(user, activity)
 389     end
 390
 391     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 392       CommonAPI.add_mute(user, activity)
 393       {:error, _} = CommonAPI.add_mute(user, activity)
 394     end
 395   end
 396
 397   describe "reports" do
 398     test "creates a report" do
 399       reporter = insert(:user)
 400       target_user = insert(:user)
 401
 402       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 403
 404       reporter_ap_id = reporter.ap_id
 405       target_ap_id = target_user.ap_id
 406       activity_ap_id = activity.data["id"]
 407       comment = "foobar"
 408
 409       report_data = %{
 410         "account_id" => target_user.id,
 411         "comment" => comment,
 412         "status_ids" => [activity.id]
 413       }
 414
 415       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 416
 417       assert %Activity{
 418                actor: ^reporter_ap_id,
 419                data: %{
 420                  "type" => "Flag",
 421                  "content" => ^comment,
 422                  "object" => [^target_ap_id, ^activity_ap_id],
 423                  "state" => "open"
 424                }
 425              } = flag_activity
 426     end
 427
 428     test "updates report state" do
 429       [reporter, target_user] = insert_pair(:user)
 430       activity = insert(:note_activity, user: target_user)
 431
 432       {:ok, %Activity{id: report_id}} =
 433         CommonAPI.report(reporter, %{
 434           "account_id" => target_user.id,
 435           "comment" => "I feel offended",
 436           "status_ids" => [activity.id]
 437         })
 438
 439       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 440
 441       assert report.data["state"] == "resolved"
 442     end
 443
 444     test "does not update report state when state is unsupported" do
 445       [reporter, target_user] = insert_pair(:user)
 446       activity = insert(:note_activity, user: target_user)
 447
 448       {:ok, %Activity{id: report_id}} =
 449         CommonAPI.report(reporter, %{
 450           "account_id" => target_user.id,
 451           "comment" => "I feel offended",
 452           "status_ids" => [activity.id]
 453         })
 454
 455       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 456     end
 457   end
 458
 459   describe "reblog muting" do
 460     setup do
 461       muter = insert(:user)
 462
 463       muted = insert(:user)
 464
 465       [muter: muter, muted: muted]
 466     end
 467
 468     test "add a reblog mute", %{muter: muter, muted: muted} do
 469       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 470
 471       assert User.showing_reblogs?(muter, muted) == false
 472     end
 473
 474     test "remove a reblog mute", %{muter: muter, muted: muted} do
 475       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 476       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 477
 478       assert User.showing_reblogs?(muter, muted) == true
 479     end
 480   end
 481
 482   describe "unfollow/2" do
 483     test "also unsubscribes a user" do
 484       [follower, followed] = insert_pair(:user)
 485       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 486       {:ok, followed} = User.subscribe(follower, followed)
 487
 488       assert User.subscribed_to?(follower, followed)
 489
 490       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 491
 492       refute User.subscribed_to?(follower, followed)
 493     end
 494   end
 495
 496   describe "accept_follow_request/2" do
 497     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 498       user = insert(:user, info: %{locked: true})
 499       follower = insert(:user)
 500       follower_two = insert(:user)
 501
 502       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 503       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 504       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 505
 506       assert follow_activity.data["state"] == "pending"
 507       assert follow_activity_two.data["state"] == "pending"
 508       assert follow_activity_three.data["state"] == "pending"
 509
 510       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 511
 512       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 513       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 514       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 515     end
 516
 517     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 518       user = insert(:user, info: %{locked: true})
 519       follower = insert(:user)
 520       follower_two = insert(:user)
 521
 522       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 523       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 524       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 525
 526       assert follow_activity.data["state"] == "pending"
 527       assert follow_activity_two.data["state"] == "pending"
 528       assert follow_activity_three.data["state"] == "pending"
 529
 530       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 531
 532       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 533       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 534       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 535     end
 536   end
 537
 538   describe "vote/3" do
 539     test "does not allow to vote twice" do
 540       user = insert(:user)
 541       other_user = insert(:user)
 542
 543       {:ok, activity} =
 544         CommonAPI.post(user, %{
 545           "status" => "Am I cute?",
 546           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 547         })
 548
 549       object = Object.normalize(activity)
 550
 551       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 552
 553       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 554     end
 555   end
 556
 557   describe "listen/2" do
 558     test "returns a valid activity" do
 559       user = insert(:user)
 560
 561       {:ok, activity} =
 562         CommonAPI.listen(user, %{
 563           "title" => "lain radio episode 1",
 564           "album" => "lain radio",
 565           "artist" => "lain",
 566           "length" => 180_000
 567         })
 568
 569       object = Object.normalize(activity)
 570
 571       assert object.data["title"] == "lain radio episode 1"
 572
 573       assert Visibility.get_visibility(activity) == "public"
 574     end
 575
 576     test "respects visibility=private" do
 577       user = insert(:user)
 578
 579       {:ok, activity} =
 580         CommonAPI.listen(user, %{
 581           "title" => "lain radio episode 1",
 582           "album" => "lain radio",
 583           "artist" => "lain",
 584           "length" => 180_000,
 585           "visibility" => "private"
 586         })
 587
 588       object = Object.normalize(activity)
 589
 590       assert object.data["title"] == "lain radio episode 1"
 591
 592       assert Visibility.get_visibility(activity) == "private"
 593     end
 594   end
 595 end