git.squeep.com Git - akkoma/blob - test/web/activity_pub/transmogrifier_test.exs

   1 defmodule Pleroma.Web.ActivityPub.TransmogrifierTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.Transmogrifier
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.OStatus
   6   alias Pleroma.Activity
   7   alias Pleroma.User
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.Websub.WebsubClientSubscription
  10   alias Pleroma.Web.Websub.WebsubServerSubscription
  11   import Ecto.Query
  12
  13   import Pleroma.Factory
  14   alias Pleroma.Web.CommonAPI
  15
  16   describe "handle_incoming" do
  17     test "it ignores an incoming notice if we already have it" do
  18       activity = insert(:note_activity)
  19
  20       data =
  21         File.read!("test/fixtures/mastodon-post-activity.json")
  22         |> Poison.decode!()
  23         |> Map.put("object", activity.data["object"])
  24
  25       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  26
  27       assert activity == returned_activity
  28     end
  29
  30     test "it fetches replied-to activities if we don't have them" do
  31       data =
  32         File.read!("test/fixtures/mastodon-post-activity.json")
  33         |> Poison.decode!()
  34
  35       object =
  36         data["object"]
  37         |> Map.put("inReplyTo", "https://shitposter.club/notice/2827873")
  38
  39       data =
  40         data
  41         |> Map.put("object", object)
  42
  43       {:ok, returned_activity} = Transmogrifier.handle_incoming(data)
  44
  45       assert activity =
  46                Activity.get_create_activity_by_object_ap_id(
  47                  "tag:shitposter.club,2017-05-05:noticeId=2827873:objectType=comment"
  48                )
  49
  50       assert returned_activity.data["object"]["inReplyToAtomUri"] ==
  51                "https://shitposter.club/notice/2827873"
  52
  53       assert returned_activity.data["object"]["inReplyToStatusId"] == activity.id
  54     end
  55
  56     test "it works for incoming notices" do
  57       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
  58
  59       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
  60
  61       assert data["id"] ==
  62                "http://mastodon.example.org/users/admin/statuses/99512778738411822/activity"
  63
  64       assert data["context"] ==
  65                "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
  66
  67       assert data["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
  68
  69       assert data["cc"] == [
  70                "http://mastodon.example.org/users/admin/followers",
  71                "http://localtesting.pleroma.lol/users/lain"
  72              ]
  73
  74       assert data["actor"] == "http://mastodon.example.org/users/admin"
  75
  76       object = data["object"]
  77       assert object["id"] == "http://mastodon.example.org/users/admin/statuses/99512778738411822"
  78
  79       assert object["to"] == ["https://www.w3.org/ns/activitystreams#Public"]
  80
  81       assert object["cc"] == [
  82                "http://mastodon.example.org/users/admin/followers",
  83                "http://localtesting.pleroma.lol/users/lain"
  84              ]
  85
  86       assert object["actor"] == "http://mastodon.example.org/users/admin"
  87       assert object["attributedTo"] == "http://mastodon.example.org/users/admin"
  88
  89       assert object["context"] ==
  90                "tag:mastodon.example.org,2018-02-12:objectId=20:objectType=Conversation"
  91
  92       assert object["sensitive"] == true
  93
  94       user = User.get_by_ap_id(object["actor"])
  95
  96       assert user.info["note_count"] == 1
  97     end
  98
  99     test "it works for incoming notices with hashtags" do
 100       data = File.read!("test/fixtures/mastodon-post-activity-hashtag.json") |> Poison.decode!()
 101
 102       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 103       assert Enum.at(data["object"]["tag"], 2) == "moo"
 104     end
 105
 106     test "it works for incoming follow requests" do
 107       user = insert(:user)
 108
 109       data =
 110         File.read!("test/fixtures/mastodon-follow-activity.json")
 111         |> Poison.decode!()
 112         |> Map.put("object", user.ap_id)
 113
 114       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 115
 116       assert data["actor"] == "http://mastodon.example.org/users/admin"
 117       assert data["type"] == "Follow"
 118       assert data["id"] == "http://mastodon.example.org/users/admin#follows/2"
 119       assert User.following?(User.get_by_ap_id(data["actor"]), user)
 120     end
 121
 122     test "it works for incoming follow requests from hubzilla" do
 123       user = insert(:user)
 124
 125       data =
 126         File.read!("test/fixtures/hubzilla-follow-activity.json")
 127         |> Poison.decode!()
 128         |> Map.put("object", user.ap_id)
 129         |> Utils.normalize_params()
 130
 131       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 132
 133       assert data["actor"] == "https://hubzilla.example.org/channel/kaniini"
 134       assert data["type"] == "Follow"
 135       assert data["id"] == "https://hubzilla.example.org/channel/kaniini#follows/2"
 136       assert User.following?(User.get_by_ap_id(data["actor"]), user)
 137     end
 138
 139     test "it works for incoming likes" do
 140       user = insert(:user)
 141       {:ok, activity} = CommonAPI.post(user, %{"status" => "hello"})
 142
 143       data =
 144         File.read!("test/fixtures/mastodon-like.json")
 145         |> Poison.decode!()
 146         |> Map.put("object", activity.data["object"]["id"])
 147
 148       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 149
 150       assert data["actor"] == "http://mastodon.example.org/users/admin"
 151       assert data["type"] == "Like"
 152       assert data["id"] == "http://mastodon.example.org/users/admin#likes/2"
 153       assert data["object"] == activity.data["object"]["id"]
 154     end
 155
 156     test "it returns an error for incoming unlikes wihout a like activity" do
 157       user = insert(:user)
 158       {:ok, activity} = CommonAPI.post(user, %{"status" => "leave a like pls"})
 159
 160       data =
 161         File.read!("test/fixtures/mastodon-undo-like.json")
 162         |> Poison.decode!()
 163         |> Map.put("object", activity.data["object"]["id"])
 164
 165       assert Transmogrifier.handle_incoming(data) == :error
 166     end
 167
 168     test "it works for incoming unlikes with an existing like activity" do
 169       user = insert(:user)
 170       {:ok, activity} = CommonAPI.post(user, %{"status" => "leave a like pls"})
 171
 172       like_data =
 173         File.read!("test/fixtures/mastodon-like.json")
 174         |> Poison.decode!()
 175         |> Map.put("object", activity.data["object"]["id"])
 176
 177       {:ok, %Activity{data: like_data, local: false}} = Transmogrifier.handle_incoming(like_data)
 178
 179       data =
 180         File.read!("test/fixtures/mastodon-undo-like.json")
 181         |> Poison.decode!()
 182         |> Map.put("object", like_data)
 183         |> Map.put("actor", like_data["actor"])
 184
 185       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 186
 187       assert data["actor"] == "http://mastodon.example.org/users/admin"
 188       assert data["type"] == "Undo"
 189       assert data["id"] == "http://mastodon.example.org/users/admin#likes/2/undo"
 190       assert data["object"]["id"] == "http://mastodon.example.org/users/admin#likes/2"
 191     end
 192
 193     test "it works for incoming announces" do
 194       data = File.read!("test/fixtures/mastodon-announce.json") |> Poison.decode!()
 195
 196       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 197
 198       assert data["actor"] == "http://mastodon.example.org/users/admin"
 199       assert data["type"] == "Announce"
 200
 201       assert data["id"] ==
 202                "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 203
 204       assert data["object"] ==
 205                "http://mastodon.example.org/users/admin/statuses/99541947525187367"
 206
 207       assert Activity.get_create_activity_by_object_ap_id(data["object"])
 208     end
 209
 210     test "it works for incoming announces with an existing activity" do
 211       user = insert(:user)
 212       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 213
 214       data =
 215         File.read!("test/fixtures/mastodon-announce.json")
 216         |> Poison.decode!()
 217         |> Map.put("object", activity.data["object"]["id"])
 218
 219       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 220
 221       assert data["actor"] == "http://mastodon.example.org/users/admin"
 222       assert data["type"] == "Announce"
 223
 224       assert data["id"] ==
 225                "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 226
 227       assert data["object"] == activity.data["object"]["id"]
 228
 229       assert Activity.get_create_activity_by_object_ap_id(data["object"]).id == activity.id
 230     end
 231
 232     test "it works for incoming update activities" do
 233       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
 234
 235       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 236       update_data = File.read!("test/fixtures/mastodon-update.json") |> Poison.decode!()
 237
 238       object =
 239         update_data["object"]
 240         |> Map.put("actor", data["actor"])
 241         |> Map.put("id", data["actor"])
 242
 243       update_data =
 244         update_data
 245         |> Map.put("actor", data["actor"])
 246         |> Map.put("object", object)
 247
 248       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(update_data)
 249
 250       user = User.get_cached_by_ap_id(data["actor"])
 251       assert user.name == "gargle"
 252
 253       assert user.avatar["url"] == [
 254                %{
 255                  "href" =>
 256                    "https://cd.niu.moe/accounts/avatars/000/033/323/original/fd7f8ae0b3ffedc9.jpeg"
 257                }
 258              ]
 259
 260       assert user.info["banner"]["url"] == [
 261                %{
 262                  "href" =>
 263                    "https://cd.niu.moe/accounts/headers/000/033/323/original/850b3448fa5fd477.png"
 264                }
 265              ]
 266
 267       assert user.bio == "<p>Some bio</p>"
 268     end
 269
 270     test "it works for incoming deletes" do
 271       activity = insert(:note_activity)
 272
 273       data =
 274         File.read!("test/fixtures/mastodon-delete.json")
 275         |> Poison.decode!()
 276
 277       object =
 278         data["object"]
 279         |> Map.put("id", activity.data["object"]["id"])
 280
 281       data =
 282         data
 283         |> Map.put("object", object)
 284         |> Map.put("actor", activity.data["actor"])
 285
 286       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 287
 288       refute Repo.get(Activity, activity.id)
 289     end
 290
 291     test "it works for incoming unannounces with an existing notice" do
 292       user = insert(:user)
 293       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 294
 295       announce_data =
 296         File.read!("test/fixtures/mastodon-announce.json")
 297         |> Poison.decode!()
 298         |> Map.put("object", activity.data["object"]["id"])
 299
 300       {:ok, %Activity{data: announce_data, local: false}} =
 301         Transmogrifier.handle_incoming(announce_data)
 302
 303       data =
 304         File.read!("test/fixtures/mastodon-undo-announce.json")
 305         |> Poison.decode!()
 306         |> Map.put("object", announce_data)
 307         |> Map.put("actor", announce_data["actor"])
 308
 309       {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 310
 311       assert data["type"] == "Undo"
 312       assert data["object"]["type"] == "Announce"
 313       assert data["object"]["object"] == activity.data["object"]["id"]
 314
 315       assert data["object"]["id"] ==
 316                "http://mastodon.example.org/users/admin/statuses/99542391527669785/activity"
 317     end
 318   end
 319
 320   describe "prepare outgoing" do
 321     test "it turns mentions into tags" do
 322       user = insert(:user)
 323       other_user = insert(:user)
 324
 325       {:ok, activity} =
 326         CommonAPI.post(user, %{"status" => "hey, @#{other_user.nickname}, how are ya? #2hu"})
 327
 328       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 329       object = modified["object"]
 330
 331       expected_mention = %{
 332         "href" => other_user.ap_id,
 333         "name" => "@#{other_user.nickname}",
 334         "type" => "Mention"
 335       }
 336
 337       expected_tag = %{
 338         "href" => Pleroma.Web.Endpoint.url() <> "/tags/2hu",
 339         "type" => "Hashtag",
 340         "name" => "#2hu"
 341       }
 342
 343       assert Enum.member?(object["tag"], expected_tag)
 344       assert Enum.member?(object["tag"], expected_mention)
 345     end
 346
 347     test "it adds the sensitive property" do
 348       user = insert(:user)
 349
 350       {:ok, activity} = CommonAPI.post(user, %{"status" => "#nsfw hey"})
 351       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 352
 353       assert modified["object"]["sensitive"]
 354     end
 355
 356     test "it adds the json-ld context and the conversation property" do
 357       user = insert(:user)
 358
 359       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 360       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 361
 362       assert modified["@context"] == "https://www.w3.org/ns/activitystreams"
 363       assert modified["object"]["conversation"] == modified["context"]
 364     end
 365
 366     test "it sets the 'attributedTo' property to the actor of the object if it doesn't have one" do
 367       user = insert(:user)
 368
 369       {:ok, activity} = CommonAPI.post(user, %{"status" => "hey"})
 370       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 371
 372       assert modified["object"]["actor"] == modified["object"]["attributedTo"]
 373     end
 374
 375     test "it translates ostatus IDs to external URLs" do
 376       incoming = File.read!("test/fixtures/incoming_note_activity.xml")
 377       {:ok, [referent_activity]} = OStatus.handle_incoming(incoming)
 378
 379       user = insert(:user)
 380
 381       {:ok, activity, _} = CommonAPI.favorite(referent_activity.id, user)
 382       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 383
 384       assert modified["object"] == "http://gs.example.org:4040/index.php/notice/29"
 385     end
 386
 387     test "it translates ostatus reply_to IDs to external URLs" do
 388       incoming = File.read!("test/fixtures/incoming_note_activity.xml")
 389       {:ok, [referred_activity]} = OStatus.handle_incoming(incoming)
 390
 391       user = insert(:user)
 392
 393       {:ok, activity} =
 394         CommonAPI.post(user, %{"status" => "HI!", "in_reply_to_status_id" => referred_activity.id})
 395
 396       {:ok, modified} = Transmogrifier.prepare_outgoing(activity.data)
 397
 398       assert modified["object"]["inReplyTo"] == "http://gs.example.org:4040/index.php/notice/29"
 399     end
 400   end
 401
 402   describe "user upgrade" do
 403     test "it upgrades a user to activitypub" do
 404       user =
 405         insert(:user, %{
 406           nickname: "rye@niu.moe",
 407           local: false,
 408           ap_id: "https://niu.moe/users/rye",
 409           follower_address: User.ap_followers(%User{nickname: "rye@niu.moe"})
 410         })
 411
 412       user_two = insert(:user, %{following: [user.follower_address]})
 413
 414       {:ok, activity} = CommonAPI.post(user, %{"status" => "test"})
 415       {:ok, unrelated_activity} = CommonAPI.post(user_two, %{"status" => "test"})
 416       assert "http://localhost:4001/users/rye@niu.moe/followers" in activity.recipients
 417
 418       user = Repo.get(User, user.id)
 419       assert user.info["note_count"] == 1
 420
 421       {:ok, user} = Transmogrifier.upgrade_user_from_ap_id("https://niu.moe/users/rye")
 422       assert user.info["ap_enabled"]
 423       assert user.info["note_count"] == 1
 424       assert user.follower_address == "https://niu.moe/users/rye/followers"
 425
 426       # Wait for the background task
 427       :timer.sleep(1000)
 428
 429       user = Repo.get(User, user.id)
 430       assert user.info["note_count"] == 1
 431
 432       activity = Repo.get(Activity, activity.id)
 433       assert user.follower_address in activity.recipients
 434
 435       assert %{
 436                "url" => [
 437                  %{
 438                    "href" =>
 439                      "https://cdn.niu.moe/accounts/avatars/000/033/323/original/fd7f8ae0b3ffedc9.jpeg"
 440                  }
 441                ]
 442              } = user.avatar
 443
 444       assert %{
 445                "url" => [
 446                  %{
 447                    "href" =>
 448                      "https://cdn.niu.moe/accounts/headers/000/033/323/original/850b3448fa5fd477.png"
 449                  }
 450                ]
 451              } = user.info["banner"]
 452
 453       refute "..." in activity.recipients
 454
 455       unrelated_activity = Repo.get(Activity, unrelated_activity.id)
 456       refute user.follower_address in unrelated_activity.recipients
 457
 458       user_two = Repo.get(User, user_two.id)
 459       assert user.follower_address in user_two.following
 460       refute "..." in user_two.following
 461     end
 462   end
 463
 464   describe "maybe_retire_websub" do
 465     test "it deletes all websub client subscripitions with the user as topic" do
 466       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/rye.atom"}
 467       {:ok, ws} = Repo.insert(subscription)
 468
 469       subscription = %WebsubClientSubscription{topic: "https://niu.moe/users/pasty.atom"}
 470       {:ok, ws2} = Repo.insert(subscription)
 471
 472       Transmogrifier.maybe_retire_websub("https://niu.moe/users/rye")
 473
 474       refute Repo.get(WebsubClientSubscription, ws.id)
 475       assert Repo.get(WebsubClientSubscription, ws2.id)
 476     end
 477   end
 478
 479   describe "actor rewriting" do
 480     test "it fixes the actor URL property to be a proper URI" do
 481       data = %{
 482         "url" => %{"href" => "http://example.com"}
 483       }
 484
 485       rewritten = Transmogrifier.maybe_fix_user_object(data)
 486       assert rewritten["url"] == "http://example.com"
 487     end
 488   end
 489 end