git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.{Activity, Object, User}
   7   alias Pleroma.Builders.ActivityBuilder
   8
   9   import Pleroma.Factory
  10
  11   describe "building a user from his ap id" do
  12     test "it returns a user" do
  13       user_id = "http://mastodon.example.org/users/admin"
  14       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  15       assert user.ap_id == user_id
  16       assert user.nickname == "admin@mastodon.example.org"
  17       assert user.info.source_data
  18       assert user.info.ap_enabled
  19       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  20     end
  21   end
  22
  23   describe "insertion" do
  24     test "returns the activity if one with the same id is already in" do
  25       activity = insert(:note_activity)
  26       {:ok, new_activity} = ActivityPub.insert(activity.data)
  27
  28       assert activity == new_activity
  29     end
  30
  31     test "inserts a given map into the activity database, giving it an id if it has none." do
  32       data = %{
  33         "ok" => true
  34       }
  35
  36       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  37       assert activity.data["ok"] == data["ok"]
  38       assert is_binary(activity.data["id"])
  39
  40       given_id = "bla"
  41
  42       data = %{
  43         "ok" => true,
  44         "id" => given_id,
  45         "context" => "blabla"
  46       }
  47
  48       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  49       assert activity.data["ok"] == data["ok"]
  50       assert activity.data["id"] == given_id
  51       assert activity.data["context"] == "blabla"
  52       assert activity.data["context_id"]
  53     end
  54
  55     test "adds a context when none is there" do
  56       data = %{
  57         "id" => "some_id",
  58         "object" => %{
  59           "id" => "object_id"
  60         }
  61       }
  62
  63       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  64
  65       assert is_binary(activity.data["context"])
  66       assert is_binary(activity.data["object"]["context"])
  67       assert activity.data["context_id"]
  68       assert activity.data["object"]["context_id"]
  69     end
  70
  71     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
  72       data = %{
  73         "object" => %{
  74           "type" => "Note",
  75           "ok" => true
  76         }
  77       }
  78
  79       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  80       object = Object.normalize(activity.data["object"])
  81
  82       assert is_binary(object.data["id"])
  83       assert %Object{} = Object.get_by_ap_id(activity.data["object"])
  84     end
  85   end
  86
  87   describe "create activities" do
  88     test "removes doubled 'to' recipients" do
  89       user = insert(:user)
  90
  91       {:ok, activity} =
  92         ActivityPub.create(%{
  93           to: ["user1", "user1", "user2"],
  94           actor: user,
  95           context: "",
  96           object: %{}
  97         })
  98
  99       assert activity.data["to"] == ["user1", "user2"]
 100       assert activity.actor == user.ap_id
 101       assert activity.recipients == ["user1", "user2"]
 102     end
 103   end
 104
 105   describe "fetch activities for recipients" do
 106     test "retrieve the activities for certain recipients" do
 107       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 108       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 109       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 110
 111       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 112       assert length(activities) == 2
 113       assert activities == [activity_one, activity_two]
 114     end
 115   end
 116
 117   describe "fetch activities in context" do
 118     test "retrieves activities that have a given context" do
 119       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 120       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 121       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 122       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 123       activity_five = insert(:note_activity)
 124       user = insert(:user)
 125
 126       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 127
 128       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 129       assert activities == [activity_two, activity]
 130     end
 131   end
 132
 133   test "doesn't return blocked activities" do
 134     activity_one = insert(:note_activity)
 135     activity_two = insert(:note_activity)
 136     activity_three = insert(:note_activity)
 137     user = insert(:user)
 138     booster = insert(:user)
 139     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 140
 141     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 142
 143     assert Enum.member?(activities, activity_two)
 144     assert Enum.member?(activities, activity_three)
 145     refute Enum.member?(activities, activity_one)
 146
 147     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 148
 149     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 150
 151     assert Enum.member?(activities, activity_two)
 152     assert Enum.member?(activities, activity_three)
 153     assert Enum.member?(activities, activity_one)
 154
 155     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 156     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 157     %Activity{} = boost_activity = Activity.get_create_activity_by_object_ap_id(id)
 158     activity_three = Repo.get(Activity, activity_three.id)
 159
 160     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 161
 162     assert Enum.member?(activities, activity_two)
 163     refute Enum.member?(activities, activity_three)
 164     refute Enum.member?(activities, boost_activity)
 165     assert Enum.member?(activities, activity_one)
 166
 167     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 168
 169     assert Enum.member?(activities, activity_two)
 170     assert Enum.member?(activities, activity_three)
 171     assert Enum.member?(activities, boost_activity)
 172     assert Enum.member?(activities, activity_one)
 173   end
 174
 175   describe "public fetch activities" do
 176     test "doesn't retrieve unlisted activities" do
 177       user = insert(:user)
 178
 179       {:ok, unlisted_activity} =
 180         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 181
 182       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 183
 184       [activity] = ActivityPub.fetch_public_activities()
 185
 186       assert activity == listed_activity
 187     end
 188
 189     test "retrieves public activities" do
 190       _activities = ActivityPub.fetch_public_activities()
 191
 192       %{public: public} = ActivityBuilder.public_and_non_public()
 193
 194       activities = ActivityPub.fetch_public_activities()
 195       assert length(activities) == 1
 196       assert Enum.at(activities, 0) == public
 197     end
 198
 199     test "retrieves a maximum of 20 activities" do
 200       activities = ActivityBuilder.insert_list(30)
 201       last_expected = List.last(activities)
 202
 203       activities = ActivityPub.fetch_public_activities()
 204       last = List.last(activities)
 205
 206       assert length(activities) == 20
 207       assert last == last_expected
 208     end
 209
 210     test "retrieves ids starting from a since_id" do
 211       activities = ActivityBuilder.insert_list(30)
 212       later_activities = ActivityBuilder.insert_list(10)
 213       since_id = List.last(activities).id
 214       last_expected = List.last(later_activities)
 215
 216       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 217       last = List.last(activities)
 218
 219       assert length(activities) == 10
 220       assert last == last_expected
 221     end
 222
 223     test "retrieves ids up to max_id" do
 224       _first_activities = ActivityBuilder.insert_list(10)
 225       activities = ActivityBuilder.insert_list(20)
 226       later_activities = ActivityBuilder.insert_list(10)
 227       max_id = List.first(later_activities).id
 228       last_expected = List.last(activities)
 229
 230       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 231       last = List.last(activities)
 232
 233       assert length(activities) == 20
 234       assert last == last_expected
 235     end
 236   end
 237
 238   describe "like an object" do
 239     test "adds a like activity to the db" do
 240       note_activity = insert(:note_activity)
 241       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 242       user = insert(:user)
 243       user_two = insert(:user)
 244
 245       {:ok, like_activity, object} = ActivityPub.like(user, object)
 246
 247       assert like_activity.data["actor"] == user.ap_id
 248       assert like_activity.data["type"] == "Like"
 249       assert like_activity.data["object"] == object.data["id"]
 250       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 251       assert like_activity.data["context"] == object.data["context"]
 252       assert object.data["like_count"] == 1
 253       assert object.data["likes"] == [user.ap_id]
 254
 255       # Just return the original activity if the user already liked it.
 256       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 257
 258       assert like_activity == same_like_activity
 259       assert object.data["likes"] == [user.ap_id]
 260
 261       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 262       assert note_activity.data["object"]["like_count"] == 1
 263
 264       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 265       assert object.data["like_count"] == 2
 266     end
 267   end
 268
 269   describe "unliking" do
 270     test "unliking a previously liked object" do
 271       note_activity = insert(:note_activity)
 272       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 273       user = insert(:user)
 274
 275       # Unliking something that hasn't been liked does nothing
 276       {:ok, object} = ActivityPub.unlike(user, object)
 277       assert object.data["like_count"] == 0
 278
 279       {:ok, like_activity, object} = ActivityPub.like(user, object)
 280       assert object.data["like_count"] == 1
 281
 282       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 283       assert object.data["like_count"] == 0
 284
 285       assert Repo.get(Activity, like_activity.id) == nil
 286     end
 287   end
 288
 289   describe "announcing an object" do
 290     test "adds an announce activity to the db" do
 291       note_activity = insert(:note_activity)
 292       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 293       user = insert(:user)
 294
 295       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 296       assert object.data["announcement_count"] == 1
 297       assert object.data["announcements"] == [user.ap_id]
 298
 299       assert announce_activity.data["to"] == [
 300                User.ap_followers(user),
 301                note_activity.data["actor"]
 302              ]
 303
 304       assert announce_activity.data["object"] == object.data["id"]
 305       assert announce_activity.data["actor"] == user.ap_id
 306       assert announce_activity.data["context"] == object.data["context"]
 307     end
 308   end
 309
 310   describe "unannouncing an object" do
 311     test "unannouncing a previously announced object" do
 312       note_activity = insert(:note_activity)
 313       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 314       user = insert(:user)
 315
 316       # Unannouncing an object that is not announced does nothing
 317       # {:ok, object} = ActivityPub.unannounce(user, object)
 318       # assert object.data["announcement_count"] == 0
 319
 320       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 321       assert object.data["announcement_count"] == 1
 322
 323       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 324       assert object.data["announcement_count"] == 0
 325
 326       assert unannounce_activity.data["to"] == [
 327                User.ap_followers(user),
 328                announce_activity.data["actor"]
 329              ]
 330
 331       assert unannounce_activity.data["type"] == "Undo"
 332       assert unannounce_activity.data["object"] == announce_activity.data
 333       assert unannounce_activity.data["actor"] == user.ap_id
 334       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 335
 336       assert Repo.get(Activity, announce_activity.id) == nil
 337     end
 338   end
 339
 340   describe "uploading files" do
 341     test "copies the file to the configured folder" do
 342       file = %Plug.Upload{
 343         content_type: "image/jpg",
 344         path: Path.absname("test/fixtures/image.jpg"),
 345         filename: "an_image.jpg"
 346       }
 347
 348       {:ok, %Object{} = object} = ActivityPub.upload(file)
 349       assert object.data["name"] == "an_image.jpg"
 350     end
 351
 352     test "works with base64 encoded images" do
 353       file = %{
 354         "img" => data_uri()
 355       }
 356
 357       {:ok, %Object{}} = ActivityPub.upload(file)
 358     end
 359   end
 360
 361   describe "fetch the latest Follow" do
 362     test "fetches the latest Follow activity" do
 363       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 364       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 365       followed = Repo.get_by(User, ap_id: activity.data["object"])
 366
 367       assert activity == Utils.fetch_latest_follow(follower, followed)
 368     end
 369   end
 370
 371   describe "fetching an object" do
 372     test "it fetches an object" do
 373       {:ok, object} =
 374         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 375
 376       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 377       assert activity.data["id"]
 378
 379       {:ok, object_again} =
 380         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 381
 382       assert [attachment] = object.data["attachment"]
 383       assert is_list(attachment["url"])
 384
 385       assert object == object_again
 386     end
 387
 388     test "it works with objects only available via Ostatus" do
 389       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 390       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 391       assert activity.data["id"]
 392
 393       {:ok, object_again} =
 394         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 395
 396       assert object == object_again
 397     end
 398
 399     test "it correctly stitches up conversations between ostatus and ap" do
 400       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 401       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 402
 403       object = Object.get_by_ap_id(object.data["inReplyTo"])
 404       assert object
 405     end
 406   end
 407
 408   describe "following / unfollowing" do
 409     test "creates a follow activity" do
 410       follower = insert(:user)
 411       followed = insert(:user)
 412
 413       {:ok, activity} = ActivityPub.follow(follower, followed)
 414       assert activity.data["type"] == "Follow"
 415       assert activity.data["actor"] == follower.ap_id
 416       assert activity.data["object"] == followed.ap_id
 417     end
 418
 419     test "creates an undo activity for the last follow" do
 420       follower = insert(:user)
 421       followed = insert(:user)
 422
 423       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 424       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 425
 426       assert activity.data["type"] == "Undo"
 427       assert activity.data["actor"] == follower.ap_id
 428
 429       assert is_map(activity.data["object"])
 430       assert activity.data["object"]["type"] == "Follow"
 431       assert activity.data["object"]["object"] == followed.ap_id
 432       assert activity.data["object"]["id"] == follow_activity.data["id"]
 433     end
 434   end
 435
 436   describe "blocking / unblocking" do
 437     test "creates a block activity" do
 438       blocker = insert(:user)
 439       blocked = insert(:user)
 440
 441       {:ok, activity} = ActivityPub.block(blocker, blocked)
 442
 443       assert activity.data["type"] == "Block"
 444       assert activity.data["actor"] == blocker.ap_id
 445       assert activity.data["object"] == blocked.ap_id
 446     end
 447
 448     test "creates an undo activity for the last block" do
 449       blocker = insert(:user)
 450       blocked = insert(:user)
 451
 452       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 453       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 454
 455       assert activity.data["type"] == "Undo"
 456       assert activity.data["actor"] == blocker.ap_id
 457
 458       assert is_map(activity.data["object"])
 459       assert activity.data["object"]["type"] == "Block"
 460       assert activity.data["object"]["object"] == blocked.ap_id
 461       assert activity.data["object"]["id"] == block_activity.data["id"]
 462     end
 463   end
 464
 465   describe "deletion" do
 466     test "it creates a delete activity and deletes the original object" do
 467       note = insert(:note_activity)
 468       object = Object.get_by_ap_id(note.data["object"]["id"])
 469       {:ok, delete} = ActivityPub.delete(object)
 470
 471       assert delete.data["type"] == "Delete"
 472       assert delete.data["actor"] == note.data["actor"]
 473       assert delete.data["object"] == note.data["object"]["id"]
 474
 475       assert Repo.get(Activity, delete.id) != nil
 476
 477       assert Repo.get(Object, object.id) == nil
 478     end
 479   end
 480
 481   describe "timeline post-processing" do
 482     test "it filters broken threads" do
 483       user1 = insert(:user)
 484       user2 = insert(:user)
 485       user3 = insert(:user)
 486
 487       {:ok, user1} = User.follow(user1, user3)
 488       assert User.following?(user1, user3)
 489
 490       {:ok, user2} = User.follow(user2, user3)
 491       assert User.following?(user2, user3)
 492
 493       {:ok, user3} = User.follow(user3, user2)
 494       assert User.following?(user3, user2)
 495
 496       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 497
 498       {:ok, private_activity_1} =
 499         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 500
 501       {:ok, private_activity_2} =
 502         CommonAPI.post(user2, %{
 503           "status" => "hi 3",
 504           "visibility" => "private",
 505           "in_reply_to_status_id" => private_activity_1.id
 506         })
 507
 508       {:ok, private_activity_3} =
 509         CommonAPI.post(user3, %{
 510           "status" => "hi 4",
 511           "visibility" => "private",
 512           "in_reply_to_status_id" => private_activity_2.id
 513         })
 514
 515       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 516
 517       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 518
 519       assert [public_activity, private_activity_1, private_activity_3] == activities
 520       assert length(activities) == 3
 521
 522       activities = ActivityPub.contain_timeline(activities, user1)
 523
 524       assert [public_activity, private_activity_1] == activities
 525       assert length(activities) == 2
 526     end
 527   end
 528
 529   test "it can fetch plume articles" do
 530     {:ok, object} =
 531       ActivityPub.fetch_object_from_id(
 532         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 533       )
 534
 535     assert object
 536   end
 537
 538   describe "update" do
 539     test "it creates an update activity with the new user data" do
 540       user = insert(:user)
 541       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 542       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 543
 544       {:ok, update} =
 545         ActivityPub.update(%{
 546           actor: user_data["id"],
 547           to: [user.follower_address],
 548           cc: [],
 549           object: user_data
 550         })
 551
 552       assert update.data["actor"] == user.ap_id
 553       assert update.data["to"] == [user.follower_address]
 554       assert update.data["object"]["id"] == user_data["id"]
 555       assert update.data["object"]["type"] == user_data["type"]
 556     end
 557   end
 558
 559   test "it can fetch peertube videos" do
 560     {:ok, object} =
 561       ActivityPub.fetch_object_from_id(
 562         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 563       )
 564
 565     assert object
 566   end
 567
 568   def data_uri do
 569     File.read!("test/fixtures/avatar_data_uri")
 570   end
 571 end