git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.{Activity, Object, User}
   7   alias Pleroma.Builders.ActivityBuilder
   8
   9   import Pleroma.Factory
  10   import Tesla.Mock
  11
  12   setup do
  13     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  14     :ok
  15   end
  16
  17   describe "building a user from his ap id" do
  18     test "it returns a user" do
  19       user_id = "http://mastodon.example.org/users/admin"
  20       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  21       assert user.ap_id == user_id
  22       assert user.nickname == "admin@mastodon.example.org"
  23       assert user.info.source_data
  24       assert user.info.ap_enabled
  25       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  26     end
  27   end
  28
  29   describe "insertion" do
  30     test "returns the activity if one with the same id is already in" do
  31       activity = insert(:note_activity)
  32       {:ok, new_activity} = ActivityPub.insert(activity.data)
  33
  34       assert activity == new_activity
  35     end
  36
  37     test "inserts a given map into the activity database, giving it an id if it has none." do
  38       data = %{
  39         "ok" => true
  40       }
  41
  42       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  43       assert activity.data["ok"] == data["ok"]
  44       assert is_binary(activity.data["id"])
  45
  46       given_id = "bla"
  47
  48       data = %{
  49         "ok" => true,
  50         "id" => given_id,
  51         "context" => "blabla"
  52       }
  53
  54       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  55       assert activity.data["ok"] == data["ok"]
  56       assert activity.data["id"] == given_id
  57       assert activity.data["context"] == "blabla"
  58       assert activity.data["context_id"]
  59     end
  60
  61     test "adds a context when none is there" do
  62       data = %{
  63         "id" => "some_id",
  64         "object" => %{
  65           "id" => "object_id"
  66         }
  67       }
  68
  69       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  70
  71       assert is_binary(activity.data["context"])
  72       assert is_binary(activity.data["object"]["context"])
  73       assert activity.data["context_id"]
  74       assert activity.data["object"]["context_id"]
  75     end
  76
  77     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
  78       data = %{
  79         "object" => %{
  80           "type" => "Note",
  81           "ok" => true
  82         }
  83       }
  84
  85       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  86       assert is_binary(activity.data["object"]["id"])
  87       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
  88     end
  89   end
  90
  91   describe "create activities" do
  92     test "removes doubled 'to' recipients" do
  93       user = insert(:user)
  94
  95       {:ok, activity} =
  96         ActivityPub.create(%{
  97           to: ["user1", "user1", "user2"],
  98           actor: user,
  99           context: "",
 100           object: %{}
 101         })
 102
 103       assert activity.data["to"] == ["user1", "user2"]
 104       assert activity.actor == user.ap_id
 105       assert activity.recipients == ["user1", "user2"]
 106     end
 107   end
 108
 109   describe "fetch activities for recipients" do
 110     test "retrieve the activities for certain recipients" do
 111       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 112       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 113       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 114
 115       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 116       assert length(activities) == 2
 117       assert activities == [activity_one, activity_two]
 118     end
 119   end
 120
 121   describe "fetch activities in context" do
 122     test "retrieves activities that have a given context" do
 123       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 124       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 125       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 126       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 127       activity_five = insert(:note_activity)
 128       user = insert(:user)
 129
 130       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 131
 132       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 133       assert activities == [activity_two, activity]
 134     end
 135   end
 136
 137   test "doesn't return blocked activities" do
 138     activity_one = insert(:note_activity)
 139     activity_two = insert(:note_activity)
 140     activity_three = insert(:note_activity)
 141     user = insert(:user)
 142     booster = insert(:user)
 143     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 144
 145     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 146
 147     assert Enum.member?(activities, activity_two)
 148     assert Enum.member?(activities, activity_three)
 149     refute Enum.member?(activities, activity_one)
 150
 151     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 152
 153     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 154
 155     assert Enum.member?(activities, activity_two)
 156     assert Enum.member?(activities, activity_three)
 157     assert Enum.member?(activities, activity_one)
 158
 159     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 160     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 161     %Activity{} = boost_activity = Activity.get_create_activity_by_object_ap_id(id)
 162     activity_three = Repo.get(Activity, activity_three.id)
 163
 164     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 165
 166     assert Enum.member?(activities, activity_two)
 167     refute Enum.member?(activities, activity_three)
 168     refute Enum.member?(activities, boost_activity)
 169     assert Enum.member?(activities, activity_one)
 170
 171     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 172
 173     assert Enum.member?(activities, activity_two)
 174     assert Enum.member?(activities, activity_three)
 175     assert Enum.member?(activities, boost_activity)
 176     assert Enum.member?(activities, activity_one)
 177   end
 178
 179   describe "public fetch activities" do
 180     test "doesn't retrieve unlisted activities" do
 181       user = insert(:user)
 182
 183       {:ok, unlisted_activity} =
 184         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 185
 186       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 187
 188       [activity] = ActivityPub.fetch_public_activities()
 189
 190       assert activity == listed_activity
 191     end
 192
 193     test "retrieves public activities" do
 194       _activities = ActivityPub.fetch_public_activities()
 195
 196       %{public: public} = ActivityBuilder.public_and_non_public()
 197
 198       activities = ActivityPub.fetch_public_activities()
 199       assert length(activities) == 1
 200       assert Enum.at(activities, 0) == public
 201     end
 202
 203     test "retrieves a maximum of 20 activities" do
 204       activities = ActivityBuilder.insert_list(30)
 205       last_expected = List.last(activities)
 206
 207       activities = ActivityPub.fetch_public_activities()
 208       last = List.last(activities)
 209
 210       assert length(activities) == 20
 211       assert last == last_expected
 212     end
 213
 214     test "retrieves ids starting from a since_id" do
 215       activities = ActivityBuilder.insert_list(30)
 216       later_activities = ActivityBuilder.insert_list(10)
 217       since_id = List.last(activities).id
 218       last_expected = List.last(later_activities)
 219
 220       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 221       last = List.last(activities)
 222
 223       assert length(activities) == 10
 224       assert last == last_expected
 225     end
 226
 227     test "retrieves ids up to max_id" do
 228       _first_activities = ActivityBuilder.insert_list(10)
 229       activities = ActivityBuilder.insert_list(20)
 230       later_activities = ActivityBuilder.insert_list(10)
 231       max_id = List.first(later_activities).id
 232       last_expected = List.last(activities)
 233
 234       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 235       last = List.last(activities)
 236
 237       assert length(activities) == 20
 238       assert last == last_expected
 239     end
 240   end
 241
 242   describe "like an object" do
 243     test "adds a like activity to the db" do
 244       note_activity = insert(:note_activity)
 245       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 246       user = insert(:user)
 247       user_two = insert(:user)
 248
 249       {:ok, like_activity, object} = ActivityPub.like(user, object)
 250
 251       assert like_activity.data["actor"] == user.ap_id
 252       assert like_activity.data["type"] == "Like"
 253       assert like_activity.data["object"] == object.data["id"]
 254       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 255       assert like_activity.data["context"] == object.data["context"]
 256       assert object.data["like_count"] == 1
 257       assert object.data["likes"] == [user.ap_id]
 258
 259       # Just return the original activity if the user already liked it.
 260       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 261
 262       assert like_activity == same_like_activity
 263       assert object.data["likes"] == [user.ap_id]
 264
 265       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 266       assert note_activity.data["object"]["like_count"] == 1
 267
 268       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 269       assert object.data["like_count"] == 2
 270     end
 271   end
 272
 273   describe "unliking" do
 274     test "unliking a previously liked object" do
 275       note_activity = insert(:note_activity)
 276       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 277       user = insert(:user)
 278
 279       # Unliking something that hasn't been liked does nothing
 280       {:ok, object} = ActivityPub.unlike(user, object)
 281       assert object.data["like_count"] == 0
 282
 283       {:ok, like_activity, object} = ActivityPub.like(user, object)
 284       assert object.data["like_count"] == 1
 285
 286       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 287       assert object.data["like_count"] == 0
 288
 289       assert Repo.get(Activity, like_activity.id) == nil
 290     end
 291   end
 292
 293   describe "announcing an object" do
 294     test "adds an announce activity to the db" do
 295       note_activity = insert(:note_activity)
 296       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 297       user = insert(:user)
 298
 299       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 300       assert object.data["announcement_count"] == 1
 301       assert object.data["announcements"] == [user.ap_id]
 302
 303       assert announce_activity.data["to"] == [
 304                User.ap_followers(user),
 305                note_activity.data["actor"]
 306              ]
 307
 308       assert announce_activity.data["object"] == object.data["id"]
 309       assert announce_activity.data["actor"] == user.ap_id
 310       assert announce_activity.data["context"] == object.data["context"]
 311     end
 312   end
 313
 314   describe "unannouncing an object" do
 315     test "unannouncing a previously announced object" do
 316       note_activity = insert(:note_activity)
 317       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 318       user = insert(:user)
 319
 320       # Unannouncing an object that is not announced does nothing
 321       # {:ok, object} = ActivityPub.unannounce(user, object)
 322       # assert object.data["announcement_count"] == 0
 323
 324       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 325       assert object.data["announcement_count"] == 1
 326
 327       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 328       assert object.data["announcement_count"] == 0
 329
 330       assert unannounce_activity.data["to"] == [
 331                User.ap_followers(user),
 332                announce_activity.data["actor"]
 333              ]
 334
 335       assert unannounce_activity.data["type"] == "Undo"
 336       assert unannounce_activity.data["object"] == announce_activity.data
 337       assert unannounce_activity.data["actor"] == user.ap_id
 338       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 339
 340       assert Repo.get(Activity, announce_activity.id) == nil
 341     end
 342   end
 343
 344   describe "uploading files" do
 345     test "copies the file to the configured folder" do
 346       file = %Plug.Upload{
 347         content_type: "image/jpg",
 348         path: Path.absname("test/fixtures/image.jpg"),
 349         filename: "an_image.jpg"
 350       }
 351
 352       {:ok, %Object{} = object} = ActivityPub.upload(file)
 353       assert object.data["name"] == "an_image.jpg"
 354     end
 355
 356     test "works with base64 encoded images" do
 357       file = %{
 358         "img" => data_uri()
 359       }
 360
 361       {:ok, %Object{}} = ActivityPub.upload(file)
 362     end
 363   end
 364
 365   describe "fetch the latest Follow" do
 366     test "fetches the latest Follow activity" do
 367       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 368       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 369       followed = Repo.get_by(User, ap_id: activity.data["object"])
 370
 371       assert activity == Utils.fetch_latest_follow(follower, followed)
 372     end
 373   end
 374
 375   describe "fetching an object" do
 376     test "it fetches an object" do
 377       {:ok, object} =
 378         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 379
 380       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 381       assert activity.data["id"]
 382
 383       {:ok, object_again} =
 384         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 385
 386       assert [attachment] = object.data["attachment"]
 387       assert is_list(attachment["url"])
 388
 389       assert object == object_again
 390     end
 391
 392     test "it works with objects only available via Ostatus" do
 393       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 394       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 395       assert activity.data["id"]
 396
 397       {:ok, object_again} =
 398         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 399
 400       assert object == object_again
 401     end
 402
 403     test "it correctly stitches up conversations between ostatus and ap" do
 404       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 405       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 406
 407       object = Object.get_by_ap_id(object.data["inReplyTo"])
 408       assert object
 409     end
 410   end
 411
 412   describe "following / unfollowing" do
 413     test "creates a follow activity" do
 414       follower = insert(:user)
 415       followed = insert(:user)
 416
 417       {:ok, activity} = ActivityPub.follow(follower, followed)
 418       assert activity.data["type"] == "Follow"
 419       assert activity.data["actor"] == follower.ap_id
 420       assert activity.data["object"] == followed.ap_id
 421     end
 422
 423     test "creates an undo activity for the last follow" do
 424       follower = insert(:user)
 425       followed = insert(:user)
 426
 427       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 428       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 429
 430       assert activity.data["type"] == "Undo"
 431       assert activity.data["actor"] == follower.ap_id
 432
 433       assert is_map(activity.data["object"])
 434       assert activity.data["object"]["type"] == "Follow"
 435       assert activity.data["object"]["object"] == followed.ap_id
 436       assert activity.data["object"]["id"] == follow_activity.data["id"]
 437     end
 438   end
 439
 440   describe "blocking / unblocking" do
 441     test "creates a block activity" do
 442       blocker = insert(:user)
 443       blocked = insert(:user)
 444
 445       {:ok, activity} = ActivityPub.block(blocker, blocked)
 446
 447       assert activity.data["type"] == "Block"
 448       assert activity.data["actor"] == blocker.ap_id
 449       assert activity.data["object"] == blocked.ap_id
 450     end
 451
 452     test "creates an undo activity for the last block" do
 453       blocker = insert(:user)
 454       blocked = insert(:user)
 455
 456       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 457       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 458
 459       assert activity.data["type"] == "Undo"
 460       assert activity.data["actor"] == blocker.ap_id
 461
 462       assert is_map(activity.data["object"])
 463       assert activity.data["object"]["type"] == "Block"
 464       assert activity.data["object"]["object"] == blocked.ap_id
 465       assert activity.data["object"]["id"] == block_activity.data["id"]
 466     end
 467   end
 468
 469   describe "deletion" do
 470     test "it creates a delete activity and deletes the original object" do
 471       note = insert(:note_activity)
 472       object = Object.get_by_ap_id(note.data["object"]["id"])
 473       {:ok, delete} = ActivityPub.delete(object)
 474
 475       assert delete.data["type"] == "Delete"
 476       assert delete.data["actor"] == note.data["actor"]
 477       assert delete.data["object"] == note.data["object"]["id"]
 478
 479       assert Repo.get(Activity, delete.id) != nil
 480
 481       assert Repo.get(Object, object.id) == nil
 482     end
 483   end
 484
 485   describe "timeline post-processing" do
 486     test "it filters broken threads" do
 487       user1 = insert(:user)
 488       user2 = insert(:user)
 489       user3 = insert(:user)
 490
 491       {:ok, user1} = User.follow(user1, user3)
 492       assert User.following?(user1, user3)
 493
 494       {:ok, user2} = User.follow(user2, user3)
 495       assert User.following?(user2, user3)
 496
 497       {:ok, user3} = User.follow(user3, user2)
 498       assert User.following?(user3, user2)
 499
 500       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 501
 502       {:ok, private_activity_1} =
 503         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 504
 505       {:ok, private_activity_2} =
 506         CommonAPI.post(user2, %{
 507           "status" => "hi 3",
 508           "visibility" => "private",
 509           "in_reply_to_status_id" => private_activity_1.id
 510         })
 511
 512       {:ok, private_activity_3} =
 513         CommonAPI.post(user3, %{
 514           "status" => "hi 4",
 515           "visibility" => "private",
 516           "in_reply_to_status_id" => private_activity_2.id
 517         })
 518
 519       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 520
 521       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 522
 523       assert [public_activity, private_activity_1, private_activity_3] == activities
 524       assert length(activities) == 3
 525
 526       activities = ActivityPub.contain_timeline(activities, user1)
 527
 528       assert [public_activity, private_activity_1] == activities
 529       assert length(activities) == 2
 530     end
 531   end
 532
 533   test "it can fetch plume articles" do
 534     {:ok, object} =
 535       ActivityPub.fetch_object_from_id(
 536         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 537       )
 538
 539     assert object
 540   end
 541
 542   describe "update" do
 543     test "it creates an update activity with the new user data" do
 544       user = insert(:user)
 545       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 546       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 547
 548       {:ok, update} =
 549         ActivityPub.update(%{
 550           actor: user_data["id"],
 551           to: [user.follower_address],
 552           cc: [],
 553           object: user_data
 554         })
 555
 556       assert update.data["actor"] == user.ap_id
 557       assert update.data["to"] == [user.follower_address]
 558       assert update.data["object"]["id"] == user_data["id"]
 559       assert update.data["object"]["type"] == user_data["type"]
 560     end
 561   end
 562
 563   test "it can fetch peertube videos" do
 564     {:ok, object} =
 565       ActivityPub.fetch_object_from_id(
 566         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 567       )
 568
 569     assert object
 570   end
 571
 572   def data_uri do
 573     File.read!("test/fixtures/avatar_data_uri")
 574   end
 575 end