git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.{Activity, Object, User}
   7   alias Pleroma.Builders.ActivityBuilder
   8
   9   import Pleroma.Factory
  10
  11   describe "building a user from his ap id" do
  12     test "it returns a user" do
  13       user_id = "http://mastodon.example.org/users/admin"
  14       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  15       assert user.ap_id == user_id
  16       assert user.nickname == "admin@mastodon.example.org"
  17       assert user.info.source_data
  18       assert user.info.ap_enabled
  19       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  20     end
  21   end
  22
  23   describe "insertion" do
  24     test "returns the activity if one with the same id is already in" do
  25       activity = insert(:note_activity)
  26       {:ok, new_activity} = ActivityPub.insert(activity.data)
  27
  28       assert activity == new_activity
  29     end
  30
  31     test "inserts a given map into the activity database, giving it an id if it has none." do
  32       data = %{
  33         "ok" => true
  34       }
  35
  36       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  37       assert activity.data["ok"] == data["ok"]
  38       assert is_binary(activity.data["id"])
  39
  40       given_id = "bla"
  41
  42       data = %{
  43         "ok" => true,
  44         "id" => given_id,
  45         "context" => "blabla"
  46       }
  47
  48       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  49       assert activity.data["ok"] == data["ok"]
  50       assert activity.data["id"] == given_id
  51       assert activity.data["context"] == "blabla"
  52       assert activity.data["context_id"]
  53     end
  54
  55     test "adds a context when none is there" do
  56       data = %{
  57         "id" => "some_id",
  58         "object" => %{
  59           "id" => "object_id"
  60         }
  61       }
  62
  63       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  64
  65       assert is_binary(activity.data["context"])
  66       assert is_binary(activity.data["object"]["context"])
  67       assert activity.data["context_id"]
  68       assert activity.data["object"]["context_id"]
  69     end
  70
  71     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
  72       data = %{
  73         "object" => %{
  74           "type" => "Note",
  75           "ok" => true
  76         }
  77       }
  78
  79       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  80       object = Object.normalize(activity.data["object"])
  81
  82       assert is_binary(object.data["id"])
  83       assert %Object{} = Object.get_by_ap_id(activity.data["object"])
  84     end
  85   end
  86
  87   describe "create activities" do
  88     test "removes doubled 'to' recipients" do
  89       user = insert(:user)
  90
  91       {:ok, activity} =
  92         ActivityPub.create(%{
  93           to: ["user1", "user1", "user2"],
  94           actor: user,
  95           context: "",
  96           object: %{
  97             "to" => ["user1", "user1", "user2"],
  98             "type" => "Note",
  99             "content" => "testing"
 100           }
 101         })
 102
 103       assert activity.data["to"] == ["user1", "user2"]
 104       assert activity.actor == user.ap_id
 105       assert activity.recipients == ["user1", "user2"]
 106     end
 107   end
 108
 109   describe "fetch activities for recipients" do
 110     test "retrieve the activities for certain recipients" do
 111       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 112       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 113       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 114
 115       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 116       assert length(activities) == 2
 117       assert activities == [activity_one, activity_two]
 118     end
 119   end
 120
 121   describe "fetch activities in context" do
 122     test "retrieves activities that have a given context" do
 123       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 124       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 125       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 126       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 127       activity_five = insert(:note_activity)
 128       user = insert(:user)
 129
 130       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 131
 132       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 133       assert activities == [activity_two, activity]
 134     end
 135   end
 136
 137   test "doesn't return blocked activities" do
 138     activity_one = insert(:note_activity)
 139     activity_two = insert(:note_activity)
 140     activity_three = insert(:note_activity)
 141     user = insert(:user)
 142     booster = insert(:user)
 143     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 144
 145     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 146
 147     assert Enum.member?(activities, activity_two)
 148     assert Enum.member?(activities, activity_three)
 149     refute Enum.member?(activities, activity_one)
 150
 151     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 152
 153     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 154
 155     assert Enum.member?(activities, activity_two)
 156     assert Enum.member?(activities, activity_three)
 157     assert Enum.member?(activities, activity_one)
 158
 159     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 160     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 161     %Activity{} = boost_activity = Activity.get_create_activity_by_object_ap_id(id)
 162     activity_three = Repo.get(Activity, activity_three.id)
 163
 164     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 165
 166     assert Enum.member?(activities, activity_two)
 167     refute Enum.member?(activities, activity_three)
 168     refute Enum.member?(activities, boost_activity)
 169     assert Enum.member?(activities, activity_one)
 170
 171     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 172
 173     assert Enum.member?(activities, activity_two)
 174     assert Enum.member?(activities, activity_three)
 175     assert Enum.member?(activities, boost_activity)
 176     assert Enum.member?(activities, activity_one)
 177   end
 178
 179   describe "public fetch activities" do
 180     test "doesn't retrieve unlisted activities" do
 181       user = insert(:user)
 182
 183       {:ok, unlisted_activity} =
 184         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 185
 186       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 187
 188       [activity] = ActivityPub.fetch_public_activities()
 189
 190       assert activity == listed_activity
 191     end
 192
 193     test "retrieves public activities" do
 194       _activities = ActivityPub.fetch_public_activities()
 195
 196       %{public: public} = ActivityBuilder.public_and_non_public()
 197
 198       activities = ActivityPub.fetch_public_activities()
 199       assert length(activities) == 1
 200       assert Enum.at(activities, 0) == public
 201     end
 202
 203     test "retrieves a maximum of 20 activities" do
 204       activities = ActivityBuilder.insert_list(30)
 205       last_expected = List.last(activities)
 206
 207       activities = ActivityPub.fetch_public_activities()
 208       last = List.last(activities)
 209
 210       assert length(activities) == 20
 211       assert last == last_expected
 212     end
 213
 214     test "retrieves ids starting from a since_id" do
 215       activities = ActivityBuilder.insert_list(30)
 216       later_activities = ActivityBuilder.insert_list(10)
 217       since_id = List.last(activities).id
 218       last_expected = List.last(later_activities)
 219
 220       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 221       last = List.last(activities)
 222
 223       assert length(activities) == 10
 224       assert last == last_expected
 225     end
 226
 227     test "retrieves ids up to max_id" do
 228       _first_activities = ActivityBuilder.insert_list(10)
 229       activities = ActivityBuilder.insert_list(20)
 230       later_activities = ActivityBuilder.insert_list(10)
 231       max_id = List.first(later_activities).id
 232       last_expected = List.last(activities)
 233
 234       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 235       last = List.last(activities)
 236
 237       assert length(activities) == 20
 238       assert last == last_expected
 239     end
 240   end
 241
 242   describe "like an object" do
 243     test "adds a like activity to the db" do
 244       note_activity = insert(:note_activity)
 245       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 246       user = insert(:user)
 247       user_two = insert(:user)
 248
 249       {:ok, like_activity, object} = ActivityPub.like(user, object)
 250
 251       assert like_activity.data["actor"] == user.ap_id
 252       assert like_activity.data["type"] == "Like"
 253       assert like_activity.data["object"] == object.data["id"]
 254       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 255       assert like_activity.data["context"] == object.data["context"]
 256       assert object.data["like_count"] == 1
 257       assert object.data["likes"] == [user.ap_id]
 258
 259       # Just return the original activity if the user already liked it.
 260       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 261
 262       assert like_activity == same_like_activity
 263       assert object.data["likes"] == [user.ap_id]
 264
 265       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 266       assert note_activity.data["object"]["like_count"] == 1
 267
 268       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 269       assert object.data["like_count"] == 2
 270     end
 271   end
 272
 273   describe "unliking" do
 274     test "unliking a previously liked object" do
 275       note_activity = insert(:note_activity)
 276       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 277       user = insert(:user)
 278
 279       # Unliking something that hasn't been liked does nothing
 280       {:ok, object} = ActivityPub.unlike(user, object)
 281       assert object.data["like_count"] == 0
 282
 283       {:ok, like_activity, object} = ActivityPub.like(user, object)
 284       assert object.data["like_count"] == 1
 285
 286       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 287       assert object.data["like_count"] == 0
 288
 289       assert Repo.get(Activity, like_activity.id) == nil
 290     end
 291   end
 292
 293   describe "announcing an object" do
 294     test "adds an announce activity to the db" do
 295       note_activity = insert(:note_activity)
 296       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 297       user = insert(:user)
 298
 299       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 300       assert object.data["announcement_count"] == 1
 301       assert object.data["announcements"] == [user.ap_id]
 302
 303       assert announce_activity.data["to"] == [
 304                User.ap_followers(user),
 305                note_activity.data["actor"]
 306              ]
 307
 308       assert announce_activity.data["object"] == object.data["id"]
 309       assert announce_activity.data["actor"] == user.ap_id
 310       assert announce_activity.data["context"] == object.data["context"]
 311     end
 312   end
 313
 314   describe "unannouncing an object" do
 315     test "unannouncing a previously announced object" do
 316       note_activity = insert(:note_activity)
 317       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 318       user = insert(:user)
 319
 320       # Unannouncing an object that is not announced does nothing
 321       # {:ok, object} = ActivityPub.unannounce(user, object)
 322       # assert object.data["announcement_count"] == 0
 323
 324       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 325       assert object.data["announcement_count"] == 1
 326
 327       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 328       assert object.data["announcement_count"] == 0
 329
 330       assert unannounce_activity.data["to"] == [
 331                User.ap_followers(user),
 332                announce_activity.data["actor"]
 333              ]
 334
 335       assert unannounce_activity.data["type"] == "Undo"
 336       assert unannounce_activity.data["object"] == announce_activity.data
 337       assert unannounce_activity.data["actor"] == user.ap_id
 338       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 339
 340       assert Repo.get(Activity, announce_activity.id) == nil
 341     end
 342   end
 343
 344   describe "uploading files" do
 345     test "copies the file to the configured folder" do
 346       file = %Plug.Upload{
 347         content_type: "image/jpg",
 348         path: Path.absname("test/fixtures/image.jpg"),
 349         filename: "an_image.jpg"
 350       }
 351
 352       {:ok, %Object{} = object} = ActivityPub.upload(file)
 353       assert object.data["name"] == "an_image.jpg"
 354     end
 355
 356     test "works with base64 encoded images" do
 357       file = %{
 358         "img" => data_uri()
 359       }
 360
 361       {:ok, %Object{}} = ActivityPub.upload(file)
 362     end
 363   end
 364
 365   describe "fetch the latest Follow" do
 366     test "fetches the latest Follow activity" do
 367       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 368       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 369       followed = Repo.get_by(User, ap_id: activity.data["object"])
 370
 371       assert activity == Utils.fetch_latest_follow(follower, followed)
 372     end
 373   end
 374
 375   describe "following / unfollowing" do
 376     test "creates a follow activity" do
 377       follower = insert(:user)
 378       followed = insert(:user)
 379
 380       {:ok, activity} = ActivityPub.follow(follower, followed)
 381       assert activity.data["type"] == "Follow"
 382       assert activity.data["actor"] == follower.ap_id
 383       assert activity.data["object"] == followed.ap_id
 384     end
 385
 386     test "creates an undo activity for the last follow" do
 387       follower = insert(:user)
 388       followed = insert(:user)
 389
 390       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 391       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 392
 393       assert activity.data["type"] == "Undo"
 394       assert activity.data["actor"] == follower.ap_id
 395
 396       assert is_map(activity.data["object"])
 397       assert activity.data["object"]["type"] == "Follow"
 398       assert activity.data["object"]["object"] == followed.ap_id
 399       assert activity.data["object"]["id"] == follow_activity.data["id"]
 400     end
 401   end
 402
 403   describe "blocking / unblocking" do
 404     test "creates a block activity" do
 405       blocker = insert(:user)
 406       blocked = insert(:user)
 407
 408       {:ok, activity} = ActivityPub.block(blocker, blocked)
 409
 410       assert activity.data["type"] == "Block"
 411       assert activity.data["actor"] == blocker.ap_id
 412       assert activity.data["object"] == blocked.ap_id
 413     end
 414
 415     test "creates an undo activity for the last block" do
 416       blocker = insert(:user)
 417       blocked = insert(:user)
 418
 419       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 420       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 421
 422       assert activity.data["type"] == "Undo"
 423       assert activity.data["actor"] == blocker.ap_id
 424
 425       assert is_map(activity.data["object"])
 426       assert activity.data["object"]["type"] == "Block"
 427       assert activity.data["object"]["object"] == blocked.ap_id
 428       assert activity.data["object"]["id"] == block_activity.data["id"]
 429     end
 430   end
 431
 432   describe "deletion" do
 433     test "it creates a delete activity and deletes the original object" do
 434       note = insert(:note_activity)
 435       object = Object.get_by_ap_id(note.data["object"]["id"])
 436       {:ok, delete} = ActivityPub.delete(object)
 437
 438       assert delete.data["type"] == "Delete"
 439       assert delete.data["actor"] == note.data["actor"]
 440       assert delete.data["object"] == note.data["object"]["id"]
 441
 442       assert Repo.get(Activity, delete.id) != nil
 443
 444       assert Repo.get(Object, object.id) == nil
 445     end
 446   end
 447
 448   describe "timeline post-processing" do
 449     test "it filters broken threads" do
 450       user1 = insert(:user)
 451       user2 = insert(:user)
 452       user3 = insert(:user)
 453
 454       {:ok, user1} = User.follow(user1, user3)
 455       assert User.following?(user1, user3)
 456
 457       {:ok, user2} = User.follow(user2, user3)
 458       assert User.following?(user2, user3)
 459
 460       {:ok, user3} = User.follow(user3, user2)
 461       assert User.following?(user3, user2)
 462
 463       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 464
 465       {:ok, private_activity_1} =
 466         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 467
 468       {:ok, private_activity_2} =
 469         CommonAPI.post(user2, %{
 470           "status" => "hi 3",
 471           "visibility" => "private",
 472           "in_reply_to_status_id" => private_activity_1.id
 473         })
 474
 475       {:ok, private_activity_3} =
 476         CommonAPI.post(user3, %{
 477           "status" => "hi 4",
 478           "visibility" => "private",
 479           "in_reply_to_status_id" => private_activity_2.id
 480         })
 481
 482       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 483
 484       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 485
 486       assert [public_activity, private_activity_1, private_activity_3] == activities
 487       assert length(activities) == 3
 488
 489       activities = ActivityPub.contain_timeline(activities, user1)
 490
 491       assert [public_activity, private_activity_1] == activities
 492       assert length(activities) == 2
 493     end
 494   end
 495
 496   describe "update" do
 497     test "it creates an update activity with the new user data" do
 498       user = insert(:user)
 499       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 500       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 501
 502       {:ok, update} =
 503         ActivityPub.update(%{
 504           actor: user_data["id"],
 505           to: [user.follower_address],
 506           cc: [],
 507           object: user_data
 508         })
 509
 510       assert update.data["actor"] == user.ap_id
 511       assert update.data["to"] == [user.follower_address]
 512       assert update.data["object"]["id"] == user_data["id"]
 513       assert update.data["object"]["type"] == user_data["type"]
 514     end
 515   end
 516
 517   def data_uri do
 518     File.read!("test/fixtures/avatar_data_uri")
 519   end
 520 end