git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.{Activity, Object, User}
   6   alias Pleroma.Builders.ActivityBuilder
   7
   8   import Pleroma.Factory
   9
  10   describe "building a user from his ap id" do
  11     test "it returns a user" do
  12       user_id = "http://mastodon.example.org/users/admin"
  13       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  14       assert user.ap_id == user_id
  15       assert user.nickname == "admin@mastodon.example.org"
  16       assert user.info["source_data"]
  17       assert user.info["ap_enabled"]
  18       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  19     end
  20   end
  21
  22   describe "insertion" do
  23     test "returns the activity if one with the same id is already in" do
  24       activity = insert(:note_activity)
  25       {:ok, new_activity}= ActivityPub.insert(activity.data)
  26
  27       assert activity == new_activity
  28     end
  29
  30     test "inserts a given map into the activity database, giving it an id if it has none." do
  31       data = %{
  32         "ok" => true
  33       }
  34
  35       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  36       assert activity.data["ok"] == data["ok"]
  37       assert is_binary(activity.data["id"])
  38
  39       given_id = "bla"
  40       data = %{
  41         "ok" => true,
  42         "id" => given_id
  43       }
  44
  45       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  46       assert activity.data["ok"] == data["ok"]
  47       assert activity.data["id"] == given_id
  48     end
  49
  50     test "adds an id to a given object if it lacks one and inserts it to the object database" do
  51       data = %{
  52         "object" => %{
  53           "ok" => true
  54         }
  55       }
  56
  57       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  58       assert is_binary(activity.data["object"]["id"])
  59       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
  60     end
  61   end
  62
  63   describe "create activities" do
  64     test "removes doubled 'to' recipients" do
  65       {:ok, activity} = ActivityPub.create(%{to: ["user1", "user1", "user2"], actor: %User{ap_id: "1"}, context: "", object: %{}})
  66       assert activity.data["to"] == ["user1", "user2"]
  67       assert activity.actor == "1"
  68       assert activity.recipients == ["user1", "user2"]
  69     end
  70   end
  71
  72   describe "fetch activities for recipients" do
  73     test "retrieve the activities for certain recipients" do
  74       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
  75       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
  76       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
  77
  78       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
  79       assert length(activities) == 2
  80       assert activities == [activity_one, activity_two]
  81     end
  82   end
  83
  84   describe "fetch activities in context" do
  85     test "retrieves activities that have a given context" do
  86       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
  87       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
  88       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
  89       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
  90       activity_five = insert(:note_activity)
  91       user = insert(:user)
  92
  93       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
  94
  95       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
  96       assert activities == [activity_two, activity]
  97     end
  98   end
  99
 100   test "doesn't return blocked activities" do
 101     activity_one = insert(:note_activity)
 102     activity_two = insert(:note_activity)
 103     user = insert(:user)
 104     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 105
 106     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 107
 108     assert Enum.member?(activities, activity_two)
 109     refute Enum.member?(activities, activity_one)
 110
 111     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 112
 113     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 114
 115     assert Enum.member?(activities, activity_two)
 116     assert Enum.member?(activities, activity_one)
 117
 118     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 119
 120     assert Enum.member?(activities, activity_two)
 121     assert Enum.member?(activities, activity_one)
 122   end
 123
 124   describe "public fetch activities" do
 125     test "retrieves public activities" do
 126       _activities = ActivityPub.fetch_public_activities
 127
 128       %{public: public} = ActivityBuilder.public_and_non_public
 129
 130       activities = ActivityPub.fetch_public_activities
 131       assert length(activities) == 1
 132       assert Enum.at(activities, 0) == public
 133     end
 134
 135     test "retrieves a maximum of 20 activities" do
 136       activities = ActivityBuilder.insert_list(30)
 137       last_expected = List.last(activities)
 138
 139       activities = ActivityPub.fetch_public_activities
 140       last = List.last(activities)
 141
 142       assert length(activities) == 20
 143       assert last == last_expected
 144     end
 145
 146     test "retrieves ids starting from a since_id" do
 147       activities = ActivityBuilder.insert_list(30)
 148       later_activities = ActivityBuilder.insert_list(10)
 149       since_id = List.last(activities).id
 150       last_expected = List.last(later_activities)
 151
 152       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 153       last = List.last(activities)
 154
 155       assert length(activities) == 10
 156       assert last == last_expected
 157     end
 158
 159     test "retrieves ids up to max_id" do
 160       _first_activities = ActivityBuilder.insert_list(10)
 161       activities = ActivityBuilder.insert_list(20)
 162       later_activities = ActivityBuilder.insert_list(10)
 163       max_id = List.first(later_activities).id
 164       last_expected = List.last(activities)
 165
 166       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 167       last = List.last(activities)
 168
 169       assert length(activities) == 20
 170       assert last == last_expected
 171     end
 172   end
 173
 174   describe "like an object" do
 175     test "adds a like activity to the db" do
 176       note_activity = insert(:note_activity)
 177       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 178       user = insert(:user)
 179       user_two = insert(:user)
 180
 181       {:ok, like_activity, object} = ActivityPub.like(user, object)
 182
 183       assert like_activity.data["actor"] == user.ap_id
 184       assert like_activity.data["type"] == "Like"
 185       assert like_activity.data["object"] == object.data["id"]
 186       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 187       assert like_activity.data["context"] == object.data["context"]
 188       assert object.data["like_count"] == 1
 189       assert object.data["likes"] == [user.ap_id]
 190
 191       # Just return the original activity if the user already liked it.
 192       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 193
 194       assert like_activity == same_like_activity
 195       assert object.data["likes"] == [user.ap_id]
 196
 197       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 198       assert note_activity.data["object"]["like_count"] == 1
 199
 200       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 201       assert object.data["like_count"] == 2
 202     end
 203   end
 204
 205   describe "unliking" do
 206     test "unliking a previously liked object" do
 207       note_activity = insert(:note_activity)
 208       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 209       user = insert(:user)
 210
 211       # Unliking something that hasn't been liked does nothing
 212       {:ok, object} = ActivityPub.unlike(user, object)
 213       assert object.data["like_count"] == 0
 214
 215       {:ok, like_activity, object} = ActivityPub.like(user, object)
 216       assert object.data["like_count"] == 1
 217
 218       {:ok, object} = ActivityPub.unlike(user, object)
 219       assert object.data["like_count"] == 0
 220
 221       assert Repo.get(Activity, like_activity.id) == nil
 222     end
 223   end
 224
 225   describe "announcing an object" do
 226     test "adds an announce activity to the db" do
 227       note_activity = insert(:note_activity)
 228       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 229       user = insert(:user)
 230
 231       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 232       assert object.data["announcement_count"] == 1
 233       assert object.data["announcements"] == [user.ap_id]
 234       assert announce_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 235       assert announce_activity.data["object"] == object.data["id"]
 236       assert announce_activity.data["actor"] == user.ap_id
 237       assert announce_activity.data["context"] == object.data["context"]
 238     end
 239   end
 240
 241   describe "uploading files" do
 242     test "copies the file to the configured folder" do
 243       file = %Plug.Upload{content_type: "image/jpg", path: Path.absname("test/fixtures/image.jpg"), filename: "an_image.jpg"}
 244
 245       {:ok, %Object{} = object} = ActivityPub.upload(file)
 246       assert object.data["name"] == "an_image.jpg"
 247     end
 248
 249     test "works with base64 encoded images" do
 250       file = %{
 251         "img" => data_uri()
 252       }
 253
 254       {:ok, %Object{}} = ActivityPub.upload(file)
 255     end
 256   end
 257
 258   describe "fetch the latest Follow" do
 259     test "fetches the latest Follow activity" do
 260       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 261       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 262       followed = Repo.get_by(User, ap_id: activity.data["object"])
 263
 264       assert activity == Utils.fetch_latest_follow(follower, followed)
 265     end
 266   end
 267
 268   describe "fetching an object" do
 269     test "it fetches an object" do
 270       {:ok, object} = ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 271       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 272       assert activity.data["id"]
 273
 274       {:ok, object_again} = ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 275
 276       assert [attachment] = object.data["attachment"]
 277       assert is_list(attachment["url"])
 278
 279       assert object == object_again
 280     end
 281
 282     test "it works with objects only available via Ostatus" do
 283       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 284       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 285       assert activity.data["id"]
 286
 287       {:ok, object_again} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 288
 289       assert object == object_again
 290     end
 291
 292     test "it correctly stitches up conversations between ostatus and ap" do
 293       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 294       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 295
 296       object = Object.get_by_ap_id(object.data["inReplyTo"])
 297       assert object
 298     end
 299   end
 300
 301   describe "following / unfollowing" do
 302     test "creates a follow activity" do
 303       follower = insert(:user)
 304       followed = insert(:user)
 305
 306       {:ok, activity} = ActivityPub.follow(follower, followed)
 307       assert activity.data["type"] == "Follow"
 308       assert activity.data["actor"] == follower.ap_id
 309       assert activity.data["object"] == followed.ap_id
 310     end
 311
 312     test "creates an undo activity for the last follow" do
 313       follower = insert(:user)
 314       followed = insert(:user)
 315
 316       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 317       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 318
 319       assert activity.data["type"] == "Undo"
 320       assert activity.data["actor"] == follower.ap_id
 321       assert activity.data["object"] == follow_activity.data["id"]
 322     end
 323   end
 324
 325   describe "deletion" do
 326     test "it creates a delete activity and deletes the original object" do
 327       note = insert(:note_activity)
 328       object = Object.get_by_ap_id(note.data["object"]["id"])
 329       {:ok, delete} = ActivityPub.delete(object)
 330
 331       assert delete.data["type"] == "Delete"
 332       assert delete.data["actor"] == note.data["actor"]
 333       assert delete.data["object"] == note.data["object"]["id"]
 334
 335       assert Repo.get(Activity, delete.id) != nil
 336
 337       assert Repo.get(Object, object.id) == nil
 338     end
 339   end
 340
 341   describe "update" do
 342     test "it creates an update activity with the new user data" do
 343       user = insert(:user)
 344       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 345       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 346       {:ok, update} = ActivityPub.update(%{actor: user_data["id"], to: [user.follower_address], cc: [], object: user_data})
 347
 348       assert update.data["actor"] == user.ap_id
 349       assert update.data["to"] == [user.follower_address]
 350       assert update.data["object"]["id"] == user_data["id"]
 351       assert update.data["object"]["type"] == user_data["type"]
 352     end
 353   end
 354
 355   def data_uri do
 356     File.read!("test/fixtures/avatar_data_uri")
 357   end
 358 end