git.squeep.com Git - akkoma/blob - test/web/activity_pub/views/user_view_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserViewTest do
   6   use Pleroma.DataCase
   7   import Pleroma.Factory
   8
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.UserView
  11   alias Pleroma.Web.CommonAPI
  12
  13   test "Renders a user, including the public key" do
  14     user = insert(:user)
  15     {:ok, user} = User.ensure_keys_present(user)
  16
  17     result = UserView.render("user.json", %{user: user})
  18
  19     assert result["id"] == user.ap_id
  20     assert result["preferredUsername"] == user.nickname
  21
  22     assert String.contains?(result["publicKey"]["publicKeyPem"], "BEGIN PUBLIC KEY")
  23   end
  24
  25   test "Renders profile fields" do
  26     fields = [
  27       %{"name" => "foo", "value" => "bar"}
  28     ]
  29
  30     {:ok, user} =
  31       insert(:user)
  32       |> User.upgrade_changeset(%{fields: fields})
  33       |> User.update_and_set_cache()
  34
  35     assert %{
  36              "attachment" => [%{"name" => "foo", "type" => "PropertyValue", "value" => "bar"}]
  37            } = UserView.render("user.json", %{user: user})
  38   end
  39
  40   test "Renders with emoji tags" do
  41     user = insert(:user, emoji: [%{"bib" => "/test"}])
  42
  43     assert %{
  44              "tag" => [
  45                %{
  46                  "icon" => %{"type" => "Image", "url" => "/test"},
  47                  "id" => "/test",
  48                  "name" => ":bib:",
  49                  "type" => "Emoji",
  50                  "updated" => "1970-01-01T00:00:00Z"
  51                }
  52              ]
  53            } = UserView.render("user.json", %{user: user})
  54   end
  55
  56   test "Does not add an avatar image if the user hasn't set one" do
  57     user = insert(:user)
  58     {:ok, user} = User.ensure_keys_present(user)
  59
  60     result = UserView.render("user.json", %{user: user})
  61     refute result["icon"]
  62     refute result["image"]
  63
  64     user =
  65       insert(:user,
  66         avatar: %{"url" => [%{"href" => "https://someurl"}]},
  67         banner: %{"url" => [%{"href" => "https://somebanner"}]}
  68       )
  69
  70     {:ok, user} = User.ensure_keys_present(user)
  71
  72     result = UserView.render("user.json", %{user: user})
  73     assert result["icon"]["url"] == "https://someurl"
  74     assert result["image"]["url"] == "https://somebanner"
  75   end
  76
  77   describe "endpoints" do
  78     test "local users have a usable endpoints structure" do
  79       user = insert(:user)
  80       {:ok, user} = User.ensure_keys_present(user)
  81
  82       result = UserView.render("user.json", %{user: user})
  83
  84       assert result["id"] == user.ap_id
  85
  86       %{
  87         "sharedInbox" => _,
  88         "oauthAuthorizationEndpoint" => _,
  89         "oauthRegistrationEndpoint" => _,
  90         "oauthTokenEndpoint" => _
  91       } = result["endpoints"]
  92     end
  93
  94     test "remote users have an empty endpoints structure" do
  95       user = insert(:user, local: false)
  96       {:ok, user} = User.ensure_keys_present(user)
  97
  98       result = UserView.render("user.json", %{user: user})
  99
 100       assert result["id"] == user.ap_id
 101       assert result["endpoints"] == %{}
 102     end
 103
 104     test "instance users do not expose oAuth endpoints" do
 105       user = insert(:user, nickname: nil, local: true)
 106       {:ok, user} = User.ensure_keys_present(user)
 107
 108       result = UserView.render("user.json", %{user: user})
 109
 110       refute result["endpoints"]["oauthAuthorizationEndpoint"]
 111       refute result["endpoints"]["oauthRegistrationEndpoint"]
 112       refute result["endpoints"]["oauthTokenEndpoint"]
 113     end
 114   end
 115
 116   describe "followers" do
 117     test "sets totalItems to zero when followers are hidden" do
 118       user = insert(:user)
 119       other_user = insert(:user)
 120       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 121       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 122       user = Map.merge(user, %{hide_followers_count: true, hide_followers: true})
 123       assert %{"totalItems" => 0} = UserView.render("followers.json", %{user: user})
 124     end
 125
 126     test "sets correct totalItems when followers are hidden but the follower counter is not" do
 127       user = insert(:user)
 128       other_user = insert(:user)
 129       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 130       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 131       user = Map.merge(user, %{hide_followers_count: false, hide_followers: true})
 132       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 133     end
 134   end
 135
 136   describe "following" do
 137     test "sets totalItems to zero when follows are hidden" do
 138       user = insert(:user)
 139       other_user = insert(:user)
 140       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 141       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 142       user = Map.merge(user, %{hide_follows_count: true, hide_follows: true})
 143       assert %{"totalItems" => 0} = UserView.render("following.json", %{user: user})
 144     end
 145
 146     test "sets correct totalItems when follows are hidden but the follow counter is not" do
 147       user = insert(:user)
 148       other_user = insert(:user)
 149       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 150       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 151       user = Map.merge(user, %{hide_follows_count: false, hide_follows: true})
 152       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 153     end
 154   end
 155
 156   test "activity collection page aginates correctly" do
 157     user = insert(:user)
 158
 159     posts =
 160       for i <- 0..25 do
 161         {:ok, activity} = CommonAPI.post(user, %{"status" => "post #{i}"})
 162         activity
 163       end
 164
 165     # outbox sorts chronologically, newest first, with ten per page
 166     posts = Enum.reverse(posts)
 167
 168     %{"next" => next_url} =
 169       UserView.render("activity_collection_page.json", %{
 170         iri: "#{user.ap_id}/outbox",
 171         activities: Enum.take(posts, 10)
 172       })
 173
 174     next_id = Enum.at(posts, 9).id
 175     assert next_url =~ next_id
 176
 177     %{"next" => next_url} =
 178       UserView.render("activity_collection_page.json", %{
 179         iri: "#{user.ap_id}/outbox",
 180         activities: Enum.take(Enum.drop(posts, 10), 10)
 181       })
 182
 183     next_id = Enum.at(posts, 19).id
 184     assert next_url =~ next_id
 185   end
 186 end