git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.{Activity, Object, User}
   6   alias Pleroma.Builders.ActivityBuilder
   7
   8   import Pleroma.Factory
   9
  10   describe "building a user from his ap id" do
  11     test "it returns a user" do
  12       user_id = "http://mastodon.example.org/users/admin"
  13       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  14       assert user.ap_id == user_id
  15       assert user.nickname == "admin@mastodon.example.org"
  16       assert user.info["source_data"]
  17       assert user.info["ap_enabled"]
  18       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  19     end
  20   end
  21
  22   describe "insertion" do
  23     test "returns the activity if one with the same id is already in" do
  24       activity = insert(:note_activity)
  25       {:ok, new_activity} = ActivityPub.insert(activity.data)
  26
  27       assert activity == new_activity
  28     end
  29
  30     test "inserts a given map into the activity database, giving it an id if it has none." do
  31       data = %{
  32         "ok" => true
  33       }
  34
  35       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  36       assert activity.data["ok"] == data["ok"]
  37       assert is_binary(activity.data["id"])
  38
  39       given_id = "bla"
  40
  41       data = %{
  42         "ok" => true,
  43         "id" => given_id,
  44         "context" => "blabla"
  45       }
  46
  47       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  48       assert activity.data["ok"] == data["ok"]
  49       assert activity.data["id"] == given_id
  50       assert activity.data["context"] == "blabla"
  51       assert activity.data["context_id"]
  52     end
  53
  54     test "adds a context when none is there" do
  55       data = %{
  56         "id" => "some_id",
  57         "object" => %{
  58           "id" => "object_id"
  59         }
  60       }
  61
  62       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  63
  64       assert is_binary(activity.data["context"])
  65       assert is_binary(activity.data["object"]["context"])
  66       assert activity.data["context_id"]
  67       assert activity.data["object"]["context_id"]
  68     end
  69
  70     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
  71       data = %{
  72         "object" => %{
  73           "type" => "Note",
  74           "ok" => true
  75         }
  76       }
  77
  78       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  79       assert is_binary(activity.data["object"]["id"])
  80       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
  81     end
  82   end
  83
  84   describe "create activities" do
  85     test "removes doubled 'to' recipients" do
  86       user = insert(:user)
  87
  88       {:ok, activity} =
  89         ActivityPub.create(%{
  90           to: ["user1", "user1", "user2"],
  91           actor: user,
  92           context: "",
  93           object: %{}
  94         })
  95
  96       assert activity.data["to"] == ["user1", "user2"]
  97       assert activity.actor == user.ap_id
  98       assert activity.recipients == ["user1", "user2"]
  99     end
 100   end
 101
 102   describe "fetch activities for recipients" do
 103     test "retrieve the activities for certain recipients" do
 104       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 105       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 106       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 107
 108       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 109       assert length(activities) == 2
 110       assert activities == [activity_one, activity_two]
 111     end
 112   end
 113
 114   describe "fetch activities in context" do
 115     test "retrieves activities that have a given context" do
 116       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 117       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 118       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 119       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 120       activity_five = insert(:note_activity)
 121       user = insert(:user)
 122
 123       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 124
 125       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 126       assert activities == [activity_two, activity]
 127     end
 128   end
 129
 130   test "doesn't return blocked activities" do
 131     activity_one = insert(:note_activity)
 132     activity_two = insert(:note_activity)
 133     user = insert(:user)
 134     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 135
 136     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 137
 138     assert Enum.member?(activities, activity_two)
 139     refute Enum.member?(activities, activity_one)
 140
 141     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 142
 143     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 144
 145     assert Enum.member?(activities, activity_two)
 146     assert Enum.member?(activities, activity_one)
 147
 148     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 149
 150     assert Enum.member?(activities, activity_two)
 151     assert Enum.member?(activities, activity_one)
 152   end
 153
 154   describe "public fetch activities" do
 155     test "retrieves public activities" do
 156       _activities = ActivityPub.fetch_public_activities()
 157
 158       %{public: public} = ActivityBuilder.public_and_non_public()
 159
 160       activities = ActivityPub.fetch_public_activities()
 161       assert length(activities) == 1
 162       assert Enum.at(activities, 0) == public
 163     end
 164
 165     test "retrieves a maximum of 20 activities" do
 166       activities = ActivityBuilder.insert_list(30)
 167       last_expected = List.last(activities)
 168
 169       activities = ActivityPub.fetch_public_activities()
 170       last = List.last(activities)
 171
 172       assert length(activities) == 20
 173       assert last == last_expected
 174     end
 175
 176     test "retrieves ids starting from a since_id" do
 177       activities = ActivityBuilder.insert_list(30)
 178       later_activities = ActivityBuilder.insert_list(10)
 179       since_id = List.last(activities).id
 180       last_expected = List.last(later_activities)
 181
 182       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 183       last = List.last(activities)
 184
 185       assert length(activities) == 10
 186       assert last == last_expected
 187     end
 188
 189     test "retrieves ids up to max_id" do
 190       _first_activities = ActivityBuilder.insert_list(10)
 191       activities = ActivityBuilder.insert_list(20)
 192       later_activities = ActivityBuilder.insert_list(10)
 193       max_id = List.first(later_activities).id
 194       last_expected = List.last(activities)
 195
 196       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 197       last = List.last(activities)
 198
 199       assert length(activities) == 20
 200       assert last == last_expected
 201     end
 202   end
 203
 204   describe "like an object" do
 205     test "adds a like activity to the db" do
 206       note_activity = insert(:note_activity)
 207       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 208       user = insert(:user)
 209       user_two = insert(:user)
 210
 211       {:ok, like_activity, object} = ActivityPub.like(user, object)
 212
 213       assert like_activity.data["actor"] == user.ap_id
 214       assert like_activity.data["type"] == "Like"
 215       assert like_activity.data["object"] == object.data["id"]
 216       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 217       assert like_activity.data["context"] == object.data["context"]
 218       assert object.data["like_count"] == 1
 219       assert object.data["likes"] == [user.ap_id]
 220
 221       # Just return the original activity if the user already liked it.
 222       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 223
 224       assert like_activity == same_like_activity
 225       assert object.data["likes"] == [user.ap_id]
 226
 227       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 228       assert note_activity.data["object"]["like_count"] == 1
 229
 230       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 231       assert object.data["like_count"] == 2
 232     end
 233   end
 234
 235   describe "unliking" do
 236     test "unliking a previously liked object" do
 237       note_activity = insert(:note_activity)
 238       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 239       user = insert(:user)
 240
 241       # Unliking something that hasn't been liked does nothing
 242       {:ok, object} = ActivityPub.unlike(user, object)
 243       assert object.data["like_count"] == 0
 244
 245       {:ok, like_activity, object} = ActivityPub.like(user, object)
 246       assert object.data["like_count"] == 1
 247
 248       {:ok, object} = ActivityPub.unlike(user, object)
 249       assert object.data["like_count"] == 0
 250
 251       assert Repo.get(Activity, like_activity.id) == nil
 252     end
 253   end
 254
 255   describe "announcing an object" do
 256     test "adds an announce activity to the db" do
 257       note_activity = insert(:note_activity)
 258       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 259       user = insert(:user)
 260
 261       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 262       assert object.data["announcement_count"] == 1
 263       assert object.data["announcements"] == [user.ap_id]
 264
 265       assert announce_activity.data["to"] == [
 266                User.ap_followers(user),
 267                note_activity.data["actor"]
 268              ]
 269
 270       assert announce_activity.data["object"] == object.data["id"]
 271       assert announce_activity.data["actor"] == user.ap_id
 272       assert announce_activity.data["context"] == object.data["context"]
 273     end
 274   end
 275
 276   describe "unannouncing an object" do
 277     test "unannouncing a previously announced object" do
 278       note_activity = insert(:note_activity)
 279       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 280       user = insert(:user)
 281
 282       # Unannouncing an object that is not announced does nothing
 283       # {:ok, object} = ActivityPub.unannounce(user, object)
 284       # assert object.data["announcement_count"] == 0
 285
 286       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 287       assert object.data["announcement_count"] == 1
 288
 289       {:ok, unannounce_activity, activity, object} = ActivityPub.unannounce(user, object)
 290       assert object.data["announcement_count"] == 0
 291
 292       assert activity == announce_activity
 293
 294       assert unannounce_activity.data["to"] == [
 295                User.ap_followers(user),
 296                announce_activity.data["actor"]
 297              ]
 298
 299       assert unannounce_activity.data["type"] == "Undo"
 300       assert unannounce_activity.data["object"] == announce_activity.data["id"]
 301       assert unannounce_activity.data["actor"] == user.ap_id
 302       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 303
 304       assert Repo.get(Activity, announce_activity.id) == nil
 305     end
 306   end
 307
 308   describe "uploading files" do
 309     test "copies the file to the configured folder" do
 310       file = %Plug.Upload{
 311         content_type: "image/jpg",
 312         path: Path.absname("test/fixtures/image.jpg"),
 313         filename: "an_image.jpg"
 314       }
 315
 316       {:ok, %Object{} = object} = ActivityPub.upload(file)
 317       assert object.data["name"] == "an_image.jpg"
 318     end
 319
 320     test "works with base64 encoded images" do
 321       file = %{
 322         "img" => data_uri()
 323       }
 324
 325       {:ok, %Object{}} = ActivityPub.upload(file)
 326     end
 327   end
 328
 329   describe "fetch the latest Follow" do
 330     test "fetches the latest Follow activity" do
 331       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 332       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 333       followed = Repo.get_by(User, ap_id: activity.data["object"])
 334
 335       assert activity == Utils.fetch_latest_follow(follower, followed)
 336     end
 337   end
 338
 339   describe "fetching an object" do
 340     test "it fetches an object" do
 341       {:ok, object} =
 342         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 343
 344       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 345       assert activity.data["id"]
 346
 347       {:ok, object_again} =
 348         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 349
 350       assert [attachment] = object.data["attachment"]
 351       assert is_list(attachment["url"])
 352
 353       assert object == object_again
 354     end
 355
 356     test "it works with objects only available via Ostatus" do
 357       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 358       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 359       assert activity.data["id"]
 360
 361       {:ok, object_again} =
 362         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 363
 364       assert object == object_again
 365     end
 366
 367     test "it correctly stitches up conversations between ostatus and ap" do
 368       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 369       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 370
 371       object = Object.get_by_ap_id(object.data["inReplyTo"])
 372       assert object
 373     end
 374   end
 375
 376   describe "following / unfollowing" do
 377     test "creates a follow activity" do
 378       follower = insert(:user)
 379       followed = insert(:user)
 380
 381       {:ok, activity} = ActivityPub.follow(follower, followed)
 382       assert activity.data["type"] == "Follow"
 383       assert activity.data["actor"] == follower.ap_id
 384       assert activity.data["object"] == followed.ap_id
 385     end
 386
 387     test "creates an undo activity for the last follow" do
 388       follower = insert(:user)
 389       followed = insert(:user)
 390
 391       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 392       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 393
 394       assert activity.data["type"] == "Undo"
 395       assert activity.data["actor"] == follower.ap_id
 396       assert activity.data["object"] == follow_activity.data["id"]
 397     end
 398   end
 399
 400   describe "deletion" do
 401     test "it creates a delete activity and deletes the original object" do
 402       note = insert(:note_activity)
 403       object = Object.get_by_ap_id(note.data["object"]["id"])
 404       {:ok, delete} = ActivityPub.delete(object)
 405
 406       assert delete.data["type"] == "Delete"
 407       assert delete.data["actor"] == note.data["actor"]
 408       assert delete.data["object"] == note.data["object"]["id"]
 409
 410       assert Repo.get(Activity, delete.id) != nil
 411
 412       assert Repo.get(Object, object.id) == nil
 413     end
 414   end
 415
 416   describe "update" do
 417     test "it creates an update activity with the new user data" do
 418       user = insert(:user)
 419       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 420       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 421
 422       {:ok, update} =
 423         ActivityPub.update(%{
 424           actor: user_data["id"],
 425           to: [user.follower_address],
 426           cc: [],
 427           object: user_data
 428         })
 429
 430       assert update.data["actor"] == user.ap_id
 431       assert update.data["to"] == [user.follower_address]
 432       assert update.data["object"]["id"] == user_data["id"]
 433       assert update.data["object"]["type"] == user_data["type"]
 434     end
 435   end
 436
 437   def data_uri do
 438     File.read!("test/fixtures/avatar_data_uri")
 439   end
 440 end