git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.{Activity, Object, User}
  11   alias Pleroma.Builders.ActivityBuilder
  12
  13   import Pleroma.Factory
  14   import Tesla.Mock
  15
  16   setup do
  17     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  18     :ok
  19   end
  20
  21   describe "fetching restricted by visibility" do
  22     test "it restricts by the appropriate visibility" do
  23       user = insert(:user)
  24
  25       {:ok, public_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "public"})
  26
  27       {:ok, direct_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  28
  29       {:ok, unlisted_activity} =
  30         CommonAPI.post(user, %{"status" => ".", "visibility" => "unlisted"})
  31
  32       {:ok, private_activity} =
  33         CommonAPI.post(user, %{"status" => ".", "visibility" => "private"})
  34
  35       activities =
  36         ActivityPub.fetch_activities([], %{:visibility => "direct", "actor_id" => user.ap_id})
  37
  38       assert activities == [direct_activity]
  39
  40       activities =
  41         ActivityPub.fetch_activities([], %{:visibility => "unlisted", "actor_id" => user.ap_id})
  42
  43       assert activities == [unlisted_activity]
  44
  45       activities =
  46         ActivityPub.fetch_activities([], %{:visibility => "private", "actor_id" => user.ap_id})
  47
  48       assert activities == [private_activity]
  49
  50       activities =
  51         ActivityPub.fetch_activities([], %{:visibility => "public", "actor_id" => user.ap_id})
  52
  53       assert activities == [public_activity]
  54     end
  55   end
  56
  57   describe "building a user from his ap id" do
  58     test "it returns a user" do
  59       user_id = "http://mastodon.example.org/users/admin"
  60       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  61       assert user.ap_id == user_id
  62       assert user.nickname == "admin@mastodon.example.org"
  63       assert user.info.source_data
  64       assert user.info.ap_enabled
  65       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  66     end
  67
  68     test "it fetches the appropriate tag-restricted posts" do
  69       user = insert(:user)
  70
  71       {:ok, status_one} = CommonAPI.post(user, %{"status" => ". #test"})
  72       {:ok, status_two} = CommonAPI.post(user, %{"status" => ". #essais"})
  73       {:ok, status_three} = CommonAPI.post(user, %{"status" => ". #test #reject"})
  74
  75       fetch_one = ActivityPub.fetch_activities([], %{"tag" => "test"})
  76       fetch_two = ActivityPub.fetch_activities([], %{"tag" => ["test", "essais"]})
  77
  78       fetch_three =
  79         ActivityPub.fetch_activities([], %{
  80           "tag" => ["test", "essais"],
  81           "tag_reject" => ["reject"]
  82         })
  83
  84       assert fetch_one == [status_one, status_three]
  85       assert fetch_two == [status_one, status_two, status_three]
  86       assert fetch_three == [status_one, status_two]
  87     end
  88   end
  89
  90   describe "insertion" do
  91     test "drops activities beyond a certain limit" do
  92       limit = Pleroma.Config.get([:instance, :remote_limit])
  93
  94       random_text =
  95         :crypto.strong_rand_bytes(limit + 1)
  96         |> Base.encode64()
  97         |> binary_part(0, limit + 1)
  98
  99       data = %{
 100         "ok" => true,
 101         "object" => %{
 102           "content" => random_text
 103         }
 104       }
 105
 106       assert {:error, {:remote_limit_error, _}} = ActivityPub.insert(data)
 107     end
 108
 109     test "returns the activity if one with the same id is already in" do
 110       activity = insert(:note_activity)
 111       {:ok, new_activity} = ActivityPub.insert(activity.data)
 112
 113       assert activity == new_activity
 114     end
 115
 116     test "inserts a given map into the activity database, giving it an id if it has none." do
 117       data = %{
 118         "ok" => true
 119       }
 120
 121       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 122       assert activity.data["ok"] == data["ok"]
 123       assert is_binary(activity.data["id"])
 124
 125       given_id = "bla"
 126
 127       data = %{
 128         "ok" => true,
 129         "id" => given_id,
 130         "context" => "blabla"
 131       }
 132
 133       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 134       assert activity.data["ok"] == data["ok"]
 135       assert activity.data["id"] == given_id
 136       assert activity.data["context"] == "blabla"
 137       assert activity.data["context_id"]
 138     end
 139
 140     test "adds a context when none is there" do
 141       data = %{
 142         "id" => "some_id",
 143         "object" => %{
 144           "id" => "object_id"
 145         }
 146       }
 147
 148       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 149
 150       assert is_binary(activity.data["context"])
 151       assert is_binary(activity.data["object"]["context"])
 152       assert activity.data["context_id"]
 153       assert activity.data["object"]["context_id"]
 154     end
 155
 156     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
 157       data = %{
 158         "object" => %{
 159           "type" => "Note",
 160           "ok" => true
 161         }
 162       }
 163
 164       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 165       assert is_binary(activity.data["object"]["id"])
 166       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
 167     end
 168   end
 169
 170   describe "create activities" do
 171     test "removes doubled 'to' recipients" do
 172       user = insert(:user)
 173
 174       {:ok, activity} =
 175         ActivityPub.create(%{
 176           to: ["user1", "user1", "user2"],
 177           actor: user,
 178           context: "",
 179           object: %{}
 180         })
 181
 182       assert activity.data["to"] == ["user1", "user2"]
 183       assert activity.actor == user.ap_id
 184       assert activity.recipients == ["user1", "user2", user.ap_id]
 185     end
 186   end
 187
 188   describe "fetch activities for recipients" do
 189     test "retrieve the activities for certain recipients" do
 190       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 191       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 192       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 193
 194       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 195       assert length(activities) == 2
 196       assert activities == [activity_one, activity_two]
 197     end
 198   end
 199
 200   describe "fetch activities in context" do
 201     test "retrieves activities that have a given context" do
 202       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 203       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 204       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 205       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 206       activity_five = insert(:note_activity)
 207       user = insert(:user)
 208
 209       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 210
 211       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 212       assert activities == [activity_two, activity]
 213     end
 214   end
 215
 216   test "doesn't return blocked activities" do
 217     activity_one = insert(:note_activity)
 218     activity_two = insert(:note_activity)
 219     activity_three = insert(:note_activity)
 220     user = insert(:user)
 221     booster = insert(:user)
 222     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 223
 224     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 225
 226     assert Enum.member?(activities, activity_two)
 227     assert Enum.member?(activities, activity_three)
 228     refute Enum.member?(activities, activity_one)
 229
 230     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 231
 232     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 233
 234     assert Enum.member?(activities, activity_two)
 235     assert Enum.member?(activities, activity_three)
 236     assert Enum.member?(activities, activity_one)
 237
 238     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 239     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 240     %Activity{} = boost_activity = Activity.get_create_by_object_ap_id(id)
 241     activity_three = Repo.get(Activity, activity_three.id)
 242
 243     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 244
 245     assert Enum.member?(activities, activity_two)
 246     refute Enum.member?(activities, activity_three)
 247     refute Enum.member?(activities, boost_activity)
 248     assert Enum.member?(activities, activity_one)
 249
 250     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 251
 252     assert Enum.member?(activities, activity_two)
 253     assert Enum.member?(activities, activity_three)
 254     assert Enum.member?(activities, boost_activity)
 255     assert Enum.member?(activities, activity_one)
 256   end
 257
 258   test "excludes reblogs on request" do
 259     user = insert(:user)
 260     {:ok, expected_activity} = ActivityBuilder.insert(%{"type" => "Create"}, %{:user => user})
 261     {:ok, _} = ActivityBuilder.insert(%{"type" => "Announce"}, %{:user => user})
 262
 263     [activity] = ActivityPub.fetch_user_activities(user, nil, %{"exclude_reblogs" => "true"})
 264
 265     assert activity == expected_activity
 266   end
 267
 268   describe "public fetch activities" do
 269     test "doesn't retrieve unlisted activities" do
 270       user = insert(:user)
 271
 272       {:ok, _unlisted_activity} =
 273         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 274
 275       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 276
 277       [activity] = ActivityPub.fetch_public_activities()
 278
 279       assert activity == listed_activity
 280     end
 281
 282     test "retrieves public activities" do
 283       _activities = ActivityPub.fetch_public_activities()
 284
 285       %{public: public} = ActivityBuilder.public_and_non_public()
 286
 287       activities = ActivityPub.fetch_public_activities()
 288       assert length(activities) == 1
 289       assert Enum.at(activities, 0) == public
 290     end
 291
 292     test "retrieves a maximum of 20 activities" do
 293       activities = ActivityBuilder.insert_list(30)
 294       last_expected = List.last(activities)
 295
 296       activities = ActivityPub.fetch_public_activities()
 297       last = List.last(activities)
 298
 299       assert length(activities) == 20
 300       assert last == last_expected
 301     end
 302
 303     test "retrieves ids starting from a since_id" do
 304       activities = ActivityBuilder.insert_list(30)
 305       later_activities = ActivityBuilder.insert_list(10)
 306       since_id = List.last(activities).id
 307       last_expected = List.last(later_activities)
 308
 309       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 310       last = List.last(activities)
 311
 312       assert length(activities) == 10
 313       assert last == last_expected
 314     end
 315
 316     test "retrieves ids up to max_id" do
 317       _first_activities = ActivityBuilder.insert_list(10)
 318       activities = ActivityBuilder.insert_list(20)
 319       later_activities = ActivityBuilder.insert_list(10)
 320       max_id = List.first(later_activities).id
 321       last_expected = List.last(activities)
 322
 323       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 324       last = List.last(activities)
 325
 326       assert length(activities) == 20
 327       assert last == last_expected
 328     end
 329   end
 330
 331   describe "like an object" do
 332     test "adds a like activity to the db" do
 333       note_activity = insert(:note_activity)
 334       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 335       user = insert(:user)
 336       user_two = insert(:user)
 337
 338       {:ok, like_activity, object} = ActivityPub.like(user, object)
 339
 340       assert like_activity.data["actor"] == user.ap_id
 341       assert like_activity.data["type"] == "Like"
 342       assert like_activity.data["object"] == object.data["id"]
 343       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 344       assert like_activity.data["context"] == object.data["context"]
 345       assert object.data["like_count"] == 1
 346       assert object.data["likes"] == [user.ap_id]
 347
 348       # Just return the original activity if the user already liked it.
 349       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 350
 351       assert like_activity == same_like_activity
 352       assert object.data["likes"] == [user.ap_id]
 353
 354       [note_activity] = Activity.get_all_create_by_object_ap_id(object.data["id"])
 355       assert note_activity.data["object"]["like_count"] == 1
 356
 357       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 358       assert object.data["like_count"] == 2
 359     end
 360   end
 361
 362   describe "unliking" do
 363     test "unliking a previously liked object" do
 364       note_activity = insert(:note_activity)
 365       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 366       user = insert(:user)
 367
 368       # Unliking something that hasn't been liked does nothing
 369       {:ok, object} = ActivityPub.unlike(user, object)
 370       assert object.data["like_count"] == 0
 371
 372       {:ok, like_activity, object} = ActivityPub.like(user, object)
 373       assert object.data["like_count"] == 1
 374
 375       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 376       assert object.data["like_count"] == 0
 377
 378       assert Repo.get(Activity, like_activity.id) == nil
 379     end
 380   end
 381
 382   describe "announcing an object" do
 383     test "adds an announce activity to the db" do
 384       note_activity = insert(:note_activity)
 385       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 386       user = insert(:user)
 387
 388       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 389       assert object.data["announcement_count"] == 1
 390       assert object.data["announcements"] == [user.ap_id]
 391
 392       assert announce_activity.data["to"] == [
 393                User.ap_followers(user),
 394                note_activity.data["actor"]
 395              ]
 396
 397       assert announce_activity.data["object"] == object.data["id"]
 398       assert announce_activity.data["actor"] == user.ap_id
 399       assert announce_activity.data["context"] == object.data["context"]
 400     end
 401   end
 402
 403   describe "unannouncing an object" do
 404     test "unannouncing a previously announced object" do
 405       note_activity = insert(:note_activity)
 406       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 407       user = insert(:user)
 408
 409       # Unannouncing an object that is not announced does nothing
 410       # {:ok, object} = ActivityPub.unannounce(user, object)
 411       # assert object.data["announcement_count"] == 0
 412
 413       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 414       assert object.data["announcement_count"] == 1
 415
 416       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 417       assert object.data["announcement_count"] == 0
 418
 419       assert unannounce_activity.data["to"] == [
 420                User.ap_followers(user),
 421                announce_activity.data["actor"]
 422              ]
 423
 424       assert unannounce_activity.data["type"] == "Undo"
 425       assert unannounce_activity.data["object"] == announce_activity.data
 426       assert unannounce_activity.data["actor"] == user.ap_id
 427       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 428
 429       assert Repo.get(Activity, announce_activity.id) == nil
 430     end
 431   end
 432
 433   describe "uploading files" do
 434     test "copies the file to the configured folder" do
 435       file = %Plug.Upload{
 436         content_type: "image/jpg",
 437         path: Path.absname("test/fixtures/image.jpg"),
 438         filename: "an_image.jpg"
 439       }
 440
 441       {:ok, %Object{} = object} = ActivityPub.upload(file)
 442       assert object.data["name"] == "an_image.jpg"
 443     end
 444
 445     test "works with base64 encoded images" do
 446       file = %{
 447         "img" => data_uri()
 448       }
 449
 450       {:ok, %Object{}} = ActivityPub.upload(file)
 451     end
 452   end
 453
 454   describe "fetch the latest Follow" do
 455     test "fetches the latest Follow activity" do
 456       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 457       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 458       followed = Repo.get_by(User, ap_id: activity.data["object"])
 459
 460       assert activity == Utils.fetch_latest_follow(follower, followed)
 461     end
 462   end
 463
 464   describe "fetching an object" do
 465     test "it fetches an object" do
 466       {:ok, object} =
 467         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 468
 469       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 470       assert activity.data["id"]
 471
 472       {:ok, object_again} =
 473         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 474
 475       assert [attachment] = object.data["attachment"]
 476       assert is_list(attachment["url"])
 477
 478       assert object == object_again
 479     end
 480
 481     test "it works with objects only available via Ostatus" do
 482       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 483       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 484       assert activity.data["id"]
 485
 486       {:ok, object_again} =
 487         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 488
 489       assert object == object_again
 490     end
 491
 492     test "it correctly stitches up conversations between ostatus and ap" do
 493       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 494       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 495
 496       object = Object.get_by_ap_id(object.data["inReplyTo"])
 497       assert object
 498     end
 499   end
 500
 501   describe "following / unfollowing" do
 502     test "creates a follow activity" do
 503       follower = insert(:user)
 504       followed = insert(:user)
 505
 506       {:ok, activity} = ActivityPub.follow(follower, followed)
 507       assert activity.data["type"] == "Follow"
 508       assert activity.data["actor"] == follower.ap_id
 509       assert activity.data["object"] == followed.ap_id
 510     end
 511
 512     test "creates an undo activity for the last follow" do
 513       follower = insert(:user)
 514       followed = insert(:user)
 515
 516       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 517       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 518
 519       assert activity.data["type"] == "Undo"
 520       assert activity.data["actor"] == follower.ap_id
 521
 522       assert is_map(activity.data["object"])
 523       assert activity.data["object"]["type"] == "Follow"
 524       assert activity.data["object"]["object"] == followed.ap_id
 525       assert activity.data["object"]["id"] == follow_activity.data["id"]
 526     end
 527   end
 528
 529   describe "blocking / unblocking" do
 530     test "creates a block activity" do
 531       blocker = insert(:user)
 532       blocked = insert(:user)
 533
 534       {:ok, activity} = ActivityPub.block(blocker, blocked)
 535
 536       assert activity.data["type"] == "Block"
 537       assert activity.data["actor"] == blocker.ap_id
 538       assert activity.data["object"] == blocked.ap_id
 539     end
 540
 541     test "creates an undo activity for the last block" do
 542       blocker = insert(:user)
 543       blocked = insert(:user)
 544
 545       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 546       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 547
 548       assert activity.data["type"] == "Undo"
 549       assert activity.data["actor"] == blocker.ap_id
 550
 551       assert is_map(activity.data["object"])
 552       assert activity.data["object"]["type"] == "Block"
 553       assert activity.data["object"]["object"] == blocked.ap_id
 554       assert activity.data["object"]["id"] == block_activity.data["id"]
 555     end
 556   end
 557
 558   describe "deletion" do
 559     test "it creates a delete activity and deletes the original object" do
 560       note = insert(:note_activity)
 561       object = Object.get_by_ap_id(note.data["object"]["id"])
 562       {:ok, delete} = ActivityPub.delete(object)
 563
 564       assert delete.data["type"] == "Delete"
 565       assert delete.data["actor"] == note.data["actor"]
 566       assert delete.data["object"] == note.data["object"]["id"]
 567
 568       assert Repo.get(Activity, delete.id) != nil
 569
 570       assert Repo.get(Object, object.id).data["type"] == "Tombstone"
 571     end
 572   end
 573
 574   describe "timeline post-processing" do
 575     test "it filters broken threads" do
 576       user1 = insert(:user)
 577       user2 = insert(:user)
 578       user3 = insert(:user)
 579
 580       {:ok, user1} = User.follow(user1, user3)
 581       assert User.following?(user1, user3)
 582
 583       {:ok, user2} = User.follow(user2, user3)
 584       assert User.following?(user2, user3)
 585
 586       {:ok, user3} = User.follow(user3, user2)
 587       assert User.following?(user3, user2)
 588
 589       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 590
 591       {:ok, private_activity_1} =
 592         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 593
 594       {:ok, private_activity_2} =
 595         CommonAPI.post(user2, %{
 596           "status" => "hi 3",
 597           "visibility" => "private",
 598           "in_reply_to_status_id" => private_activity_1.id
 599         })
 600
 601       {:ok, private_activity_3} =
 602         CommonAPI.post(user3, %{
 603           "status" => "hi 4",
 604           "visibility" => "private",
 605           "in_reply_to_status_id" => private_activity_2.id
 606         })
 607
 608       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 609
 610       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 611
 612       assert [public_activity, private_activity_1, private_activity_3] == activities
 613       assert length(activities) == 3
 614
 615       activities = ActivityPub.contain_timeline(activities, user1)
 616
 617       assert [public_activity, private_activity_1] == activities
 618       assert length(activities) == 2
 619     end
 620   end
 621
 622   test "it can fetch plume articles" do
 623     {:ok, object} =
 624       ActivityPub.fetch_object_from_id(
 625         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 626       )
 627
 628     assert object
 629   end
 630
 631   describe "update" do
 632     test "it creates an update activity with the new user data" do
 633       user = insert(:user)
 634       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 635       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 636
 637       {:ok, update} =
 638         ActivityPub.update(%{
 639           actor: user_data["id"],
 640           to: [user.follower_address],
 641           cc: [],
 642           object: user_data
 643         })
 644
 645       assert update.data["actor"] == user.ap_id
 646       assert update.data["to"] == [user.follower_address]
 647       assert update.data["object"]["id"] == user_data["id"]
 648       assert update.data["object"]["type"] == user_data["type"]
 649     end
 650   end
 651
 652   test "it can fetch peertube videos" do
 653     {:ok, object} =
 654       ActivityPub.fetch_object_from_id(
 655         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 656       )
 657
 658     assert object
 659   end
 660
 661   test "returned pinned statuses" do
 662     Pleroma.Config.put([:instance, :max_pinned_statuses], 3)
 663     user = insert(:user)
 664
 665     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "HI!!!"})
 666     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 667     {:ok, activity_three} = CommonAPI.post(user, %{"status" => "HI!!!"})
 668
 669     CommonAPI.pin(activity_one.id, user)
 670     user = refresh_record(user)
 671
 672     CommonAPI.pin(activity_two.id, user)
 673     user = refresh_record(user)
 674
 675     CommonAPI.pin(activity_three.id, user)
 676     user = refresh_record(user)
 677
 678     activities = ActivityPub.fetch_user_activities(user, nil, %{"pinned" => "true"})
 679
 680     assert 3 = length(activities)
 681   end
 682
 683   def data_uri do
 684     File.read!("test/fixtures/avatar_data_uri")
 685   end
 686 end