git.squeep.com Git - akkoma/blob - test/web/activity_pub/object_validator_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ObjectValidatorTest do
   2   use Pleroma.DataCase
   3
   4   alias Pleroma.Web.ActivityPub.Builder
   5   alias Pleroma.Web.ActivityPub.ObjectValidator
   6   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
   7   alias Pleroma.Web.ActivityPub.Utils
   8   alias Pleroma.Web.CommonAPI
   9
  10   import Pleroma.Factory
  11
  12   describe "deletes" do
  13     setup do
  14       user = insert(:user)
  15       {:ok, post_activity} = CommonAPI.post(user, %{"status" => "cancel me daddy"})
  16
  17       {:ok, valid_post_delete, _} = Builder.delete(user, post_activity.data["object"])
  18       {:ok, valid_user_delete, _} = Builder.delete(user, user.ap_id)
  19
  20       %{user: user, valid_post_delete: valid_post_delete, valid_user_delete: valid_user_delete}
  21     end
  22
  23     test "it is valid for a post deletion", %{valid_post_delete: valid_post_delete} do
  24       {:ok, valid_post_delete_u, _} = ObjectValidator.validate(valid_post_delete, [])
  25
  26       assert valid_post_delete_u["deleted_activity_id"]
  27     end
  28
  29     test "it is valid for a user deletion", %{valid_user_delete: valid_user_delete} do
  30       assert match?({:ok, _, _}, ObjectValidator.validate(valid_user_delete, []))
  31     end
  32
  33     test "it's invalid if the id is missing", %{valid_post_delete: valid_post_delete} do
  34       no_id =
  35         valid_post_delete
  36         |> Map.delete("id")
  37
  38       {:error, cng} = ObjectValidator.validate(no_id, [])
  39
  40       assert {:id, {"can't be blank", [validation: :required]}} in cng.errors
  41     end
  42
  43     test "it's invalid if the object doesn't exist", %{valid_post_delete: valid_post_delete} do
  44       missing_object =
  45         valid_post_delete
  46         |> Map.put("object", "http://does.not/exist")
  47
  48       {:error, cng} = ObjectValidator.validate(missing_object, [])
  49
  50       assert {:object, {"can't find object", []}} in cng.errors
  51     end
  52
  53     test "it's invalid if the actor of the object and the actor of delete are from different domains",
  54          %{valid_post_delete: valid_post_delete} do
  55       valid_other_actor =
  56         valid_post_delete
  57         |> Map.put("actor", valid_post_delete["actor"] <> "1")
  58
  59       assert match?({:ok, _, _}, ObjectValidator.validate(valid_other_actor, []))
  60
  61       invalid_other_actor =
  62         valid_post_delete
  63         |> Map.put("actor", "https://gensokyo.2hu/users/raymoo")
  64
  65       {:error, cng} = ObjectValidator.validate(invalid_other_actor, [])
  66
  67       assert {:actor, {"is not allowed to delete object", []}} in cng.errors
  68     end
  69   end
  70
  71   describe "likes" do
  72     setup do
  73       user = insert(:user)
  74       {:ok, post_activity} = CommonAPI.post(user, %{"status" => "uguu"})
  75
  76       valid_like = %{
  77         "to" => [user.ap_id],
  78         "cc" => [],
  79         "type" => "Like",
  80         "id" => Utils.generate_activity_id(),
  81         "object" => post_activity.data["object"],
  82         "actor" => user.ap_id,
  83         "context" => "a context"
  84       }
  85
  86       %{valid_like: valid_like, user: user, post_activity: post_activity}
  87     end
  88
  89     test "returns ok when called in the ObjectValidator", %{valid_like: valid_like} do
  90       {:ok, object, _meta} = ObjectValidator.validate(valid_like, [])
  91
  92       assert "id" in Map.keys(object)
  93     end
  94
  95     test "is valid for a valid object", %{valid_like: valid_like} do
  96       assert LikeValidator.cast_and_validate(valid_like).valid?
  97     end
  98
  99     test "it errors when the actor is missing or not known", %{valid_like: valid_like} do
 100       without_actor = Map.delete(valid_like, "actor")
 101
 102       refute LikeValidator.cast_and_validate(without_actor).valid?
 103
 104       with_invalid_actor = Map.put(valid_like, "actor", "invalidactor")
 105
 106       refute LikeValidator.cast_and_validate(with_invalid_actor).valid?
 107     end
 108
 109     test "it errors when the object is missing or not known", %{valid_like: valid_like} do
 110       without_object = Map.delete(valid_like, "object")
 111
 112       refute LikeValidator.cast_and_validate(without_object).valid?
 113
 114       with_invalid_object = Map.put(valid_like, "object", "invalidobject")
 115
 116       refute LikeValidator.cast_and_validate(with_invalid_object).valid?
 117     end
 118
 119     test "it errors when the actor has already like the object", %{
 120       valid_like: valid_like,
 121       user: user,
 122       post_activity: post_activity
 123     } do
 124       _like = CommonAPI.favorite(user, post_activity.id)
 125
 126       refute LikeValidator.cast_and_validate(valid_like).valid?
 127     end
 128
 129     test "it works when actor or object are wrapped in maps", %{valid_like: valid_like} do
 130       wrapped_like =
 131         valid_like
 132         |> Map.put("actor", %{"id" => valid_like["actor"]})
 133         |> Map.put("object", %{"id" => valid_like["object"]})
 134
 135       validated = LikeValidator.cast_and_validate(wrapped_like)
 136
 137       assert validated.valid?
 138
 139       assert {:actor, valid_like["actor"]} in validated.changes
 140       assert {:object, valid_like["object"]} in validated.changes
 141     end
 142   end
 143 end