git.squeep.com Git - akkoma/blob - test/web/activity_pub/transmogrifier_test.exs

   1 defmodule Pleroma.Web.ActivityPub.TransmogrifierTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Web.OStatus
   5   alias Pleroma.Activity
   6   alias Pleroma.User
   7   alias Pleroma.Repo
   8   alias Pleroma.Web.Websub.WebsubClientSubscription
   9   alias Pleroma.Web.Websub.WebsubServerSubscription
  10   import Ecto.Query
  11
  12   import Pleroma.Factory
  13   alias Pleroma.Web.CommonAPI
  14
  15   describe "handle_incoming" do
  16     test "it ignores an incoming notice if we already have it" do
  17       activity = insert(:note_activity)
  18
  19       data =
  20         File.read!("test/fixtures/mastodon-post-activity.json")
  21         |> Poison.decode!()
  22         |> Map.put("object", activity.data["object"])
  23
  24       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  25
  26       assert activity == returned_activity
  27     end
  28
  29     test "it fetches replied-to activities if we don't have them" do
  30       data =
  31         File.read!("test/fixtures/mastodon-post-activity.json")
  32         |> Poison.decode!()
  33
  34       object =
  35         data["object"]
  36         |> Map.put("inReplyTo", "https://shitposter.club/notice/2827873")
  37
  38       data =
  39         data
  40         |> Map.put("object", object)
  41
  42       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  43
  44       assert activity =
  45                Activity.get_create_activity_by_object_ap_id(
  46                  "tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment"
  47                )
  48
  49       assert returned_activity.data["object"]["inReplyToAtomUri"] ==
  50                "https://shitposter.club/notice/2827873"
  51
  52       assert returned_activity.data["object"]["inReplyToStatusId"] == activity.id
  53     end
  54
  55     test "it works for incoming notices" do
  56       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
  57
  58       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
  59
  60       assert data["id"] ==
  61                "http://mastodon.example.org/users/admin/statuses/99512778738411822/activity"
  62
  63       assert data["context"] ==
  64                "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
  65
  66       assert data["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
  67
  68       assert data["cc"] == [
  69                "http://mastodon.example.org/users/admin/followers",
  70                "http://localtesting.pleroma.lol/users/lain"
  71              ]
  72
  73       assert data["actor"] == "http://mastodon.example.org/users/admin"
  74
  75       object = data["object"]
  76       assert object["id"] == "http://mastodon.example.org/users/admin/statuses/99512778738411822"
  77
  78       assert object["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
  79
  80       assert object["cc"] == [
  81                "http://mastodon.example.org/users/admin/followers",
  82                "http://localtesting.pleroma.lol/users/lain"
  83              ]
  84
  85       assert object["actor"] == "http://mastodon.example.org/users/admin"
  86       assert object["attributedTo"] == "http://mastodon.example.org/users/admin"
  87
  88       assert object["context"] ==
  89                "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
  90
  91       assert object["sensitive"] == true
  92     end
  93
  94     test "it works for incoming notices with hashtags" do
  95       data = File.read!("test/fixtures/mastodon-post-activity-hashtag.json") |> Poison.decode!()
  96
  97       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
  98       assert Enum.at(data["object"]["tag"], 2) == "moo"
  99     end
 100
 101     test "it works for incoming follow requests" do
 102       user = insert(:user)
 103
 104       data =
 105         File.read!("test/fixtures/mastodon-follow-activity.json")
 106         |> Poison.decode!()
 107         |> Map.put("object", user.ap_id)
 108
 109       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 110
 111       assert data["actor"] == "http://mastodon.example.org/users/admin"
 112       assert data["type"] == "Follow"
 113       assert data["id"] == "http://mastodon.example.org/users/admin#follows/2"
 114       assert User.following?(User.get_by_ap_id(data["actor"]), user)
 115     end
 116
 117     test "it works for incoming likes" do
 118       user = insert(:user)
 119       {:ok, activity} = CommonAPI.post(user, %{"status" => "hello"})
 120
 121       data =
 122         File.read!("test/fixtures/mastodon-like.json")
 123         |> Poison.decode!()
 124         |> Map.put("object", activity.data["object"]["id"])
 125
 126       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 127
 128       assert data["actor"] == "http://mastodon.example.org/users/admin"
 129       assert data["type"] == "Like"
 130       assert data["id"] == "http://mastodon.example.org/users/admin#likes/2"
 131       assert data["object"] == activity.data["object"]["id"]
 132     end
 133
 134     test "it works for incoming announces" do
 135       data = File.read!("test/fixtures/mastodon-announce.json") |> Poison.decode!()
 136
 137       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 138
 139       assert data["actor"] == "http://mastodon.example.org/users/admin"
 140       assert data["type"] == "Announce"
 141
 142       assert data["id"] ==
 143                "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 144
 145       assert data["object"] ==
 146                "http://mastodon.example.org/users/admin/statuses/99541947525187367"
 147
 148       assert Activity.get_create_activity_by_object_ap_id(data["object"])
 149     end
 150
 151     test "it works for incoming announces with an existing activity" do
 152       user = insert(:user)
 153       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 154
 155       data =
 156         File.read!("test/fixtures/mastodon-announce.json")
 157         |> Poison.decode!()
 158         |> Map.put("object", activity.data["object"]["id"])
 159
 160       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 161
 162       assert data["actor"] == "http://mastodon.example.org/users/admin"
 163       assert data["type"] == "Announce"
 164
 165       assert data["id"] ==
 166                "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 167
 168       assert data["object"] == activity.data["object"]["id"]
 169
 170       assert Activity.get_create_activity_by_object_ap_id(data["object"]).id == activity.id
 171     end
 172
 173     test "it works for incoming update activities" do
 174       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
 175
 176       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 177       update_data = File.read!("test/fixtures/mastodon-update.json") |> Poison.decode!()
 178
 179       object =
 180         update_data["object"]
 181         |> Map.put("actor", data["actor"])
 182         |> Map.put("id", data["actor"])
 183
 184       update_data =
 185         update_data
 186         |> Map.put("actor", data["actor"])
 187         |> Map.put("object", object)
 188
 189       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(update_data)
 190
 191       user = User.get_cached_by_ap_id(data["actor"])
 192       assert user.name == "gargle"
 193
 194       assert user.avatar["url"] == [
 195                %{
 196                  "href" =>
 197                    "https://cd.niu.moe/accounts/avatars/000/033/323/original/fd7f8ae0b3ffedc9.jpeg"
 198                }
 199              ]
 200
 201       assert user.info["banner"]["url"] == [
 202                %{
 203                  "href" =>
 204                    "https://cd.niu.moe/accounts/headers/000/033/323/original/850b3448fa5fd477.png"
 205                }
 206              ]
 207
 208       assert user.bio == "<p>Some bio</p>"
 209     end
 210
 211     test "it works for incoming deletes" do
 212       activity = insert(:note_activity)
 213
 214       data =
 215         File.read!("test/fixtures/mastodon-delete.json")
 216         |> Poison.decode!()
 217
 218       object =
 219         data["object"]
 220         |> Map.put("id", activity.data["object"]["id"])
 221
 222       data =
 223         data
 224         |> Map.put("object", object)
 225         |> Map.put("actor", activity.data["actor"])
 226
 227       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 228
 229       refute Repo.get(Activity, activity.id)
 230     end
 231   end
 232
 233   describe "prepare outgoing" do
 234     test "it turns mentions into tags" do
 235       user = insert(:user)
 236       other_user = insert(:user)
 237
 238       {:ok, activity} =
 239         CommonAPI.post(user, %{"status" => "hey, @#{other_user.nickname}, how are ya? #2hu"})
 240
 241       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 242       object = modified["object"]
 243
 244       expected_mention = %{
 245         "href" => other_user.ap_id,
 246         "name" => "@#{other_user.nickname}",
 247         "type" => "Mention"
 248       }
 249
 250       expected_tag = %{
 251         "href" => Pleroma.Web.Endpoint.url() <> "/tags/2hu",
 252         "type" => "Hashtag",
 253         "name" => "#2hu"
 254       }
 255
 256       assert Enum.member?(object["tag"], expected_tag)
 257       assert Enum.member?(object["tag"], expected_mention)
 258     end
 259
 260     test "it adds the sensitive property" do
 261       user = insert(:user)
 262
 263       {:ok, activity} = CommonAPI.post(user, %{"status" => "#nsfw hey"})
 264       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 265
 266       assert modified["object"]["sensitive"]
 267     end
 268
 269     test "it adds the json-ld context and the conversation property" do
 270       user = insert(:user)
 271
 272       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 273       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 274
 275       assert modified["@context"] == "https://www.w3.org/ns/activitystreams"
 276       assert modified["object"]["conversation"] == modified["context"]
 277     end
 278
 279     test "it sets the 'attributedTo' property to the actor of the object if it doesn't have one" do
 280       user = insert(:user)
 281
 282       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 283       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 284
 285       assert modified["object"]["actor"] == modified["object"]["attributedTo"]
 286     end
 287
 288     test "it translates ostatus IDs to external URLs" do
 289       incoming = File.read!("test/fixtures/incoming_note_activity.xml")
 290       {:ok, [referent_activity]} = OStatus.handle_incoming(incoming)
 291
 292       user = insert(:user)
 293
 294       {:ok, activity, _} = CommonAPI.favorite(referent_activity.id, user)
 295       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 296
 297       assert modified["object"] == "http://gs.example.org:4040/index.php/notice/29"
 298     end
 299
 300     test "it translates ostatus reply_to IDs to external URLs" do
 301       incoming = File.read!("test/fixtures/incoming_note_activity.xml")
 302       {:ok, [referred_activity]} = OStatus.handle_incoming(incoming)
 303
 304       user = insert(:user)
 305
 306       {:ok, activity} =
 307         CommonAPI.post(user, %{"status" => "HI!", "in_reply_to_status_id" => referred_activity.id})
 308
 309       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 310
 311       assert modified["object"]["inReplyTo"] == "http://gs.example.org:4040/index.php/notice/29"
 312     end
 313   end
 314
 315   describe "user upgrade" do
 316     test "it upgrades a user to activitypub" do
 317       user =
 318         insert(:user, %{
 319           nickname: "rye@niu.moe",
 320           local: false,
 321           ap_id: "https://niu.moe/users/rye",
 322           follower_address: User.ap_followers(%User{nickname: "rye@niu.moe"})
 323         })
 324
 325       user_two = insert(:user, %{following: [user.follower_address]})
 326
 327       {:ok, activity} = CommonAPI.post(user, %{"status" => "test"})
 328       {:ok, unrelated_activity} = CommonAPI.post(user_two, %{"status" => "test"})
 329       assert "http://localhost:4001/users/rye@niu.moe/followers" in activity.recipients
 330
 331       user = Repo.get(User, user.id)
 332       assert user.info["note_count"] == 1
 333
 334       {:ok, user} = Transmogrifier.upgrade_user_from_ap_id("https://niu.moe/users/rye")
 335       assert user.info["ap_enabled"]
 336       assert user.info["note_count"] == 1
 337       assert user.follower_address == "https://niu.moe/users/rye/followers"
 338
 339       # Wait for the background task
 340       :timer.sleep(1000)
 341
 342       user = Repo.get(User, user.id)
 343       assert user.info["note_count"] == 1
 344
 345       activity = Repo.get(Activity, activity.id)
 346       assert user.follower_address in activity.recipients
 347
 348       assert %{
 349                "url" => [
 350                  %{
 351                    "href" =>
 352                      "https://cdn.niu.moe/accounts/avatars/000/033/323/original/fd7f8ae0b3ffedc9.jpeg"
 353                  }
 354                ]
 355              } = user.avatar
 356
 357       assert %{
 358                "url" => [
 359                  %{
 360                    "href" =>
 361                      "https://cdn.niu.moe/accounts/headers/000/033/323/original/850b3448fa5fd477.png"
 362                  }
 363                ]
 364              } = user.info["banner"]
 365
 366       refute "..." in activity.recipients
 367
 368       unrelated_activity = Repo.get(Activity, unrelated_activity.id)
 369       refute user.follower_address in unrelated_activity.recipients
 370
 371       user_two = Repo.get(User, user_two.id)
 372       assert user.follower_address in user_two.following
 373       refute "..." in user_two.following
 374     end
 375   end
 376
 377   describe "maybe_retire_websub" do
 378     test "it deletes all websub client subscripitions with the user as topic" do
 379       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/rye.atom"}
 380       {:ok, ws} = Repo.insert(subscription)
 381
 382       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/pasty.atom"}
 383       {:ok, ws2} = Repo.insert(subscription)
 384
 385       Transmogrifier.maybe_retire_websub("https://niu.moe/users/rye")
 386
 387       refute Repo.get(WebsubClientSubscription, ws.id)
 388       assert Repo.get(WebsubClientSubscription, ws2.id)
 389     end
 390   end
 391 end