git.squeep.com Git - akkoma/blob - test/web/activity_pub/views/user_view_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserViewTest do
   6   use Pleroma.DataCase
   7   import Pleroma.Factory
   8
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.UserView
  11   alias Pleroma.Web.CommonAPI
  12
  13   test "Renders a user, including the public key" do
  14     user = insert(:user)
  15     {:ok, user} = User.ensure_keys_present(user)
  16
  17     result = UserView.render("user.json", %{user: user})
  18
  19     assert result["id"] == user.ap_id
  20     assert result["preferredUsername"] == user.nickname
  21
  22     assert String.contains?(result["publicKey"]["publicKeyPem"], "BEGIN PUBLIC KEY")
  23   end
  24
  25   test "Does not add an avatar image if the user hasn't set one" do
  26     user = insert(:user)
  27     {:ok, user} = User.ensure_keys_present(user)
  28
  29     result = UserView.render("user.json", %{user: user})
  30     refute result["icon"]
  31     refute result["image"]
  32
  33     user =
  34       insert(:user,
  35         avatar: %{"url" => [%{"href" => "https://someurl"}]},
  36         info: %{
  37           banner: %{"url" => [%{"href" => "https://somebanner"}]}
  38         }
  39       )
  40
  41     {:ok, user} = User.ensure_keys_present(user)
  42
  43     result = UserView.render("user.json", %{user: user})
  44     assert result["icon"]["url"] == "https://someurl"
  45     assert result["image"]["url"] == "https://somebanner"
  46   end
  47
  48   describe "endpoints" do
  49     test "local users have a usable endpoints structure" do
  50       user = insert(:user)
  51       {:ok, user} = User.ensure_keys_present(user)
  52
  53       result = UserView.render("user.json", %{user: user})
  54
  55       assert result["id"] == user.ap_id
  56
  57       %{
  58         "sharedInbox" => _,
  59         "oauthAuthorizationEndpoint" => _,
  60         "oauthRegistrationEndpoint" => _,
  61         "oauthTokenEndpoint" => _
  62       } = result["endpoints"]
  63     end
  64
  65     test "remote users have an empty endpoints structure" do
  66       user = insert(:user, local: false)
  67       {:ok, user} = User.ensure_keys_present(user)
  68
  69       result = UserView.render("user.json", %{user: user})
  70
  71       assert result["id"] == user.ap_id
  72       assert result["endpoints"] == %{}
  73     end
  74
  75     test "instance users do not expose oAuth endpoints" do
  76       user = insert(:user, nickname: nil, local: true)
  77       {:ok, user} = User.ensure_keys_present(user)
  78
  79       result = UserView.render("user.json", %{user: user})
  80
  81       refute result["endpoints"]["oauthAuthorizationEndpoint"]
  82       refute result["endpoints"]["oauthRegistrationEndpoint"]
  83       refute result["endpoints"]["oauthTokenEndpoint"]
  84     end
  85   end
  86
  87   describe "followers" do
  88     test "sets totalItems to zero when followers are hidden" do
  89       user = insert(:user)
  90       other_user = insert(:user)
  91       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
  92       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
  93       info = Map.put(user.info, :hide_followers, true)
  94       user = Map.put(user, :info, info)
  95       assert %{"totalItems" => 0} = UserView.render("followers.json", %{user: user})
  96     end
  97   end
  98
  99   describe "following" do
 100     test "sets totalItems to zero when follows are hidden" do
 101       user = insert(:user)
 102       other_user = insert(:user)
 103       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 104       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 105       info = Map.put(user.info, :hide_follows, true)
 106       user = Map.put(user, :info, info)
 107       assert %{"totalItems" => 0} = UserView.render("following.json", %{user: user})
 108     end
 109   end
 110 end