git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.{Activity, Object, User}
   7   alias Pleroma.Builders.ActivityBuilder
   8
   9   import Pleroma.Factory
  10
  11   describe "building a user from his ap id" do
  12     test "it returns a user" do
  13       user_id = "http://mastodon.example.org/users/admin"
  14       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  15       assert user.ap_id == user_id
  16       assert user.nickname == "admin@mastodon.example.org"
  17       assert user.info["source_data"]
  18       assert user.info["ap_enabled"]
  19       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  20     end
  21   end
  22
  23   describe "insertion" do
  24     test "returns the activity if one with the same id is already in" do
  25       activity = insert(:note_activity)
  26       {:ok, new_activity} = ActivityPub.insert(activity.data)
  27
  28       assert activity == new_activity
  29     end
  30
  31     test "inserts a given map into the activity database, giving it an id if it has none." do
  32       data = %{
  33         "ok" => true
  34       }
  35
  36       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  37       assert activity.data["ok"] == data["ok"]
  38       assert is_binary(activity.data["id"])
  39
  40       given_id = "bla"
  41
  42       data = %{
  43         "ok" => true,
  44         "id" => given_id,
  45         "context" => "blabla"
  46       }
  47
  48       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  49       assert activity.data["ok"] == data["ok"]
  50       assert activity.data["id"] == given_id
  51       assert activity.data["context"] == "blabla"
  52       assert activity.data["context_id"]
  53     end
  54
  55     test "adds a context when none is there" do
  56       data = %{
  57         "id" => "some_id",
  58         "object" => %{
  59           "id" => "object_id"
  60         }
  61       }
  62
  63       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  64
  65       assert is_binary(activity.data["context"])
  66       assert is_binary(activity.data["object"]["context"])
  67       assert activity.data["context_id"]
  68       assert activity.data["object"]["context_id"]
  69     end
  70
  71     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
  72       data = %{
  73         "object" => %{
  74           "type" => "Note",
  75           "ok" => true
  76         }
  77       }
  78
  79       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  80       assert is_binary(activity.data["object"]["id"])
  81       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
  82     end
  83   end
  84
  85   describe "create activities" do
  86     test "removes doubled 'to' recipients" do
  87       user = insert(:user)
  88
  89       {:ok, activity} =
  90         ActivityPub.create(%{
  91           to: ["user1", "user1", "user2"],
  92           actor: user,
  93           context: "",
  94           object: %{}
  95         })
  96
  97       assert activity.data["to"] == ["user1", "user2"]
  98       assert activity.actor == user.ap_id
  99       assert activity.recipients == ["user1", "user2"]
 100     end
 101   end
 102
 103   describe "fetch activities for recipients" do
 104     test "retrieve the activities for certain recipients" do
 105       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 106       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 107       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 108
 109       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 110       assert length(activities) == 2
 111       assert activities == [activity_one, activity_two]
 112     end
 113   end
 114
 115   describe "fetch activities in context" do
 116     test "retrieves activities that have a given context" do
 117       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 118       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 119       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 120       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 121       activity_five = insert(:note_activity)
 122       user = insert(:user)
 123
 124       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 125
 126       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 127       assert activities == [activity_two, activity]
 128     end
 129   end
 130
 131   test "doesn't return blocked activities" do
 132     activity_one = insert(:note_activity)
 133     activity_two = insert(:note_activity)
 134     activity_three = insert(:note_activity)
 135     user = insert(:user)
 136     booster = insert(:user)
 137     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 138
 139     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 140
 141     assert Enum.member?(activities, activity_two)
 142     assert Enum.member?(activities, activity_three)
 143     refute Enum.member?(activities, activity_one)
 144
 145     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 146
 147     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 148
 149     assert Enum.member?(activities, activity_two)
 150     assert Enum.member?(activities, activity_three)
 151     assert Enum.member?(activities, activity_one)
 152
 153     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 154     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 155     %Activity{} = boost_activity = Activity.get_create_activity_by_object_ap_id(id)
 156     activity_three = Repo.get(Activity, activity_three.id)
 157
 158     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 159
 160     assert Enum.member?(activities, activity_two)
 161     refute Enum.member?(activities, activity_three)
 162     refute Enum.member?(activities, boost_activity)
 163     assert Enum.member?(activities, activity_one)
 164
 165     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 166
 167     assert Enum.member?(activities, activity_two)
 168     assert Enum.member?(activities, activity_three)
 169     assert Enum.member?(activities, boost_activity)
 170     assert Enum.member?(activities, activity_one)
 171   end
 172
 173   describe "public fetch activities" do
 174     test "doesn't retrieve unlisted activities" do
 175       user = insert(:user)
 176       {:ok, unlisted_activity} = CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 177       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 178
 179       [activity] = ActivityPub.fetch_public_activities()
 180
 181       assert activity == listed_activity
 182     end
 183
 184     test "retrieves public activities" do
 185       _activities = ActivityPub.fetch_public_activities()
 186
 187       %{public: public} = ActivityBuilder.public_and_non_public()
 188
 189       activities = ActivityPub.fetch_public_activities()
 190       assert length(activities) == 1
 191       assert Enum.at(activities, 0) == public
 192     end
 193
 194     test "retrieves a maximum of 20 activities" do
 195       activities = ActivityBuilder.insert_list(30)
 196       last_expected = List.last(activities)
 197
 198       activities = ActivityPub.fetch_public_activities()
 199       last = List.last(activities)
 200
 201       assert length(activities) == 20
 202       assert last == last_expected
 203     end
 204
 205     test "retrieves ids starting from a since_id" do
 206       activities = ActivityBuilder.insert_list(30)
 207       later_activities = ActivityBuilder.insert_list(10)
 208       since_id = List.last(activities).id
 209       last_expected = List.last(later_activities)
 210
 211       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 212       last = List.last(activities)
 213
 214       assert length(activities) == 10
 215       assert last == last_expected
 216     end
 217
 218     test "retrieves ids up to max_id" do
 219       _first_activities = ActivityBuilder.insert_list(10)
 220       activities = ActivityBuilder.insert_list(20)
 221       later_activities = ActivityBuilder.insert_list(10)
 222       max_id = List.first(later_activities).id
 223       last_expected = List.last(activities)
 224
 225       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 226       last = List.last(activities)
 227
 228       assert length(activities) == 20
 229       assert last == last_expected
 230     end
 231   end
 232
 233   describe "like an object" do
 234     test "adds a like activity to the db" do
 235       note_activity = insert(:note_activity)
 236       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 237       user = insert(:user)
 238       user_two = insert(:user)
 239
 240       {:ok, like_activity, object} = ActivityPub.like(user, object)
 241
 242       assert like_activity.data["actor"] == user.ap_id
 243       assert like_activity.data["type"] == "Like"
 244       assert like_activity.data["object"] == object.data["id"]
 245       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 246       assert like_activity.data["context"] == object.data["context"]
 247       assert object.data["like_count"] == 1
 248       assert object.data["likes"] == [user.ap_id]
 249
 250       # Just return the original activity if the user already liked it.
 251       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 252
 253       assert like_activity == same_like_activity
 254       assert object.data["likes"] == [user.ap_id]
 255
 256       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 257       assert note_activity.data["object"]["like_count"] == 1
 258
 259       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 260       assert object.data["like_count"] == 2
 261     end
 262   end
 263
 264   describe "unliking" do
 265     test "unliking a previously liked object" do
 266       note_activity = insert(:note_activity)
 267       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 268       user = insert(:user)
 269
 270       # Unliking something that hasn't been liked does nothing
 271       {:ok, object} = ActivityPub.unlike(user, object)
 272       assert object.data["like_count"] == 0
 273
 274       {:ok, like_activity, object} = ActivityPub.like(user, object)
 275       assert object.data["like_count"] == 1
 276
 277       {:ok, object} = ActivityPub.unlike(user, object)
 278       assert object.data["like_count"] == 0
 279
 280       assert Repo.get(Activity, like_activity.id) == nil
 281     end
 282   end
 283
 284   describe "announcing an object" do
 285     test "adds an announce activity to the db" do
 286       note_activity = insert(:note_activity)
 287       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 288       user = insert(:user)
 289
 290       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 291       assert object.data["announcement_count"] == 1
 292       assert object.data["announcements"] == [user.ap_id]
 293
 294       assert announce_activity.data["to"] == [
 295                User.ap_followers(user),
 296                note_activity.data["actor"]
 297              ]
 298
 299       assert announce_activity.data["object"] == object.data["id"]
 300       assert announce_activity.data["actor"] == user.ap_id
 301       assert announce_activity.data["context"] == object.data["context"]
 302     end
 303   end
 304
 305   describe "uploading files" do
 306     test "copies the file to the configured folder" do
 307       file = %Plug.Upload{
 308         content_type: "image/jpg",
 309         path: Path.absname("test/fixtures/image.jpg"),
 310         filename: "an_image.jpg"
 311       }
 312
 313       {:ok, %Object{} = object} = ActivityPub.upload(file)
 314       assert object.data["name"] == "an_image.jpg"
 315     end
 316
 317     test "works with base64 encoded images" do
 318       file = %{
 319         "img" => data_uri()
 320       }
 321
 322       {:ok, %Object{}} = ActivityPub.upload(file)
 323     end
 324   end
 325
 326   describe "fetch the latest Follow" do
 327     test "fetches the latest Follow activity" do
 328       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 329       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 330       followed = Repo.get_by(User, ap_id: activity.data["object"])
 331
 332       assert activity == Utils.fetch_latest_follow(follower, followed)
 333     end
 334   end
 335
 336   describe "fetching an object" do
 337     test "it fetches an object" do
 338       {:ok, object} =
 339         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 340
 341       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 342       assert activity.data["id"]
 343
 344       {:ok, object_again} =
 345         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 346
 347       assert [attachment] = object.data["attachment"]
 348       assert is_list(attachment["url"])
 349
 350       assert object == object_again
 351     end
 352
 353     test "it works with objects only available via Ostatus" do
 354       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 355       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 356       assert activity.data["id"]
 357
 358       {:ok, object_again} =
 359         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 360
 361       assert object == object_again
 362     end
 363
 364     test "it correctly stitches up conversations between ostatus and ap" do
 365       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 366       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 367
 368       object = Object.get_by_ap_id(object.data["inReplyTo"])
 369       assert object
 370     end
 371   end
 372
 373   describe "following / unfollowing" do
 374     test "creates a follow activity" do
 375       follower = insert(:user)
 376       followed = insert(:user)
 377
 378       {:ok, activity} = ActivityPub.follow(follower, followed)
 379       assert activity.data["type"] == "Follow"
 380       assert activity.data["actor"] == follower.ap_id
 381       assert activity.data["object"] == followed.ap_id
 382     end
 383
 384     test "creates an undo activity for the last follow" do
 385       follower = insert(:user)
 386       followed = insert(:user)
 387
 388       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 389       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 390
 391       assert activity.data["type"] == "Undo"
 392       assert activity.data["actor"] == follower.ap_id
 393       assert activity.data["object"] == follow_activity.data["id"]
 394     end
 395   end
 396
 397   describe "deletion" do
 398     test "it creates a delete activity and deletes the original object" do
 399       note = insert(:note_activity)
 400       object = Object.get_by_ap_id(note.data["object"]["id"])
 401       {:ok, delete} = ActivityPub.delete(object)
 402
 403       assert delete.data["type"] == "Delete"
 404       assert delete.data["actor"] == note.data["actor"]
 405       assert delete.data["object"] == note.data["object"]["id"]
 406
 407       assert Repo.get(Activity, delete.id) != nil
 408
 409       assert Repo.get(Object, object.id) == nil
 410     end
 411   end
 412
 413   describe "update" do
 414     test "it creates an update activity with the new user data" do
 415       user = insert(:user)
 416       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 417       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 418
 419       {:ok, update} =
 420         ActivityPub.update(%{
 421           actor: user_data["id"],
 422           to: [user.follower_address],
 423           cc: [],
 424           object: user_data
 425         })
 426
 427       assert update.data["actor"] == user.ap_id
 428       assert update.data["to"] == [user.follower_address]
 429       assert update.data["object"]["id"] == user_data["id"]
 430       assert update.data["object"]["type"] == user_data["type"]
 431     end
 432   end
 433
 434   def data_uri do
 435     File.read!("test/fixtures/avatar_data_uri")
 436   end
 437 end