git.squeep.com Git - akkoma/blob - test/web/common_api/common_api_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPITest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Activity
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.ActivityPub.Visibility
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16   import ExUnit.CaptureLog
  17
  18   require Pleroma.Constants
  19
  20   clear_config([:instance, :safe_dm_mentions])
  21   clear_config([:instance, :limit])
  22   clear_config([:instance, :max_pinned_statuses])
  23
  24   test "when replying to a conversation / participation, it will set the correct context id even if no explicit reply_to is given" do
  25     user = insert(:user)
  26     {:ok, activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  27
  28     [participation] = Participation.for_user(user)
  29
  30     {:ok, convo_reply} =
  31       CommonAPI.post(user, %{"status" => ".", "in_reply_to_conversation_id" => participation.id})
  32
  33     assert Visibility.is_direct?(convo_reply)
  34
  35     assert activity.data["context"] == convo_reply.data["context"]
  36   end
  37
  38   test "when replying to a conversation / participation, it only mentions the recipients explicitly declared in the participation" do
  39     har = insert(:user)
  40     jafnhar = insert(:user)
  41     tridi = insert(:user)
  42
  43     {:ok, activity} =
  44       CommonAPI.post(har, %{
  45         "status" => "@#{jafnhar.nickname} hey",
  46         "visibility" => "direct"
  47       })
  48
  49     assert har.ap_id in activity.recipients
  50     assert jafnhar.ap_id in activity.recipients
  51
  52     [participation] = Participation.for_user(har)
  53
  54     {:ok, activity} =
  55       CommonAPI.post(har, %{
  56         "status" => "I don't really like @#{tridi.nickname}",
  57         "visibility" => "direct",
  58         "in_reply_to_status_id" => activity.id,
  59         "in_reply_to_conversation_id" => participation.id
  60       })
  61
  62     assert har.ap_id in activity.recipients
  63     assert jafnhar.ap_id in activity.recipients
  64     refute tridi.ap_id in activity.recipients
  65   end
  66
  67   test "with the safe_dm_mention option set, it does not mention people beyond the initial tags" do
  68     har = insert(:user)
  69     jafnhar = insert(:user)
  70     tridi = insert(:user)
  71     Pleroma.Config.put([:instance, :safe_dm_mentions], true)
  72
  73     {:ok, activity} =
  74       CommonAPI.post(har, %{
  75         "status" => "@#{jafnhar.nickname} hey, i never want to see @#{tridi.nickname} again",
  76         "visibility" => "direct"
  77       })
  78
  79     refute tridi.ap_id in activity.recipients
  80     assert jafnhar.ap_id in activity.recipients
  81   end
  82
  83   test "it de-duplicates tags" do
  84     user = insert(:user)
  85     {:ok, activity} = CommonAPI.post(user, %{"status" => "#2hu #2HU"})
  86
  87     object = Object.normalize(activity)
  88
  89     assert object.data["tag"] == ["2hu"]
  90   end
  91
  92   test "it adds emoji in the object" do
  93     user = insert(:user)
  94     {:ok, activity} = CommonAPI.post(user, %{"status" => ":firefox:"})
  95
  96     assert Object.normalize(activity).data["emoji"]["firefox"]
  97   end
  98
  99   test "it adds emoji when updating profiles" do
 100     user = insert(:user, %{name: ":firefox:"})
 101
 102     {:ok, activity} = CommonAPI.update(user)
 103     user = User.get_cached_by_ap_id(user.ap_id)
 104     [firefox] = user.info.source_data["tag"]
 105
 106     assert firefox["name"] == ":firefox:"
 107
 108     assert Pleroma.Constants.as_public() in activity.recipients
 109   end
 110
 111   describe "posting" do
 112     test "it supports explicit addressing" do
 113       user = insert(:user)
 114       user_two = insert(:user)
 115       user_three = insert(:user)
 116       user_four = insert(:user)
 117
 118       {:ok, activity} =
 119         CommonAPI.post(user, %{
 120           "status" =>
 121             "Hey, I think @#{user_three.nickname} is ugly. @#{user_four.nickname} is alright though.",
 122           "to" => [user_two.nickname, user_four.nickname, "nonexistent"]
 123         })
 124
 125       assert user.ap_id in activity.recipients
 126       assert user_two.ap_id in activity.recipients
 127       assert user_four.ap_id in activity.recipients
 128       refute user_three.ap_id in activity.recipients
 129     end
 130
 131     test "it filters out obviously bad tags when accepting a post as HTML" do
 132       user = insert(:user)
 133
 134       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 135
 136       {:ok, activity} =
 137         CommonAPI.post(user, %{
 138           "status" => post,
 139           "content_type" => "text/html"
 140         })
 141
 142       object = Object.normalize(activity)
 143
 144       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 145     end
 146
 147     test "it filters out obviously bad tags when accepting a post as Markdown" do
 148       user = insert(:user)
 149
 150       post = "<p><b>2hu</b></p><script>alert('xss')</script>"
 151
 152       {:ok, activity} =
 153         CommonAPI.post(user, %{
 154           "status" => post,
 155           "content_type" => "text/markdown"
 156         })
 157
 158       object = Object.normalize(activity)
 159
 160       assert object.data["content"] == "<p><b>2hu</b></p>alert('xss')"
 161     end
 162
 163     test "it does not allow replies to direct messages that are not direct messages themselves" do
 164       user = insert(:user)
 165
 166       {:ok, activity} = CommonAPI.post(user, %{"status" => "suya..", "visibility" => "direct"})
 167
 168       assert {:ok, _} =
 169                CommonAPI.post(user, %{
 170                  "status" => "suya..",
 171                  "visibility" => "direct",
 172                  "in_reply_to_status_id" => activity.id
 173                })
 174
 175       Enum.each(["public", "private", "unlisted"], fn visibility ->
 176         assert {:error, "The message visibility must be direct"} =
 177                  CommonAPI.post(user, %{
 178                    "status" => "suya..",
 179                    "visibility" => visibility,
 180                    "in_reply_to_status_id" => activity.id
 181                  })
 182       end)
 183     end
 184
 185     test "it allows to address a list" do
 186       user = insert(:user)
 187       {:ok, list} = Pleroma.List.create("foo", user)
 188
 189       {:ok, activity} =
 190         CommonAPI.post(user, %{"status" => "foobar", "visibility" => "list:#{list.id}"})
 191
 192       assert activity.data["bcc"] == [list.ap_id]
 193       assert activity.recipients == [list.ap_id, user.ap_id]
 194       assert activity.data["listMessage"] == list.ap_id
 195     end
 196
 197     test "it returns error when status is empty and no attachments" do
 198       user = insert(:user)
 199
 200       assert {:error, "Cannot post an empty status without attachments"} =
 201                CommonAPI.post(user, %{"status" => ""})
 202     end
 203
 204     test "it returns error when character limit is exceeded" do
 205       Pleroma.Config.put([:instance, :limit], 5)
 206
 207       user = insert(:user)
 208
 209       assert {:error, "The status is over the character limit"} =
 210                CommonAPI.post(user, %{"status" => "foobar"})
 211     end
 212
 213     test "it can handle activities that expire" do
 214       user = insert(:user)
 215
 216       expires_at =
 217         NaiveDateTime.utc_now()
 218         |> NaiveDateTime.truncate(:second)
 219         |> NaiveDateTime.add(1_000_000, :second)
 220
 221       assert {:ok, activity} =
 222                CommonAPI.post(user, %{"status" => "chai", "expires_in" => 1_000_000})
 223
 224       assert expiration = Pleroma.ActivityExpiration.get_by_activity_id(activity.id)
 225       assert expiration.scheduled_at == expires_at
 226     end
 227   end
 228
 229   describe "reactions" do
 230     test "repeating a status" do
 231       user = insert(:user)
 232       other_user = insert(:user)
 233
 234       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 235
 236       {:ok, %Activity{}, _} = CommonAPI.repeat(activity.id, user)
 237     end
 238
 239     test "repeating a status privately" do
 240       user = insert(:user)
 241       other_user = insert(:user)
 242
 243       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 244
 245       {:ok, %Activity{} = announce_activity, _} =
 246         CommonAPI.repeat(activity.id, user, %{"visibility" => "private"})
 247
 248       assert Visibility.is_private?(announce_activity)
 249     end
 250
 251     test "favoriting a status" do
 252       user = insert(:user)
 253       other_user = insert(:user)
 254
 255       {:ok, post_activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 256
 257       {:ok, %Activity{data: data}} = CommonAPI.favorite(user, post_activity.id)
 258       assert data["type"] == "Like"
 259       assert data["actor"] == user.ap_id
 260       assert data["object"] == post_activity.data["object"]
 261     end
 262
 263     test "retweeting a status twice returns an error" do
 264       user = insert(:user)
 265       other_user = insert(:user)
 266
 267       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 268       {:ok, %Activity{}, _object} = CommonAPI.repeat(activity.id, user)
 269       {:error, _} = CommonAPI.repeat(activity.id, user)
 270     end
 271
 272     test "favoriting a status twice returns an error" do
 273       user = insert(:user)
 274       other_user = insert(:user)
 275
 276       {:ok, activity} = CommonAPI.post(other_user, %{"status" => "cofe"})
 277       {:ok, %Activity{}} = CommonAPI.favorite(user, activity.id)
 278
 279       assert capture_log(fn ->
 280                assert {:error, _} = CommonAPI.favorite(user, activity.id)
 281              end) =~ "[error]"
 282     end
 283   end
 284
 285   describe "pinned statuses" do
 286     setup do
 287       Pleroma.Config.put([:instance, :max_pinned_statuses], 1)
 288
 289       user = insert(:user)
 290       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!"})
 291
 292       [user: user, activity: activity]
 293     end
 294
 295     test "pin status", %{user: user, activity: activity} do
 296       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 297
 298       id = activity.id
 299       user = refresh_record(user)
 300
 301       assert %User{info: %{pinned_activities: [^id]}} = user
 302     end
 303
 304     test "unlisted statuses can be pinned", %{user: user} do
 305       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI!!!", "visibility" => "unlisted"})
 306       assert {:ok, ^activity} = CommonAPI.pin(activity.id, user)
 307     end
 308
 309     test "only self-authored can be pinned", %{activity: activity} do
 310       user = insert(:user)
 311
 312       assert {:error, "Could not pin"} = CommonAPI.pin(activity.id, user)
 313     end
 314
 315     test "max pinned statuses", %{user: user, activity: activity_one} do
 316       {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 317
 318       assert {:ok, ^activity_one} = CommonAPI.pin(activity_one.id, user)
 319
 320       user = refresh_record(user)
 321
 322       assert {:error, "You have already pinned the maximum number of statuses"} =
 323                CommonAPI.pin(activity_two.id, user)
 324     end
 325
 326     test "unpin status", %{user: user, activity: activity} do
 327       {:ok, activity} = CommonAPI.pin(activity.id, user)
 328
 329       user = refresh_record(user)
 330
 331       assert {:ok, ^activity} = CommonAPI.unpin(activity.id, user)
 332
 333       user = refresh_record(user)
 334
 335       assert %User{info: %{pinned_activities: []}} = user
 336     end
 337
 338     test "should unpin when deleting a status", %{user: user, activity: activity} do
 339       {:ok, activity} = CommonAPI.pin(activity.id, user)
 340
 341       user = refresh_record(user)
 342
 343       assert {:ok, _} = CommonAPI.delete(activity.id, user)
 344
 345       user = refresh_record(user)
 346
 347       assert %User{info: %{pinned_activities: []}} = user
 348     end
 349   end
 350
 351   describe "mute tests" do
 352     setup do
 353       user = insert(:user)
 354
 355       activity = insert(:note_activity)
 356
 357       [user: user, activity: activity]
 358     end
 359
 360     test "add mute", %{user: user, activity: activity} do
 361       {:ok, _} = CommonAPI.add_mute(user, activity)
 362       assert CommonAPI.thread_muted?(user, activity)
 363     end
 364
 365     test "remove mute", %{user: user, activity: activity} do
 366       CommonAPI.add_mute(user, activity)
 367       {:ok, _} = CommonAPI.remove_mute(user, activity)
 368       refute CommonAPI.thread_muted?(user, activity)
 369     end
 370
 371     test "check that mutes can't be duplicate", %{user: user, activity: activity} do
 372       CommonAPI.add_mute(user, activity)
 373       {:error, _} = CommonAPI.add_mute(user, activity)
 374     end
 375   end
 376
 377   describe "reports" do
 378     test "creates a report" do
 379       reporter = insert(:user)
 380       target_user = insert(:user)
 381
 382       {:ok, activity} = CommonAPI.post(target_user, %{"status" => "foobar"})
 383
 384       reporter_ap_id = reporter.ap_id
 385       target_ap_id = target_user.ap_id
 386       activity_ap_id = activity.data["id"]
 387       comment = "foobar"
 388
 389       report_data = %{
 390         "account_id" => target_user.id,
 391         "comment" => comment,
 392         "status_ids" => [activity.id]
 393       }
 394
 395       assert {:ok, flag_activity} = CommonAPI.report(reporter, report_data)
 396
 397       assert %Activity{
 398                actor: ^reporter_ap_id,
 399                data: %{
 400                  "type" => "Flag",
 401                  "content" => ^comment,
 402                  "object" => [^target_ap_id, ^activity_ap_id],
 403                  "state" => "open"
 404                }
 405              } = flag_activity
 406     end
 407
 408     test "updates report state" do
 409       [reporter, target_user] = insert_pair(:user)
 410       activity = insert(:note_activity, user: target_user)
 411
 412       {:ok, %Activity{id: report_id}} =
 413         CommonAPI.report(reporter, %{
 414           "account_id" => target_user.id,
 415           "comment" => "I feel offended",
 416           "status_ids" => [activity.id]
 417         })
 418
 419       {:ok, report} = CommonAPI.update_report_state(report_id, "resolved")
 420
 421       assert report.data["state"] == "resolved"
 422     end
 423
 424     test "does not update report state when state is unsupported" do
 425       [reporter, target_user] = insert_pair(:user)
 426       activity = insert(:note_activity, user: target_user)
 427
 428       {:ok, %Activity{id: report_id}} =
 429         CommonAPI.report(reporter, %{
 430           "account_id" => target_user.id,
 431           "comment" => "I feel offended",
 432           "status_ids" => [activity.id]
 433         })
 434
 435       assert CommonAPI.update_report_state(report_id, "test") == {:error, "Unsupported state"}
 436     end
 437   end
 438
 439   describe "reblog muting" do
 440     setup do
 441       muter = insert(:user)
 442
 443       muted = insert(:user)
 444
 445       [muter: muter, muted: muted]
 446     end
 447
 448     test "add a reblog mute", %{muter: muter, muted: muted} do
 449       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 450
 451       assert User.showing_reblogs?(muter, muted) == false
 452     end
 453
 454     test "remove a reblog mute", %{muter: muter, muted: muted} do
 455       {:ok, muter} = CommonAPI.hide_reblogs(muter, muted)
 456       {:ok, muter} = CommonAPI.show_reblogs(muter, muted)
 457
 458       assert User.showing_reblogs?(muter, muted) == true
 459     end
 460   end
 461
 462   describe "unfollow/2" do
 463     test "also unsubscribes a user" do
 464       [follower, followed] = insert_pair(:user)
 465       {:ok, follower, followed, _} = CommonAPI.follow(follower, followed)
 466       {:ok, followed} = User.subscribe(follower, followed)
 467
 468       assert User.subscribed_to?(follower, followed)
 469
 470       {:ok, follower} = CommonAPI.unfollow(follower, followed)
 471
 472       refute User.subscribed_to?(follower, followed)
 473     end
 474   end
 475
 476   describe "accept_follow_request/2" do
 477     test "after acceptance, it sets all existing pending follow request states to 'accept'" do
 478       user = insert(:user, info: %{locked: true})
 479       follower = insert(:user)
 480       follower_two = insert(:user)
 481
 482       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 483       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 484       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 485
 486       assert follow_activity.data["state"] == "pending"
 487       assert follow_activity_two.data["state"] == "pending"
 488       assert follow_activity_three.data["state"] == "pending"
 489
 490       {:ok, _follower} = CommonAPI.accept_follow_request(follower, user)
 491
 492       assert Repo.get(Activity, follow_activity.id).data["state"] == "accept"
 493       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "accept"
 494       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 495     end
 496
 497     test "after rejection, it sets all existing pending follow request states to 'reject'" do
 498       user = insert(:user, info: %{locked: true})
 499       follower = insert(:user)
 500       follower_two = insert(:user)
 501
 502       {:ok, follow_activity} = ActivityPub.follow(follower, user)
 503       {:ok, follow_activity_two} = ActivityPub.follow(follower, user)
 504       {:ok, follow_activity_three} = ActivityPub.follow(follower_two, user)
 505
 506       assert follow_activity.data["state"] == "pending"
 507       assert follow_activity_two.data["state"] == "pending"
 508       assert follow_activity_three.data["state"] == "pending"
 509
 510       {:ok, _follower} = CommonAPI.reject_follow_request(follower, user)
 511
 512       assert Repo.get(Activity, follow_activity.id).data["state"] == "reject"
 513       assert Repo.get(Activity, follow_activity_two.id).data["state"] == "reject"
 514       assert Repo.get(Activity, follow_activity_three.id).data["state"] == "pending"
 515     end
 516   end
 517
 518   describe "vote/3" do
 519     test "does not allow to vote twice" do
 520       user = insert(:user)
 521       other_user = insert(:user)
 522
 523       {:ok, activity} =
 524         CommonAPI.post(user, %{
 525           "status" => "Am I cute?",
 526           "poll" => %{"options" => ["Yes", "No"], "expires_in" => 20}
 527         })
 528
 529       object = Object.normalize(activity)
 530
 531       {:ok, _, object} = CommonAPI.vote(other_user, object, [0])
 532
 533       assert {:error, "Already voted"} == CommonAPI.vote(other_user, object, [1])
 534     end
 535   end
 536
 537   describe "listen/2" do
 538     test "returns a valid activity" do
 539       user = insert(:user)
 540
 541       {:ok, activity} =
 542         CommonAPI.listen(user, %{
 543           "title" => "lain radio episode 1",
 544           "album" => "lain radio",
 545           "artist" => "lain",
 546           "length" => 180_000
 547         })
 548
 549       object = Object.normalize(activity)
 550
 551       assert object.data["title"] == "lain radio episode 1"
 552
 553       assert Visibility.get_visibility(activity) == "public"
 554     end
 555
 556     test "respects visibility=private" do
 557       user = insert(:user)
 558
 559       {:ok, activity} =
 560         CommonAPI.listen(user, %{
 561           "title" => "lain radio episode 1",
 562           "album" => "lain radio",
 563           "artist" => "lain",
 564           "length" => 180_000,
 565           "visibility" => "private"
 566         })
 567
 568       object = Object.normalize(activity)
 569
 570       assert object.data["title"] == "lain radio episode 1"
 571
 572       assert Visibility.get_visibility(activity) == "private"
 573     end
 574   end
 575 end