git.squeep.com Git - akkoma/blob - test/web/activity_pub/views/user_view_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserViewTest do
   6   use Pleroma.DataCase
   7   import Pleroma.Factory
   8
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.UserView
  11   alias Pleroma.Web.CommonAPI
  12
  13   test "Renders a user, including the public key" do
  14     user = insert(:user)
  15     {:ok, user} = User.ensure_keys_present(user)
  16
  17     result = UserView.render("user.json", %{user: user})
  18
  19     assert result["id"] == user.ap_id
  20     assert result["preferredUsername"] == user.nickname
  21
  22     assert String.contains?(result["publicKey"]["publicKeyPem"], "BEGIN PUBLIC KEY")
  23   end
  24
  25   test "Renders profile fields" do
  26     fields = [
  27       %{"name" => "foo", "value" => "bar"}
  28     ]
  29
  30     {:ok, user} =
  31       insert(:user)
  32       |> User.upgrade_changeset(%{info: %{fields: fields}})
  33       |> User.update_and_set_cache()
  34
  35     assert %{
  36              "attachment" => [%{"name" => "foo", "type" => "PropertyValue", "value" => "bar"}]
  37            } = UserView.render("user.json", %{user: user})
  38   end
  39
  40   test "Renders with emoji tags" do
  41     user = insert(:user, %{info: %{emoji: [%{"bib" => "/test"}]}})
  42
  43     assert %{
  44              "tag" => [
  45                %{
  46                  "icon" => %{"type" => "Image", "url" => "/test"},
  47                  "id" => "/test",
  48                  "name" => ":bib:",
  49                  "type" => "Emoji",
  50                  "updated" => "1970-01-01T00:00:00Z"
  51                }
  52              ]
  53            } = UserView.render("user.json", %{user: user})
  54   end
  55
  56   test "Does not add an avatar image if the user hasn't set one" do
  57     user = insert(:user)
  58     {:ok, user} = User.ensure_keys_present(user)
  59
  60     result = UserView.render("user.json", %{user: user})
  61     refute result["icon"]
  62     refute result["image"]
  63
  64     user =
  65       insert(:user,
  66         avatar: %{"url" => [%{"href" => "https://someurl"}]},
  67         info: %{
  68           banner: %{"url" => [%{"href" => "https://somebanner"}]}
  69         }
  70       )
  71
  72     {:ok, user} = User.ensure_keys_present(user)
  73
  74     result = UserView.render("user.json", %{user: user})
  75     assert result["icon"]["url"] == "https://someurl"
  76     assert result["image"]["url"] == "https://somebanner"
  77   end
  78
  79   describe "endpoints" do
  80     test "local users have a usable endpoints structure" do
  81       user = insert(:user)
  82       {:ok, user} = User.ensure_keys_present(user)
  83
  84       result = UserView.render("user.json", %{user: user})
  85
  86       assert result["id"] == user.ap_id
  87
  88       %{
  89         "sharedInbox" => _,
  90         "oauthAuthorizationEndpoint" => _,
  91         "oauthRegistrationEndpoint" => _,
  92         "oauthTokenEndpoint" => _
  93       } = result["endpoints"]
  94     end
  95
  96     test "remote users have an empty endpoints structure" do
  97       user = insert(:user, local: false)
  98       {:ok, user} = User.ensure_keys_present(user)
  99
 100       result = UserView.render("user.json", %{user: user})
 101
 102       assert result["id"] == user.ap_id
 103       assert result["endpoints"] == %{}
 104     end
 105
 106     test "instance users do not expose oAuth endpoints" do
 107       user = insert(:user, nickname: nil, local: true)
 108       {:ok, user} = User.ensure_keys_present(user)
 109
 110       result = UserView.render("user.json", %{user: user})
 111
 112       refute result["endpoints"]["oauthAuthorizationEndpoint"]
 113       refute result["endpoints"]["oauthRegistrationEndpoint"]
 114       refute result["endpoints"]["oauthTokenEndpoint"]
 115     end
 116   end
 117
 118   describe "followers" do
 119     test "sets totalItems to zero when followers are hidden" do
 120       user = insert(:user)
 121       other_user = insert(:user)
 122       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 123       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 124       info = Map.merge(user.info, %{hide_followers_count: true, hide_followers: true})
 125       user = Map.put(user, :info, info)
 126       assert %{"totalItems" => 0} = UserView.render("followers.json", %{user: user})
 127     end
 128
 129     test "sets correct totalItems when followers are hidden but the follower counter is not" do
 130       user = insert(:user)
 131       other_user = insert(:user)
 132       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 133       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 134       info = Map.merge(user.info, %{hide_followers_count: false, hide_followers: true})
 135       user = Map.put(user, :info, info)
 136       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 137     end
 138   end
 139
 140   describe "following" do
 141     test "sets totalItems to zero when follows are hidden" do
 142       user = insert(:user)
 143       other_user = insert(:user)
 144       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 145       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 146       info = Map.merge(user.info, %{hide_follows_count: true, hide_follows: true})
 147       user = Map.put(user, :info, info)
 148       assert %{"totalItems" => 0} = UserView.render("following.json", %{user: user})
 149     end
 150
 151     test "sets correct totalItems when follows are hidden but the follow counter is not" do
 152       user = insert(:user)
 153       other_user = insert(:user)
 154       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 155       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 156       info = Map.merge(user.info, %{hide_follows_count: false, hide_follows: true})
 157       user = Map.put(user, :info, info)
 158       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 159     end
 160   end
 161
 162   test "activity collection page aginates correctly" do
 163     user = insert(:user)
 164
 165     posts =
 166       for i <- 0..25 do
 167         {:ok, activity} = CommonAPI.post(user, %{"status" => "post #{i}"})
 168         activity
 169       end
 170
 171     # outbox sorts chronologically, newest first, with ten per page
 172     posts = Enum.reverse(posts)
 173
 174     %{"next" => next_url} =
 175       UserView.render("activity_collection_page.json", %{
 176         iri: "#{user.ap_id}/outbox",
 177         activities: Enum.take(posts, 10)
 178       })
 179
 180     next_id = Enum.at(posts, 9).id
 181     assert next_url =~ next_id
 182
 183     %{"next" => next_url} =
 184       UserView.render("activity_collection_page.json", %{
 185         iri: "#{user.ap_id}/outbox",
 186         activities: Enum.take(Enum.drop(posts, 10), 10)
 187       })
 188
 189     next_id = Enum.at(posts, 19).id
 190     assert next_url =~ next_id
 191   end
 192 end