git.squeep.com Git - akkoma/blob - test/web/admin_api/controllers/chat_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.ChatControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   import Pleroma.Factory
   9
  10   alias Pleroma.Chat
  11   alias Pleroma.Chat.MessageReference
  12   alias Pleroma.Config
  13   alias Pleroma.ModerationLog
  14   alias Pleroma.Object
  15   alias Pleroma.Repo
  16   alias Pleroma.Web.CommonAPI
  17
  18   setup do
  19     admin = insert(:user, is_admin: true)
  20     token = insert(:oauth_admin_token, user: admin)
  21
  22     conn =
  23       build_conn()
  24       |> assign(:user, admin)
  25       |> assign(:token, token)
  26
  27     {:ok, %{admin: admin, token: token, conn: conn}}
  28   end
  29
  30   describe "DELETE /api/pleroma/admin/chats/:id/messages/:message_id" do
  31     test "it deletes a message from the chat", %{conn: conn, admin: admin} do
  32       user = insert(:user)
  33       recipient = insert(:user)
  34
  35       {:ok, message} =
  36         CommonAPI.post_chat_message(user, recipient, "Hello darkness my old friend")
  37
  38       object = Object.normalize(message, false)
  39
  40       chat = Chat.get(user.id, recipient.ap_id)
  41
  42       cm_ref = MessageReference.for_chat_and_object(chat, object)
  43
  44       result =
  45         conn
  46         |> put_req_header("content-type", "application/json")
  47         |> delete("/api/pleroma/admin/chats/#{chat.id}/messages/#{cm_ref.id}")
  48         |> json_response_and_validate_schema(200)
  49
  50       log_entry = Repo.one(ModerationLog)
  51
  52       assert ModerationLog.get_log_entry_message(log_entry) ==
  53                "@#{admin.nickname} deleted chat message ##{cm_ref.id}"
  54
  55       assert result["id"] == cm_ref.id
  56       refute MessageReference.get_by_id(cm_ref.id)
  57       assert %{data: %{"type" => "Tombstone"}} = Object.get_by_id(object.id)
  58     end
  59   end
  60
  61   describe "GET /api/pleroma/admin/chats/:id/messages" do
  62     test "it paginates", %{conn: conn} do
  63       user = insert(:user)
  64       recipient = insert(:user)
  65
  66       Enum.each(1..30, fn _ ->
  67         {:ok, _} = CommonAPI.post_chat_message(user, recipient, "hey")
  68       end)
  69
  70       chat = Chat.get(user.id, recipient.ap_id)
  71
  72       result =
  73         conn
  74         |> get("/api/pleroma/admin/chats/#{chat.id}/messages")
  75         |> json_response_and_validate_schema(200)
  76
  77       assert length(result) == 20
  78
  79       result =
  80         conn
  81         |> get("/api/pleroma/admin/chats/#{chat.id}/messages?max_id=#{List.last(result)["id"]}")
  82         |> json_response_and_validate_schema(200)
  83
  84       assert length(result) == 10
  85     end
  86
  87     test "it returns the messages for a given chat", %{conn: conn} do
  88       user = insert(:user)
  89       other_user = insert(:user)
  90       third_user = insert(:user)
  91
  92       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "hey")
  93       {:ok, _} = CommonAPI.post_chat_message(user, third_user, "hey")
  94       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "how are you?")
  95       {:ok, _} = CommonAPI.post_chat_message(other_user, user, "fine, how about you?")
  96
  97       chat = Chat.get(user.id, other_user.ap_id)
  98
  99       result =
 100         conn
 101         |> get("/api/pleroma/admin/chats/#{chat.id}/messages")
 102         |> json_response_and_validate_schema(200)
 103
 104       result
 105       |> Enum.each(fn message ->
 106         assert message["chat_id"] == chat.id |> to_string()
 107       end)
 108
 109       assert length(result) == 3
 110     end
 111   end
 112
 113   describe "GET /api/pleroma/admin/chats/:id" do
 114     test "it returns a chat", %{conn: conn} do
 115       user = insert(:user)
 116       other_user = insert(:user)
 117
 118       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 119
 120       result =
 121         conn
 122         |> get("/api/pleroma/admin/chats/#{chat.id}")
 123         |> json_response_and_validate_schema(200)
 124
 125       assert result["id"] == to_string(chat.id)
 126       assert %{} = result["sender"]
 127       assert %{} = result["receiver"]
 128       refute result["account"]
 129     end
 130   end
 131 end