git.squeep.com Git - akkoma/blob - test/web/activity_pub/transmogrifier_test.exs

   1 defmodule Pleroma.Web.ActivityPub.TransmogrifierTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Activity
   5   alias Pleroma.User
   6   alias Pleroma.Repo
   7   alias Pleroma.Web.Websub.WebsubClientSubscription
   8   alias Pleroma.Web.Websub.WebsubServerSubscription
   9   import Ecto.Query
  10
  11   import Pleroma.Factory
  12   alias Pleroma.Web.CommonAPI
  13
  14   describe "handle_incoming" do
  15     test "it ignores an incoming notice if we already have it" do
  16       activity = insert(:note_activity)
  17
  18       data = File.read!("test/fixtures/mastodon-post-activity.json")
  19       |> Poison.decode!
  20       |> Map.put("object", activity.data["object"])
  21
  22       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  23
  24       assert activity == returned_activity
  25     end
  26
  27     test "it fetches replied-to activities if we don't have them" do
  28       data = File.read!("test/fixtures/mastodon-post-activity.json")
  29       |> Poison.decode!
  30
  31       object = data["object"]
  32       |> Map.put("inReplyTo", "https://shitposter.club/notice/2827873")
  33
  34       data = data
  35       |> Map.put("object", object)
  36
  37       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  38
  39       assert activity = Activity.get_create_activity_by_object_ap_id("tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment")
  40       assert returned_activity.data["object"]["inReplyToAtomUri"] == "https://shitposter.club/notice/2827873"
  41       assert returned_activity.data["object"]["inReplyToStatusId"] == activity.id
  42     end
  43
  44     test "it works if the activity id isn't an url but an atom-uri is given" do
  45       data = File.read!("test/fixtures/mastodon-post-activity.json")
  46       |> Poison.decode!
  47
  48       object = data["object"]
  49       |> Map.put("inReplyToAtomUri", "https://shitposter.club/notice/2827873")
  50       |> Map.put("inReplyTo", "tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment")
  51
  52       data = data
  53       |> Map.put("object", object)
  54
  55       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  56
  57       assert activity = Activity.get_create_activity_by_object_ap_id("tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment")
  58       assert returned_activity.data["object"]["inReplyToAtomUri"] == "https://shitposter.club/notice/2827873"
  59       assert returned_activity.data["object"]["inReplyToStatusId"] == activity.id
  60     end
  61
  62     test "it works for incoming notices" do
  63       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!
  64
  65       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
  66       assert data["id"] == "http://mastodon.example.org/users/admin/statuses/99512778738411822/activity"
  67       assert data["context"] == "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
  68       assert data["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
  69       assert data["cc"] == [
  70         "http://mastodon.example.org/users/admin/followers",
  71         "http://localtesting.pleroma.lol/users/lain"
  72       ]
  73       assert data["actor"] == "http://mastodon.example.org/users/admin"
  74
  75       object = data["object"]
  76       assert object["id"] == "http://mastodon.example.org/users/admin/statuses/99512778738411822"
  77
  78       assert object["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
  79       assert object["cc"] == [
  80         "http://mastodon.example.org/users/admin/followers",
  81         "http://localtesting.pleroma.lol/users/lain"
  82       ]
  83       assert object["actor"] == "http://mastodon.example.org/users/admin"
  84       assert object["attributedTo"] == "http://mastodon.example.org/users/admin"
  85       assert object["context"] == "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
  86       assert object["sensitive"] == true
  87     end
  88
  89     test "it works for incoming follow requests" do
  90       user = insert(:user)
  91       data = File.read!("test/fixtures/mastodon-follow-activity.json") |> Poison.decode!
  92       |> Map.put("object", user.ap_id)
  93
  94       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
  95
  96       assert data["actor"] == "http://mastodon.example.org/users/admin"
  97       assert data["type"] == "Follow"
  98       assert data["id"] == "http://mastodon.example.org/users/admin#follows/2"
  99       assert User.following?(User.get_by_ap_id(data["actor"]), user)
 100     end
 101
 102     test "it works for incoming likes" do
 103       user = insert(:user)
 104       {:ok, activity} = CommonAPI.post(user, %{"status" => "hello"})
 105
 106       data = File.read!("test/fixtures/mastodon-like.json") |> Poison.decode!
 107       |> Map.put("object", activity.data["object"]["id"])
 108
 109       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 110
 111       assert data["actor"] == "http://mastodon.example.org/users/admin"
 112       assert data["type"] == "Like"
 113       assert data["id"] == "http://mastodon.example.org/users/admin#likes/2"
 114       assert data["object"] == activity.data["object"]["id"]
 115     end
 116
 117     test "it works for incoming announces" do
 118       data = File.read!("test/fixtures/mastodon-announce.json") |> Poison.decode!
 119
 120       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 121
 122       assert data["actor"] == "http://mastodon.example.org/users/admin"
 123       assert data["type"] == "Announce"
 124       assert data["id"] == "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 125       assert data["object"] == "http://mastodon.example.org/users/admin/statuses/99541947525187367"
 126
 127       assert Activity.get_create_activity_by_object_ap_id(data["object"])
 128     end
 129
 130     test "it works for incoming announces with an existing activity" do
 131       user = insert(:user)
 132       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 133
 134       data = File.read!("test/fixtures/mastodon-announce.json")
 135       |> Poison.decode!
 136       |> Map.put("object", activity.data["object"]["id"])
 137
 138       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 139
 140       assert data["actor"] == "http://mastodon.example.org/users/admin"
 141       assert data["type"] == "Announce"
 142       assert data["id"] == "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 143       assert data["object"] == activity.data["object"]["id"]
 144
 145       assert Activity.get_create_activity_by_object_ap_id(data["object"]).id == activity.id
 146     end
 147   end
 148
 149   describe "prepare outgoing" do
 150     test "it turns mentions into tags" do
 151       user = insert(:user)
 152       other_user = insert(:user)
 153
 154       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey, @#{other_user.nickname}, how are ya? #2hu"})
 155
 156       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 157       object = modified["object"]
 158
 159       expected_mention = %{
 160         "href" => other_user.ap_id,
 161         "name" => "@#{other_user.nickname}",
 162         "type" => "Mention"
 163       }
 164
 165       expected_tag = %{
 166         "href" => Pleroma.Web.Endpoint.url <> "/tags/2hu",
 167         "type" => "Hashtag",
 168         "name" => "#2hu"
 169       }
 170
 171       assert Enum.member?(object["tag"], expected_tag)
 172       assert Enum.member?(object["tag"], expected_mention)
 173     end
 174
 175     test "it adds the sensitive property" do
 176       user = insert(:user)
 177
 178       {:ok, activity} = CommonAPI.post(user, %{"status" => "#nsfw hey"})
 179       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 180
 181       assert modified["object"]["sensitive"]
 182     end
 183
 184     test "it adds the json-ld context and the conversation property" do
 185       user = insert(:user)
 186
 187       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 188       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 189
 190       assert modified["@context"] == "https://www.w3.org/ns/activitystreams"
 191       assert modified["object"]["conversation"] == modified["context"]
 192     end
 193
 194     test "it sets the 'attributedTo' property to the actor of the object if it doesn't have one" do
 195       user = insert(:user)
 196
 197       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 198       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 199
 200       assert modified["object"]["actor"] == modified["object"]["attributedTo"]
 201     end
 202   end
 203
 204   describe "user upgrade" do
 205     test "it upgrades a user to activitypub" do
 206       user = insert(:user, %{nickname: "rye@niu.moe", local: false, ap_id: "https://niu.moe/users/rye", follower_address: User.ap_followers(%User{nickname: "rye@niu.moe"})})
 207       user_two = insert(:user, %{following: [user.follower_address]})
 208
 209       {:ok, activity} = CommonAPI.post(user, %{"status" => "test"})
 210       {:ok, unrelated_activity} = CommonAPI.post(user_two, %{"status" => "test"})
 211       assert "http://localhost:4001/users/rye@niu.moe/followers" in activity.recipients
 212
 213       user = Repo.get(User, user.id)
 214       assert user.info["note_count"] == 1
 215
 216       {:ok, user} = Transmogrifier.upgrade_user_from_ap_id("https://niu.moe/users/rye")
 217       assert user.info["ap_enabled"]
 218       assert user.info["note_count"] == 1
 219       assert user.follower_address == "https://niu.moe/users/rye/followers"
 220
 221       # Wait for the background task
 222       :timer.sleep(1000)
 223
 224       user = Repo.get(User, user.id)
 225       assert user.info["note_count"] == 1
 226
 227       activity = Repo.get(Activity, activity.id)
 228       assert user.follower_address in activity.recipients
 229       assert %{"url" => [%{"href" => "https://cdn.niu.moe/accounts/avatars/000/033/323/original/fd7f8ae0b3ffedc9.jpeg"}]} = user.avatar
 230       assert %{"url" => [%{"href" => "https://cdn.niu.moe/accounts/headers/000/033/323/original/850b3448fa5fd477.png"}]} = user.info["banner"]
 231       refute "..." in activity.recipients
 232
 233       unrelated_activity = Repo.get(Activity, unrelated_activity.id)
 234       refute user.follower_address in unrelated_activity.recipients
 235
 236       user_two = Repo.get(User, user_two.id)
 237       assert user.follower_address in user_two.following
 238       refute "..." in user_two.following
 239     end
 240   end
 241
 242   describe "maybe_retire_websub" do
 243     test "it deletes all websub client subscripitions with the user as topic" do
 244       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/rye.atom"}
 245       {:ok, ws} = Repo.insert(subscription)
 246
 247       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/pasty.atom"}
 248       {:ok, ws2} = Repo.insert(subscription)
 249
 250       Transmogrifier.maybe_retire_websub("https://niu.moe/users/rye")
 251
 252       refute Repo.get(WebsubClientSubscription, ws.id)
 253       assert Repo.get(WebsubClientSubscription, ws2.id)
 254     end
 255
 256     test "it deletes all websub server subscriptions with the server as callback" do
 257       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/rye.atom"}
 258       {:ok, ws} = Repo.insert(subscription)
 259
 260       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/pasty.atom"}
 261       {:ok, ws2} = Repo.insert(subscription)
 262
 263       Transmogrifier.maybe_retire_websub("https://niu.moe/users/rye")
 264
 265       refute Repo.get(WebsubClientSubscription, ws.id)
 266       assert Repo.get(WebsubClientSubscription, ws2.id)
 267     end
 268   end
 269 end