git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   require Pleroma.Constants
  18
  19   clear_config([:instance, :safe_dm_mentions])
  20   clear_config([:instance, :limit])
  21   clear_config([:instance, :max_pinned_statuses])
  22
  23   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  24     user = insert(:user)
  25     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  26
  27     [participation] = Participation.for_user(user)
  28
  29     {:ok, convo_reply} =
  30       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  31
  32     assert Visibility.is_direct?(convo_reply)
  33
  34     assert activity.data["context"] == convo_reply.data["context"]
  35   end
  36
  37   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  38     har = insert(:user)
  39     jafnhar = insert(:user)
  40     tridi = insert(:user)
  41
  42     {:ok, activity} =
  43       CommonAPI.post(har, %{
  44         "status" => "@#{jafnhar.nickname} hey",
  45         "visibility" => "direct"
  46       })
  47
  48     assert har.ap_id in activity.recipients
  49     assert jafnhar.ap_id in activity.recipients
  50
  51     [participation] = Participation.for_user(har)
  52
  53     {:ok, activity} =
  54       CommonAPI.post(har, %{
  55         "status" => "I don't really like @#{tridi.nickname}",
  56         "visibility" => "direct",
  57         "in_reply_to_status_id" => activity.id,
  58         "in_reply_to_conversation_id" => participation.id
  59       })
  60
  61     assert har.ap_id in activity.recipients
  62     assert jafnhar.ap_id in activity.recipients
  63     refute tridi.ap_id in activity.recipients
  64   end
  65
  66   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  67     har = insert(:user)
  68     jafnhar = insert(:user)
  69     tridi = insert(:user)
  70     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  71
  72     {:ok, activity} =
  73       CommonAPI.post(har, %{
  74         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  75         "visibility" => "direct"
  76       })
  77
  78     refute tridi.ap_id in activity.recipients
  79     assert jafnhar.ap_id in activity.recipients
  80   end
  81
  82   test "it de-duplicates tags" do
  83     user = insert(:user)
  84     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  85
  86     object = Object.normalize(activity)
  87
  88     assert object.data["tag"] == ["2hu"]
  89   end
  90
  91   test "it adds emoji in the object" do
  92     user = insert(:user)
  93     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  94
  95     assert Object.normalize(activity).data["emoji"]["firefox"]
  96   end
  97
  98   test "it adds emoji when updating profiles" do
  99     user = insert(:user, %{name: ":firefox:"})
 100
 101     {:ok, activity} = CommonAPI.update(user)
 102     user = User.get_cached_by_ap_id(user.ap_id)
 103     [firefox] = user.info.source_data["tag"]
 104
 105     assert firefox["name"] == ":firefox:"
 106
 107     assert Pleroma.Constants.as_public() in activity.recipients
 108   end
 109
 110   describe "posting" do
 111     test "it supports explicit addressing" do
 112       user = insert(:user)
 113       user_two = insert(:user)
 114       user_three = insert(:user)
 115       user_four = insert(:user)
 116
 117       {:ok, activity} =
 118         CommonAPI.post(user, %{
 119           "status" =>
 120             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 121           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 122         })
 123
 124       assert user.ap_id in activity.recipients
 125       assert user_two.ap_id in activity.recipients
 126       assert user_four.ap_id in activity.recipients
 127       refute user_three.ap_id in activity.recipients
 128     end
 129
 130     test "it filters out obviously bad tags when accepting a post as HTML" do
 131       user = insert(:user)
 132
 133       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 134
 135       {:ok, activity} =
 136         CommonAPI.post(user, %{
 137           "status" => post,
 138           "content_type" => "text/html"
 139         })
 140
 141       object = Object.normalize(activity)
 142
 143       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 144     end
 145
 146     test "it filters out obviously bad tags when accepting a post as Markdown" do
 147       user = insert(:user)
 148
 149       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 150
 151       {:ok, activity} =
 152         CommonAPI.post(user, %{
 153           "status" => post,
 154           "content_type" => "text/markdown"
 155         })
 156
 157       object = Object.normalize(activity)
 158
 159       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 160     end
 161
 162     test "it does not allow replies to direct messages that are not direct messages themselves" do
 163       user = insert(:user)
 164
 165       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 166
 167       assert {:ok, _} =
 168                CommonAPI.post(user, %{
 169                  "status" => "suya..",
 170                  "visibility" => "direct",
 171                  "in_reply_to_status_id" => activity.id
 172                })
 173
 174       Enum.each(["public", "private", "unlisted"], fn visibility ->
 175         assert {:error, "The message visibility must be direct"} =
 176                  CommonAPI.post(user, %{
 177                    "status" => "suya..",
 178                    "visibility" => visibility,
 179                    "in_reply_to_status_id" => activity.id
 180                  })
 181       end)
 182     end
 183
 184     test "it allows to address a list" do
 185       user = insert(:user)
 186       {:ok, list} = Pleroma.List.create("foo", user)
 187
 188       {:ok, activity} =
 189         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 190
 191       assert activity.data["bcc"] == [list.ap_id]
 192       assert activity.recipients == [list.ap_id, user.ap_id]
 193       assert activity.data["listMessage"] == list.ap_id
 194     end
 195
 196     test "it returns error when status is empty and no attachments" do
 197       user = insert(:user)
 198
 199       assert {:error, "Cannot post an empty status without attachments"} =
 200                CommonAPI.post(user, %{"status" => ""})
 201     end
 202
 203     test "it returns error when character limit is exceeded" do
 204       Pleroma.Config.put([:instance, :limit], 5)
 205
 206       user = insert(:user)
 207
 208       assert {:error, "The status is over the character limit"} =
 209                CommonAPI.post(user, %{"status" => "foobar"})
 210     end
 211
 212     test "it can handle activities that expire" do
 213       user = insert(:user)
 214
 215       expires_at =
 216         NaiveDateTime.utc_now()
 217         |> NaiveDateTime.truncate(:second)
 218         |> NaiveDateTime.add(1_000_000, :second)
 219
 220       assert {:ok, activity} =
 221                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 222
 223       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 224       assert expiration.scheduled_at == expires_at
 225     end
 226   end
 227
 228   describe "reactions" do
 229     test "repeating a status" do
 230       user = insert(:user)
 231       other_user = insert(:user)
 232
 233       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 234
 235       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 236     end
 237
 238     test "repeating a status privately" do
 239       user = insert(:user)
 240       other_user = insert(:user)
 241
 242       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 243
 244       {:ok, %Activity{} = announce_activity, _} =
 245         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 246
 247       assert Visibility.is_private?(announce_activity)
 248     end
 249
 250     test "favoriting a status" do
 251       user = insert(:user)
 252       other_user = insert(:user)
 253
 254       {:ok, post_activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 255
 256       {:ok, %Activity{data: data}} = CommonAPI.favorite(user, post_activity.id)
 257       assert data["type"] == "Like"
 258       assert data["actor"] == user.ap_id
 259       assert data["object"] == post_activity.data["object"]
 260     end
 261
 262     test "retweeting a status twice returns an error" do
 263       user = insert(:user)
 264       other_user = insert(:user)
 265
 266       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 267       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 268       {:error, _} = CommonAPI.repeat(activity.id, user)
 269     end
 270
 271     test "favoriting a status twice returns an error" do
 272       user = insert(:user)
 273       other_user = insert(:user)
 274
 275       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 276       {:ok, %Activity{}} = CommonAPI.favorite(user, activity.id)
 277       {:error, _} = CommonAPI.favorite(user, activity.id)
 278     end
 279   end
 280
 281   describe "pinned statuses" do
 282     setup do
 283       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 284
 285       user = insert(:user)
 286       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 287
 288       [user: user, activity: activity]
 289     end
 290
 291     test "pin status", %{user: user, activity: activity} do
 292       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 293
 294       id = activity.id
 295       user = refresh_record(user)
 296
 297       assert %User{info: %{pinned_activities: [^id]}} = user
 298     end
 299
 300     test "unlisted statuses can be pinned", %{user: user} do
 301       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 302       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 303     end
 304
 305     test "only self-authored can be pinned", %{activity: activity} do
 306       user = insert(:user)
 307
 308       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 309     end
 310
 311     test "max pinned statuses", %{user: user, activity: activity_one} do
 312       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 313
 314       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 315
 316       user = refresh_record(user)
 317
 318       assert {:error, "You have already pinned the maximum number of statuses"} =
 319                CommonAPI.pin(activity_two.id, user)
 320     end
 321
 322     test "unpin status", %{user: user, activity: activity} do
 323       {:ok, activity} = CommonAPI.pin(activity.id, user)
 324
 325       user = refresh_record(user)
 326
 327       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 328
 329       user = refresh_record(user)
 330
 331       assert %User{info: %{pinned_activities: []}} = user
 332     end
 333
 334     test "should unpin when deleting a status", %{user: user, activity: activity} do
 335       {:ok, activity} = CommonAPI.pin(activity.id, user)
 336
 337       user = refresh_record(user)
 338
 339       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 340
 341       user = refresh_record(user)
 342
 343       assert %User{info: %{pinned_activities: []}} = user
 344     end
 345   end
 346
 347   describe "mute tests" do
 348     setup do
 349       user = insert(:user)
 350
 351       activity = insert(:note_activity)
 352
 353       [user: user, activity: activity]
 354     end
 355
 356     test "add mute", %{user: user, activity: activity} do
 357       {:ok, _} = CommonAPI.add_mute(user, activity)
 358       assert CommonAPI.thread_muted?(user, activity)
 359     end
 360
 361     test "remove mute", %{user: user, activity: activity} do
 362       CommonAPI.add_mute(user, activity)
 363       {:ok, _} = CommonAPI.remove_mute(user, activity)
 364       refute CommonAPI.thread_muted?(user, activity)
 365     end
 366
 367     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 368       CommonAPI.add_mute(user, activity)
 369       {:error, _} = CommonAPI.add_mute(user, activity)
 370     end
 371   end
 372
 373   describe "reports" do
 374     test "creates a report" do
 375       reporter = insert(:user)
 376       target_user = insert(:user)
 377
 378       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 379
 380       reporter_ap_id = reporter.ap_id
 381       target_ap_id = target_user.ap_id
 382       activity_ap_id = activity.data["id"]
 383       comment = "foobar"
 384
 385       report_data = %{
 386         "account_id" => target_user.id,
 387         "comment" => comment,
 388         "status_ids" => [activity.id]
 389       }
 390
 391       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 392
 393       assert %Activity{
 394                actor: ^reporter_ap_id,
 395                data: %{
 396                  "type" => "Flag",
 397                  "content" => ^comment,
 398                  "object" => [^target_ap_id, ^activity_ap_id],
 399                  "state" => "open"
 400                }
 401              } = flag_activity
 402     end
 403
 404     test "updates report state" do
 405       [reporter, target_user] = insert_pair(:user)
 406       activity = insert(:note_activity, user: target_user)
 407
 408       {:ok, %Activity{id: report_id}} =
 409         CommonAPI.report(reporter, %{
 410           "account_id" => target_user.id,
 411           "comment" => "I feel offended",
 412           "status_ids" => [activity.id]
 413         })
 414
 415       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 416
 417       assert report.data["state"] == "resolved"
 418     end
 419
 420     test "does not update report state when state is unsupported" do
 421       [reporter, target_user] = insert_pair(:user)
 422       activity = insert(:note_activity, user: target_user)
 423
 424       {:ok, %Activity{id: report_id}} =
 425         CommonAPI.report(reporter, %{
 426           "account_id" => target_user.id,
 427           "comment" => "I feel offended",
 428           "status_ids" => [activity.id]
 429         })
 430
 431       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 432     end
 433   end
 434
 435   describe "reblog muting" do
 436     setup do
 437       muter = insert(:user)
 438
 439       muted = insert(:user)
 440
 441       [muter: muter, muted: muted]
 442     end
 443
 444     test "add a reblog mute", %{muter: muter, muted: muted} do
 445       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 446
 447       assert User.showing_reblogs?(muter, muted) == false
 448     end
 449
 450     test "remove a reblog mute", %{muter: muter, muted: muted} do
 451       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 452       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 453
 454       assert User.showing_reblogs?(muter, muted) == true
 455     end
 456   end
 457
 458   describe "unfollow/2" do
 459     test "also unsubscribes a user" do
 460       [follower, followed] = insert_pair(:user)
 461       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 462       {:ok, followed} = User.subscribe(follower, followed)
 463
 464       assert User.subscribed_to?(follower, followed)
 465
 466       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 467
 468       refute User.subscribed_to?(follower, followed)
 469     end
 470   end
 471
 472   describe "accept_follow_request/2" do
 473     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 474       user = insert(:user, info: %{locked: true})
 475       follower = insert(:user)
 476       follower_two = insert(:user)
 477
 478       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 479       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 480       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 481
 482       assert follow_activity.data["state"] == "pending"
 483       assert follow_activity_two.data["state"] == "pending"
 484       assert follow_activity_three.data["state"] == "pending"
 485
 486       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 487
 488       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 489       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 490       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 491     end
 492
 493     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 494       user = insert(:user, info: %{locked: true})
 495       follower = insert(:user)
 496       follower_two = insert(:user)
 497
 498       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 499       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 500       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 501
 502       assert follow_activity.data["state"] == "pending"
 503       assert follow_activity_two.data["state"] == "pending"
 504       assert follow_activity_three.data["state"] == "pending"
 505
 506       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 507
 508       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 509       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 510       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 511     end
 512   end
 513
 514   describe "vote/3" do
 515     test "does not allow to vote twice" do
 516       user = insert(:user)
 517       other_user = insert(:user)
 518
 519       {:ok, activity} =
 520         CommonAPI.post(user, %{
 521           "status" => "Am I cute?",
 522           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 523         })
 524
 525       object = Object.normalize(activity)
 526
 527       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 528
 529       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 530     end
 531   end
 532
 533   describe "listen/2" do
 534     test "returns a valid activity" do
 535       user = insert(:user)
 536
 537       {:ok, activity} =
 538         CommonAPI.listen(user, %{
 539           "title" => "lain radio episode 1",
 540           "album" => "lain radio",
 541           "artist" => "lain",
 542           "length" => 180_000
 543         })
 544
 545       object = Object.normalize(activity)
 546
 547       assert object.data["title"] == "lain radio episode 1"
 548
 549       assert Visibility.get_visibility(activity) == "public"
 550     end
 551
 552     test "respects visibility=private" do
 553       user = insert(:user)
 554
 555       {:ok, activity} =
 556         CommonAPI.listen(user, %{
 557           "title" => "lain radio episode 1",
 558           "album" => "lain radio",
 559           "artist" => "lain",
 560           "length" => 180_000,
 561           "visibility" => "private"
 562         })
 563
 564       object = Object.normalize(activity)
 565
 566       assert object.data["title"] == "lain radio episode 1"
 567
 568       assert Visibility.get_visibility(activity) == "private"
 569     end
 570   end
 571 end