git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.AdminAPI.AccountView
  14   alias Pleroma.Web.CommonAPI
  15
  16   import Pleroma.Factory
  17
  18   require Pleroma.Constants
  19
  20   clear_config([:instance, :safe_dm_mentions])
  21   clear_config([:instance, :limit])
  22   clear_config([:instance, :max_pinned_statuses])
  23
  24   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  25     user = insert(:user)
  26     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  27
  28     [participation] = Participation.for_user(user)
  29
  30     {:ok, convo_reply} =
  31       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  32
  33     assert Visibility.is_direct?(convo_reply)
  34
  35     assert activity.data["context"] == convo_reply.data["context"]
  36   end
  37
  38   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  39     har = insert(:user)
  40     jafnhar = insert(:user)
  41     tridi = insert(:user)
  42
  43     {:ok, activity} =
  44       CommonAPI.post(har, %{
  45         "status" => "@#{jafnhar.nickname} hey",
  46         "visibility" => "direct"
  47       })
  48
  49     assert har.ap_id in activity.recipients
  50     assert jafnhar.ap_id in activity.recipients
  51
  52     [participation] = Participation.for_user(har)
  53
  54     {:ok, activity} =
  55       CommonAPI.post(har, %{
  56         "status" => "I don't really like @#{tridi.nickname}",
  57         "visibility" => "direct",
  58         "in_reply_to_status_id" => activity.id,
  59         "in_reply_to_conversation_id" => participation.id
  60       })
  61
  62     assert har.ap_id in activity.recipients
  63     assert jafnhar.ap_id in activity.recipients
  64     refute tridi.ap_id in activity.recipients
  65   end
  66
  67   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  68     har = insert(:user)
  69     jafnhar = insert(:user)
  70     tridi = insert(:user)
  71     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  72
  73     {:ok, activity} =
  74       CommonAPI.post(har, %{
  75         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  76         "visibility" => "direct"
  77       })
  78
  79     refute tridi.ap_id in activity.recipients
  80     assert jafnhar.ap_id in activity.recipients
  81   end
  82
  83   test "it de-duplicates tags" do
  84     user = insert(:user)
  85     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  86
  87     object = Object.normalize(activity)
  88
  89     assert object.data["tag"] == ["2hu"]
  90   end
  91
  92   test "it adds emoji in the object" do
  93     user = insert(:user)
  94     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  95
  96     assert Object.normalize(activity).data["emoji"]["firefox"]
  97   end
  98
  99   test "it adds emoji when updating profiles" do
 100     user = insert(:user, %{name: ":firefox:"})
 101
 102     {:ok, activity} = CommonAPI.update(user)
 103     user = User.get_cached_by_ap_id(user.ap_id)
 104     [firefox] = user.source_data["tag"]
 105
 106     assert firefox["name"] == ":firefox:"
 107
 108     assert Pleroma.Constants.as_public() in activity.recipients
 109   end
 110
 111   describe "posting" do
 112     test "it supports explicit addressing" do
 113       user = insert(:user)
 114       user_two = insert(:user)
 115       user_three = insert(:user)
 116       user_four = insert(:user)
 117
 118       {:ok, activity} =
 119         CommonAPI.post(user, %{
 120           "status" =>
 121             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 122           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 123         })
 124
 125       assert user.ap_id in activity.recipients
 126       assert user_two.ap_id in activity.recipients
 127       assert user_four.ap_id in activity.recipients
 128       refute user_three.ap_id in activity.recipients
 129     end
 130
 131     test "it filters out obviously bad tags when accepting a post as HTML" do
 132       user = insert(:user)
 133
 134       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 135
 136       {:ok, activity} =
 137         CommonAPI.post(user, %{
 138           "status" => post,
 139           "content_type" => "text/html"
 140         })
 141
 142       object = Object.normalize(activity)
 143
 144       assert object.data["content"] == "<p><b>2hu</b></p>alert(&#39;xss&#39;)"
 145     end
 146
 147     test "it filters out obviously bad tags when accepting a post as Markdown" do
 148       user = insert(:user)
 149
 150       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 151
 152       {:ok, activity} =
 153         CommonAPI.post(user, %{
 154           "status" => post,
 155           "content_type" => "text/markdown"
 156         })
 157
 158       object = Object.normalize(activity)
 159
 160       assert object.data["content"] == "<p><b>2hu</b></p>alert(&#39;xss&#39;)"
 161     end
 162
 163     test "it does not allow replies to direct messages that are not direct messages themselves" do
 164       user = insert(:user)
 165
 166       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 167
 168       assert {:ok, _} =
 169                CommonAPI.post(user, %{
 170                  "status" => "suya..",
 171                  "visibility" => "direct",
 172                  "in_reply_to_status_id" => activity.id
 173                })
 174
 175       Enum.each(["public", "private", "unlisted"], fn visibility ->
 176         assert {:error, "The message visibility must be direct"} =
 177                  CommonAPI.post(user, %{
 178                    "status" => "suya..",
 179                    "visibility" => visibility,
 180                    "in_reply_to_status_id" => activity.id
 181                  })
 182       end)
 183     end
 184
 185     test "it allows to address a list" do
 186       user = insert(:user)
 187       {:ok, list} = Pleroma.List.create("foo", user)
 188
 189       {:ok, activity} =
 190         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 191
 192       assert activity.data["bcc"] == [list.ap_id]
 193       assert activity.recipients == [list.ap_id, user.ap_id]
 194       assert activity.data["listMessage"] == list.ap_id
 195     end
 196
 197     test "it returns error when status is empty and no attachments" do
 198       user = insert(:user)
 199
 200       assert {:error, "Cannot post an empty status without attachments"} =
 201                CommonAPI.post(user, %{"status" => ""})
 202     end
 203
 204     test "it returns error when character limit is exceeded" do
 205       Pleroma.Config.put([:instance, :limit], 5)
 206
 207       user = insert(:user)
 208
 209       assert {:error, "The status is over the character limit"} =
 210                CommonAPI.post(user, %{"status" => "foobar"})
 211     end
 212
 213     test "it can handle activities that expire" do
 214       user = insert(:user)
 215
 216       expires_at =
 217         NaiveDateTime.utc_now()
 218         |> NaiveDateTime.truncate(:second)
 219         |> NaiveDateTime.add(1_000_000, :second)
 220
 221       assert {:ok, activity} =
 222                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 223
 224       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 225       assert expiration.scheduled_at == expires_at
 226     end
 227   end
 228
 229   describe "reactions" do
 230     test "reacting to a status with an emoji" do
 231       user = insert(:user)
 232       other_user = insert(:user)
 233
 234       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 235
 236       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 237
 238       assert reaction.data["actor"] == user.ap_id
 239       assert reaction.data["content"] == "👍"
 240
 241       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 242
 243       {:error, _} = CommonAPI.react_with_emoji(activity.id, user, ".")
 244     end
 245
 246     test "unreacting to a status with an emoji" do
 247       user = insert(:user)
 248       other_user = insert(:user)
 249
 250       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 251       {:ok, reaction, _} = CommonAPI.react_with_emoji(activity.id, user, "👍")
 252
 253       {:ok, unreaction, _} = CommonAPI.unreact_with_emoji(activity.id, user, "👍")
 254
 255       assert unreaction.data["type"] == "Undo"
 256       assert unreaction.data["object"] == reaction.data["id"]
 257     end
 258
 259     test "repeating a status" do
 260       user = insert(:user)
 261       other_user = insert(:user)
 262
 263       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 264
 265       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 266     end
 267
 268     test "repeating a status privately" do
 269       user = insert(:user)
 270       other_user = insert(:user)
 271
 272       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 273
 274       {:ok, %Activity{} = announce_activity, _} =
 275         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 276
 277       assert Visibility.is_private?(announce_activity)
 278     end
 279
 280     test "favoriting a status" do
 281       user = insert(:user)
 282       other_user = insert(:user)
 283
 284       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 285
 286       {:ok, %Activity{}, _} = CommonAPI.favorite(activity.id, user)
 287     end
 288
 289     test "retweeting a status twice returns the status" do
 290       user = insert(:user)
 291       other_user = insert(:user)
 292
 293       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 294       {:ok, %Activity{} = activity, object} = CommonAPI.repeat(activity.id, user)
 295       {:ok, ^activity, ^object} = CommonAPI.repeat(activity.id, user)
 296     end
 297
 298     test "favoriting a status twice returns the status" do
 299       user = insert(:user)
 300       other_user = insert(:user)
 301
 302       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 303       {:ok, %Activity{} = activity, object} = CommonAPI.favorite(activity.id, user)
 304       {:ok, ^activity, ^object} = CommonAPI.favorite(activity.id, user)
 305     end
 306   end
 307
 308   describe "pinned statuses" do
 309     setup do
 310       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 311
 312       user = insert(:user)
 313       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 314
 315       [user: user, activity: activity]
 316     end
 317
 318     test "pin status", %{user: user, activity: activity} do
 319       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 320
 321       id = activity.id
 322       user = refresh_record(user)
 323
 324       assert %User{pinned_activities: [^id]} = user
 325     end
 326
 327     test "unlisted statuses can be pinned", %{user: user} do
 328       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 329       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 330     end
 331
 332     test "only self-authored can be pinned", %{activity: activity} do
 333       user = insert(:user)
 334
 335       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 336     end
 337
 338     test "max pinned statuses", %{user: user, activity: activity_one} do
 339       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 340
 341       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 342
 343       user = refresh_record(user)
 344
 345       assert {:error, "You have already pinned the maximum number of statuses"} =
 346                CommonAPI.pin(activity_two.id, user)
 347     end
 348
 349     test "unpin status", %{user: user, activity: activity} do
 350       {:ok, activity} = CommonAPI.pin(activity.id, user)
 351
 352       user = refresh_record(user)
 353
 354       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 355
 356       user = refresh_record(user)
 357
 358       assert %User{pinned_activities: []} = user
 359     end
 360
 361     test "should unpin when deleting a status", %{user: user, activity: activity} do
 362       {:ok, activity} = CommonAPI.pin(activity.id, user)
 363
 364       user = refresh_record(user)
 365
 366       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 367
 368       user = refresh_record(user)
 369
 370       assert %User{pinned_activities: []} = user
 371     end
 372   end
 373
 374   describe "mute tests" do
 375     setup do
 376       user = insert(:user)
 377
 378       activity = insert(:note_activity)
 379
 380       [user: user, activity: activity]
 381     end
 382
 383     test "add mute", %{user: user, activity: activity} do
 384       {:ok, _} = CommonAPI.add_mute(user, activity)
 385       assert CommonAPI.thread_muted?(user, activity)
 386     end
 387
 388     test "remove mute", %{user: user, activity: activity} do
 389       CommonAPI.add_mute(user, activity)
 390       {:ok, _} = CommonAPI.remove_mute(user, activity)
 391       refute CommonAPI.thread_muted?(user, activity)
 392     end
 393
 394     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 395       CommonAPI.add_mute(user, activity)
 396       {:error, _} = CommonAPI.add_mute(user, activity)
 397     end
 398   end
 399
 400   describe "reports" do
 401     test "creates a report" do
 402       reporter = insert(:user)
 403       target_user = insert(:user)
 404
 405       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 406
 407       reporter_ap_id = reporter.ap_id
 408       target_ap_id = target_user.ap_id
 409       activity_ap_id = activity.data["id"]
 410       comment = "foobar"
 411
 412       report_data = %{
 413         "account_id" => target_user.id,
 414         "comment" => comment,
 415         "status_ids" => [activity.id]
 416       }
 417
 418       note_obj = %{
 419         "type" => "Note",
 420         "id" => activity_ap_id,
 421         "content" => "foobar",
 422         "published" => activity.object.data["published"],
 423         "actor" => AccountView.render("show.json", %{user: target_user})
 424       }
 425
 426       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 427
 428       assert %Activity{
 429                actor: ^reporter_ap_id,
 430                data: %{
 431                  "type" => "Flag",
 432                  "content" => ^comment,
 433                  "object" => [^target_ap_id, ^note_obj],
 434                  "state" => "open"
 435                }
 436              } = flag_activity
 437     end
 438
 439     test "updates report state" do
 440       [reporter, target_user] = insert_pair(:user)
 441       activity = insert(:note_activity, user: target_user)
 442
 443       {:ok, %Activity{id: report_id}} =
 444         CommonAPI.report(reporter, %{
 445           "account_id" => target_user.id,
 446           "comment" => "I feel offended",
 447           "status_ids" => [activity.id]
 448         })
 449
 450       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 451
 452       assert report.data["state"] == "resolved"
 453
 454       [reported_user, activity_id] = report.data["object"]
 455
 456       assert reported_user == target_user.ap_id
 457       assert activity_id == activity.data["id"]
 458     end
 459
 460     test "does not update report state when state is unsupported" do
 461       [reporter, target_user] = insert_pair(:user)
 462       activity = insert(:note_activity, user: target_user)
 463
 464       {:ok, %Activity{id: report_id}} =
 465         CommonAPI.report(reporter, %{
 466           "account_id" => target_user.id,
 467           "comment" => "I feel offended",
 468           "status_ids" => [activity.id]
 469         })
 470
 471       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 472     end
 473
 474     test "updates state of multiple reports" do
 475       [reporter, target_user] = insert_pair(:user)
 476       activity = insert(:note_activity, user: target_user)
 477
 478       {:ok, %Activity{id: first_report_id}} =
 479         CommonAPI.report(reporter, %{
 480           "account_id" => target_user.id,
 481           "comment" => "I feel offended",
 482           "status_ids" => [activity.id]
 483         })
 484
 485       {:ok, %Activity{id: second_report_id}} =
 486         CommonAPI.report(reporter, %{
 487           "account_id" => target_user.id,
 488           "comment" => "I feel very offended!",
 489           "status_ids" => [activity.id]
 490         })
 491
 492       {:ok, report_ids} =
 493         CommonAPI.update_report_state([first_report_id, second_report_id], "resolved")
 494
 495       first_report = Activity.get_by_id(first_report_id)
 496       second_report = Activity.get_by_id(second_report_id)
 497
 498       assert report_ids -- [first_report_id, second_report_id] == []
 499       assert first_report.data["state"] == "resolved"
 500       assert second_report.data["state"] == "resolved"
 501     end
 502   end
 503
 504   describe "reblog muting" do
 505     setup do
 506       muter = insert(:user)
 507
 508       muted = insert(:user)
 509
 510       [muter: muter, muted: muted]
 511     end
 512
 513     test "add a reblog mute", %{muter: muter, muted: muted} do
 514       {:ok, _reblog_mute} = CommonAPI.hide_reblogs(muter, muted)
 515
 516       assert User.showing_reblogs?(muter, muted) == false
 517     end
 518
 519     test "remove a reblog mute", %{muter: muter, muted: muted} do
 520       {:ok, _reblog_mute} = CommonAPI.hide_reblogs(muter, muted)
 521       {:ok, _reblog_mute} = CommonAPI.show_reblogs(muter, muted)
 522
 523       assert User.showing_reblogs?(muter, muted) == true
 524     end
 525   end
 526
 527   describe "unfollow/2" do
 528     test "also unsubscribes a user" do
 529       [follower, followed] = insert_pair(:user)
 530       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 531       {:ok, _subscription} = User.subscribe(follower, followed)
 532
 533       assert User.subscribed_to?(follower, followed)
 534
 535       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 536
 537       refute User.subscribed_to?(follower, followed)
 538     end
 539   end
 540
 541   describe "accept_follow_request/2" do
 542     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 543       user = insert(:user, locked: true)
 544       follower = insert(:user)
 545       follower_two = insert(:user)
 546
 547       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 548       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 549       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 550
 551       assert follow_activity.data["state"] == "pending"
 552       assert follow_activity_two.data["state"] == "pending"
 553       assert follow_activity_three.data["state"] == "pending"
 554
 555       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 556
 557       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 558       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 559       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 560     end
 561
 562     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 563       user = insert(:user, locked: true)
 564       follower = insert(:user)
 565       follower_two = insert(:user)
 566
 567       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 568       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 569       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 570
 571       assert follow_activity.data["state"] == "pending"
 572       assert follow_activity_two.data["state"] == "pending"
 573       assert follow_activity_three.data["state"] == "pending"
 574
 575       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 576
 577       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 578       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 579       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 580     end
 581   end
 582
 583   describe "vote/3" do
 584     test "does not allow to vote twice" do
 585       user = insert(:user)
 586       other_user = insert(:user)
 587
 588       {:ok, activity} =
 589         CommonAPI.post(user, %{
 590           "status" => "Am I cute?",
 591           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 592         })
 593
 594       object = Object.normalize(activity)
 595
 596       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 597
 598       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 599     end
 600   end
 601
 602   describe "listen/2" do
 603     test "returns a valid activity" do
 604       user = insert(:user)
 605
 606       {:ok, activity} =
 607         CommonAPI.listen(user, %{
 608           "title" => "lain radio episode 1",
 609           "album" => "lain radio",
 610           "artist" => "lain",
 611           "length" => 180_000
 612         })
 613
 614       object = Object.normalize(activity)
 615
 616       assert object.data["title"] == "lain radio episode 1"
 617
 618       assert Visibility.get_visibility(activity) == "public"
 619     end
 620
 621     test "respects visibility=private" do
 622       user = insert(:user)
 623
 624       {:ok, activity} =
 625         CommonAPI.listen(user, %{
 626           "title" => "lain radio episode 1",
 627           "album" => "lain radio",
 628           "artist" => "lain",
 629           "length" => 180_000,
 630           "visibility" => "private"
 631         })
 632
 633       object = Object.normalize(activity)
 634
 635       assert object.data["title"] == "lain radio episode 1"
 636
 637       assert Visibility.get_visibility(activity) == "private"
 638     end
 639   end
 640 end