git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.{Activity, Object, User, Instances}
  11   alias Pleroma.Builders.ActivityBuilder
  12
  13   import Pleroma.Factory
  14   import Tesla.Mock
  15   import Mock
  16
  17   setup do
  18     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  19     :ok
  20   end
  21
  22   describe "fetching restricted by visibility" do
  23     test "it restricts by the appropriate visibility" do
  24       user = insert(:user)
  25
  26       {:ok, public_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "public"})
  27
  28       {:ok, direct_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  29
  30       {:ok, unlisted_activity} =
  31         CommonAPI.post(user, %{"status" => ".", "visibility" => "unlisted"})
  32
  33       {:ok, private_activity} =
  34         CommonAPI.post(user, %{"status" => ".", "visibility" => "private"})
  35
  36       activities =
  37         ActivityPub.fetch_activities([], %{:visibility => "direct", "actor_id" => user.ap_id})
  38
  39       assert activities == [direct_activity]
  40
  41       activities =
  42         ActivityPub.fetch_activities([], %{:visibility => "unlisted", "actor_id" => user.ap_id})
  43
  44       assert activities == [unlisted_activity]
  45
  46       activities =
  47         ActivityPub.fetch_activities([], %{:visibility => "private", "actor_id" => user.ap_id})
  48
  49       assert activities == [private_activity]
  50
  51       activities =
  52         ActivityPub.fetch_activities([], %{:visibility => "public", "actor_id" => user.ap_id})
  53
  54       assert activities == [public_activity]
  55     end
  56   end
  57
  58   describe "building a user from his ap id" do
  59     test "it returns a user" do
  60       user_id = "http://mastodon.example.org/users/admin"
  61       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  62       assert user.ap_id == user_id
  63       assert user.nickname == "admin@mastodon.example.org"
  64       assert user.info.source_data
  65       assert user.info.ap_enabled
  66       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  67     end
  68
  69     test "it fetches the appropriate tag-restricted posts" do
  70       user = insert(:user)
  71
  72       {:ok, status_one} = CommonAPI.post(user, %{"status" => ". #test"})
  73       {:ok, status_two} = CommonAPI.post(user, %{"status" => ". #essais"})
  74       {:ok, status_three} = CommonAPI.post(user, %{"status" => ". #test #reject"})
  75
  76       fetch_one = ActivityPub.fetch_activities([], %{"tag" => "test"})
  77       fetch_two = ActivityPub.fetch_activities([], %{"tag" => ["test", "essais"]})
  78
  79       fetch_three =
  80         ActivityPub.fetch_activities([], %{
  81           "tag" => ["test", "essais"],
  82           "tag_reject" => ["reject"]
  83         })
  84
  85       fetch_four =
  86         ActivityPub.fetch_activities([], %{
  87           "tag" => ["test"],
  88           "tag_all" => ["test", "reject"]
  89         })
  90
  91       assert fetch_one == [status_one, status_three]
  92       assert fetch_two == [status_one, status_two, status_three]
  93       assert fetch_three == [status_one, status_two]
  94       assert fetch_four == [status_three]
  95     end
  96   end
  97
  98   describe "insertion" do
  99     test "drops activities beyond a certain limit" do
 100       limit = Pleroma.Config.get([:instance, :remote_limit])
 101
 102       random_text =
 103         :crypto.strong_rand_bytes(limit + 1)
 104         |> Base.encode64()
 105         |> binary_part(0, limit + 1)
 106
 107       data = %{
 108         "ok" => true,
 109         "object" => %{
 110           "content" => random_text
 111         }
 112       }
 113
 114       assert {:error, {:remote_limit_error, _}} = ActivityPub.insert(data)
 115     end
 116
 117     test "doesn't drop activities with content being null" do
 118       data = %{
 119         "ok" => true,
 120         "object" => %{
 121           "content" => nil
 122         }
 123       }
 124
 125       assert {:ok, _} = ActivityPub.insert(data)
 126     end
 127
 128     test "returns the activity if one with the same id is already in" do
 129       activity = insert(:note_activity)
 130       {:ok, new_activity} = ActivityPub.insert(activity.data)
 131
 132       assert activity == new_activity
 133     end
 134
 135     test "inserts a given map into the activity database, giving it an id if it has none." do
 136       data = %{
 137         "ok" => true
 138       }
 139
 140       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 141       assert activity.data["ok"] == data["ok"]
 142       assert is_binary(activity.data["id"])
 143
 144       given_id = "bla"
 145
 146       data = %{
 147         "ok" => true,
 148         "id" => given_id,
 149         "context" => "blabla"
 150       }
 151
 152       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 153       assert activity.data["ok"] == data["ok"]
 154       assert activity.data["id"] == given_id
 155       assert activity.data["context"] == "blabla"
 156       assert activity.data["context_id"]
 157     end
 158
 159     test "adds a context when none is there" do
 160       data = %{
 161         "id" => "some_id",
 162         "object" => %{
 163           "id" => "object_id"
 164         }
 165       }
 166
 167       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 168
 169       assert is_binary(activity.data["context"])
 170       assert is_binary(activity.data["object"]["context"])
 171       assert activity.data["context_id"]
 172       assert activity.data["object"]["context_id"]
 173     end
 174
 175     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
 176       data = %{
 177         "object" => %{
 178           "type" => "Note",
 179           "ok" => true
 180         }
 181       }
 182
 183       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 184       assert is_binary(activity.data["object"]["id"])
 185       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
 186     end
 187   end
 188
 189   describe "create activities" do
 190     test "removes doubled 'to' recipients" do
 191       user = insert(:user)
 192
 193       {:ok, activity} =
 194         ActivityPub.create(%{
 195           to: ["user1", "user1", "user2"],
 196           actor: user,
 197           context: "",
 198           object: %{}
 199         })
 200
 201       assert activity.data["to"] == ["user1", "user2"]
 202       assert activity.actor == user.ap_id
 203       assert activity.recipients == ["user1", "user2", user.ap_id]
 204     end
 205   end
 206
 207   describe "fetch activities for recipients" do
 208     test "retrieve the activities for certain recipients" do
 209       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 210       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 211       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 212
 213       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 214       assert length(activities) == 2
 215       assert activities == [activity_one, activity_two]
 216     end
 217   end
 218
 219   describe "fetch activities in context" do
 220     test "retrieves activities that have a given context" do
 221       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 222       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 223       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 224       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 225       activity_five = insert(:note_activity)
 226       user = insert(:user)
 227
 228       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 229
 230       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 231       assert activities == [activity_two, activity]
 232     end
 233   end
 234
 235   test "doesn't return blocked activities" do
 236     activity_one = insert(:note_activity)
 237     activity_two = insert(:note_activity)
 238     activity_three = insert(:note_activity)
 239     user = insert(:user)
 240     booster = insert(:user)
 241     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 242
 243     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 244
 245     assert Enum.member?(activities, activity_two)
 246     assert Enum.member?(activities, activity_three)
 247     refute Enum.member?(activities, activity_one)
 248
 249     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 250
 251     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 252
 253     assert Enum.member?(activities, activity_two)
 254     assert Enum.member?(activities, activity_three)
 255     assert Enum.member?(activities, activity_one)
 256
 257     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 258     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 259     %Activity{} = boost_activity = Activity.get_create_by_object_ap_id(id)
 260     activity_three = Repo.get(Activity, activity_three.id)
 261
 262     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 263
 264     assert Enum.member?(activities, activity_two)
 265     refute Enum.member?(activities, activity_three)
 266     refute Enum.member?(activities, boost_activity)
 267     assert Enum.member?(activities, activity_one)
 268
 269     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 270
 271     assert Enum.member?(activities, activity_two)
 272     assert Enum.member?(activities, activity_three)
 273     assert Enum.member?(activities, boost_activity)
 274     assert Enum.member?(activities, activity_one)
 275   end
 276
 277   test "excludes reblogs on request" do
 278     user = insert(:user)
 279     {:ok, expected_activity} = ActivityBuilder.insert(%{"type" => "Create"}, %{:user => user})
 280     {:ok, _} = ActivityBuilder.insert(%{"type" => "Announce"}, %{:user => user})
 281
 282     [activity] = ActivityPub.fetch_user_activities(user, nil, %{"exclude_reblogs" => "true"})
 283
 284     assert activity == expected_activity
 285   end
 286
 287   describe "public fetch activities" do
 288     test "doesn't retrieve unlisted activities" do
 289       user = insert(:user)
 290
 291       {:ok, _unlisted_activity} =
 292         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 293
 294       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 295
 296       [activity] = ActivityPub.fetch_public_activities()
 297
 298       assert activity == listed_activity
 299     end
 300
 301     test "retrieves public activities" do
 302       _activities = ActivityPub.fetch_public_activities()
 303
 304       %{public: public} = ActivityBuilder.public_and_non_public()
 305
 306       activities = ActivityPub.fetch_public_activities()
 307       assert length(activities) == 1
 308       assert Enum.at(activities, 0) == public
 309     end
 310
 311     test "retrieves a maximum of 20 activities" do
 312       activities = ActivityBuilder.insert_list(30)
 313       last_expected = List.last(activities)
 314
 315       activities = ActivityPub.fetch_public_activities()
 316       last = List.last(activities)
 317
 318       assert length(activities) == 20
 319       assert last == last_expected
 320     end
 321
 322     test "retrieves ids starting from a since_id" do
 323       activities = ActivityBuilder.insert_list(30)
 324       later_activities = ActivityBuilder.insert_list(10)
 325       since_id = List.last(activities).id
 326       last_expected = List.last(later_activities)
 327
 328       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 329       last = List.last(activities)
 330
 331       assert length(activities) == 10
 332       assert last == last_expected
 333     end
 334
 335     test "retrieves ids up to max_id" do
 336       _first_activities = ActivityBuilder.insert_list(10)
 337       activities = ActivityBuilder.insert_list(20)
 338       later_activities = ActivityBuilder.insert_list(10)
 339       max_id = List.first(later_activities).id
 340       last_expected = List.last(activities)
 341
 342       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 343       last = List.last(activities)
 344
 345       assert length(activities) == 20
 346       assert last == last_expected
 347     end
 348   end
 349
 350   describe "like an object" do
 351     test "adds a like activity to the db" do
 352       note_activity = insert(:note_activity)
 353       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 354       user = insert(:user)
 355       user_two = insert(:user)
 356
 357       {:ok, like_activity, object} = ActivityPub.like(user, object)
 358
 359       assert like_activity.data["actor"] == user.ap_id
 360       assert like_activity.data["type"] == "Like"
 361       assert like_activity.data["object"] == object.data["id"]
 362       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 363       assert like_activity.data["context"] == object.data["context"]
 364       assert object.data["like_count"] == 1
 365       assert object.data["likes"] == [user.ap_id]
 366
 367       # Just return the original activity if the user already liked it.
 368       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 369
 370       assert like_activity == same_like_activity
 371       assert object.data["likes"] == [user.ap_id]
 372
 373       [note_activity] = Activity.get_all_create_by_object_ap_id(object.data["id"])
 374       assert note_activity.data["object"]["like_count"] == 1
 375
 376       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 377       assert object.data["like_count"] == 2
 378     end
 379   end
 380
 381   describe "unliking" do
 382     test "unliking a previously liked object" do
 383       note_activity = insert(:note_activity)
 384       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 385       user = insert(:user)
 386
 387       # Unliking something that hasn't been liked does nothing
 388       {:ok, object} = ActivityPub.unlike(user, object)
 389       assert object.data["like_count"] == 0
 390
 391       {:ok, like_activity, object} = ActivityPub.like(user, object)
 392       assert object.data["like_count"] == 1
 393
 394       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 395       assert object.data["like_count"] == 0
 396
 397       assert Repo.get(Activity, like_activity.id) == nil
 398     end
 399   end
 400
 401   describe "announcing an object" do
 402     test "adds an announce activity to the db" do
 403       note_activity = insert(:note_activity)
 404       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 405       user = insert(:user)
 406
 407       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 408       assert object.data["announcement_count"] == 1
 409       assert object.data["announcements"] == [user.ap_id]
 410
 411       assert announce_activity.data["to"] == [
 412                User.ap_followers(user),
 413                note_activity.data["actor"]
 414              ]
 415
 416       assert announce_activity.data["object"] == object.data["id"]
 417       assert announce_activity.data["actor"] == user.ap_id
 418       assert announce_activity.data["context"] == object.data["context"]
 419     end
 420   end
 421
 422   describe "unannouncing an object" do
 423     test "unannouncing a previously announced object" do
 424       note_activity = insert(:note_activity)
 425       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 426       user = insert(:user)
 427
 428       # Unannouncing an object that is not announced does nothing
 429       # {:ok, object} = ActivityPub.unannounce(user, object)
 430       # assert object.data["announcement_count"] == 0
 431
 432       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 433       assert object.data["announcement_count"] == 1
 434
 435       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 436       assert object.data["announcement_count"] == 0
 437
 438       assert unannounce_activity.data["to"] == [
 439                User.ap_followers(user),
 440                announce_activity.data["actor"]
 441              ]
 442
 443       assert unannounce_activity.data["type"] == "Undo"
 444       assert unannounce_activity.data["object"] == announce_activity.data
 445       assert unannounce_activity.data["actor"] == user.ap_id
 446       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 447
 448       assert Repo.get(Activity, announce_activity.id) == nil
 449     end
 450   end
 451
 452   describe "uploading files" do
 453     test "copies the file to the configured folder" do
 454       file = %Plug.Upload{
 455         content_type: "image/jpg",
 456         path: Path.absname("test/fixtures/image.jpg"),
 457         filename: "an_image.jpg"
 458       }
 459
 460       {:ok, %Object{} = object} = ActivityPub.upload(file)
 461       assert object.data["name"] == "an_image.jpg"
 462     end
 463
 464     test "works with base64 encoded images" do
 465       file = %{
 466         "img" => data_uri()
 467       }
 468
 469       {:ok, %Object{}} = ActivityPub.upload(file)
 470     end
 471   end
 472
 473   describe "fetch the latest Follow" do
 474     test "fetches the latest Follow activity" do
 475       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 476       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 477       followed = Repo.get_by(User, ap_id: activity.data["object"])
 478
 479       assert activity == Utils.fetch_latest_follow(follower, followed)
 480     end
 481   end
 482
 483   describe "fetching an object" do
 484     test "it fetches an object" do
 485       {:ok, object} =
 486         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 487
 488       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 489       assert activity.data["id"]
 490
 491       {:ok, object_again} =
 492         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 493
 494       assert [attachment] = object.data["attachment"]
 495       assert is_list(attachment["url"])
 496
 497       assert object == object_again
 498     end
 499
 500     test "it works with objects only available via Ostatus" do
 501       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 502       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 503       assert activity.data["id"]
 504
 505       {:ok, object_again} =
 506         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 507
 508       assert object == object_again
 509     end
 510
 511     test "it correctly stitches up conversations between ostatus and ap" do
 512       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 513       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 514
 515       object = Object.get_by_ap_id(object.data["inReplyTo"])
 516       assert object
 517     end
 518   end
 519
 520   describe "following / unfollowing" do
 521     test "creates a follow activity" do
 522       follower = insert(:user)
 523       followed = insert(:user)
 524
 525       {:ok, activity} = ActivityPub.follow(follower, followed)
 526       assert activity.data["type"] == "Follow"
 527       assert activity.data["actor"] == follower.ap_id
 528       assert activity.data["object"] == followed.ap_id
 529     end
 530
 531     test "creates an undo activity for the last follow" do
 532       follower = insert(:user)
 533       followed = insert(:user)
 534
 535       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 536       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 537
 538       assert activity.data["type"] == "Undo"
 539       assert activity.data["actor"] == follower.ap_id
 540
 541       assert is_map(activity.data["object"])
 542       assert activity.data["object"]["type"] == "Follow"
 543       assert activity.data["object"]["object"] == followed.ap_id
 544       assert activity.data["object"]["id"] == follow_activity.data["id"]
 545     end
 546   end
 547
 548   describe "blocking / unblocking" do
 549     test "creates a block activity" do
 550       blocker = insert(:user)
 551       blocked = insert(:user)
 552
 553       {:ok, activity} = ActivityPub.block(blocker, blocked)
 554
 555       assert activity.data["type"] == "Block"
 556       assert activity.data["actor"] == blocker.ap_id
 557       assert activity.data["object"] == blocked.ap_id
 558     end
 559
 560     test "creates an undo activity for the last block" do
 561       blocker = insert(:user)
 562       blocked = insert(:user)
 563
 564       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 565       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 566
 567       assert activity.data["type"] == "Undo"
 568       assert activity.data["actor"] == blocker.ap_id
 569
 570       assert is_map(activity.data["object"])
 571       assert activity.data["object"]["type"] == "Block"
 572       assert activity.data["object"]["object"] == blocked.ap_id
 573       assert activity.data["object"]["id"] == block_activity.data["id"]
 574     end
 575   end
 576
 577   describe "deletion" do
 578     test "it creates a delete activity and deletes the original object" do
 579       note = insert(:note_activity)
 580       object = Object.get_by_ap_id(note.data["object"]["id"])
 581       {:ok, delete} = ActivityPub.delete(object)
 582
 583       assert delete.data["type"] == "Delete"
 584       assert delete.data["actor"] == note.data["actor"]
 585       assert delete.data["object"] == note.data["object"]["id"]
 586
 587       assert Repo.get(Activity, delete.id) != nil
 588
 589       assert Repo.get(Object, object.id).data["type"] == "Tombstone"
 590     end
 591   end
 592
 593   describe "timeline post-processing" do
 594     test "it filters broken threads" do
 595       user1 = insert(:user)
 596       user2 = insert(:user)
 597       user3 = insert(:user)
 598
 599       {:ok, user1} = User.follow(user1, user3)
 600       assert User.following?(user1, user3)
 601
 602       {:ok, user2} = User.follow(user2, user3)
 603       assert User.following?(user2, user3)
 604
 605       {:ok, user3} = User.follow(user3, user2)
 606       assert User.following?(user3, user2)
 607
 608       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 609
 610       {:ok, private_activity_1} =
 611         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 612
 613       {:ok, private_activity_2} =
 614         CommonAPI.post(user2, %{
 615           "status" => "hi 3",
 616           "visibility" => "private",
 617           "in_reply_to_status_id" => private_activity_1.id
 618         })
 619
 620       {:ok, private_activity_3} =
 621         CommonAPI.post(user3, %{
 622           "status" => "hi 4",
 623           "visibility" => "private",
 624           "in_reply_to_status_id" => private_activity_2.id
 625         })
 626
 627       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 628
 629       assert [public_activity, private_activity_1, private_activity_3] == activities
 630       assert length(activities) == 3
 631
 632       activities = ActivityPub.contain_timeline(activities, user1)
 633
 634       assert [public_activity, private_activity_1] == activities
 635       assert length(activities) == 2
 636     end
 637   end
 638
 639   test "it can fetch plume articles" do
 640     {:ok, object} =
 641       ActivityPub.fetch_object_from_id(
 642         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 643       )
 644
 645     assert object
 646   end
 647
 648   describe "update" do
 649     test "it creates an update activity with the new user data" do
 650       user = insert(:user)
 651       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 652       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 653
 654       {:ok, update} =
 655         ActivityPub.update(%{
 656           actor: user_data["id"],
 657           to: [user.follower_address],
 658           cc: [],
 659           object: user_data
 660         })
 661
 662       assert update.data["actor"] == user.ap_id
 663       assert update.data["to"] == [user.follower_address]
 664       assert update.data["object"]["id"] == user_data["id"]
 665       assert update.data["object"]["type"] == user_data["type"]
 666     end
 667   end
 668
 669   test "it can fetch peertube videos" do
 670     {:ok, object} =
 671       ActivityPub.fetch_object_from_id(
 672         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 673       )
 674
 675     assert object
 676   end
 677
 678   test "returned pinned statuses" do
 679     Pleroma.Config.put([:instance, :max_pinned_statuses], 3)
 680     user = insert(:user)
 681
 682     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "HI!!!"})
 683     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 684     {:ok, activity_three} = CommonAPI.post(user, %{"status" => "HI!!!"})
 685
 686     CommonAPI.pin(activity_one.id, user)
 687     user = refresh_record(user)
 688
 689     CommonAPI.pin(activity_two.id, user)
 690     user = refresh_record(user)
 691
 692     CommonAPI.pin(activity_three.id, user)
 693     user = refresh_record(user)
 694
 695     activities = ActivityPub.fetch_user_activities(user, nil, %{"pinned" => "true"})
 696
 697     assert 3 = length(activities)
 698   end
 699
 700   describe "publish_one/1" do
 701     test_with_mock "calls `Instances.set_reachable` on successful federation if `unreachable_since` is not specified",
 702                    Instances,
 703                    [:passthrough],
 704                    [] do
 705       actor = insert(:user)
 706       inbox = "http://200.site/users/nick1/inbox"
 707
 708       assert {:ok, _} = ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 709
 710       assert called(Instances.set_reachable(inbox))
 711     end
 712
 713     test_with_mock "calls `Instances.set_reachable` on successful federation if `unreachable_since` is set",
 714                    Instances,
 715                    [:passthrough],
 716                    [] do
 717       actor = insert(:user)
 718       inbox = "http://200.site/users/nick1/inbox"
 719
 720       assert {:ok, _} =
 721                ActivityPub.publish_one(%{
 722                  inbox: inbox,
 723                  json: "{}",
 724                  actor: actor,
 725                  id: 1,
 726                  unreachable_since: NaiveDateTime.utc_now()
 727                })
 728
 729       assert called(Instances.set_reachable(inbox))
 730     end
 731
 732     test_with_mock "does NOT call `Instances.set_reachable` on successful federation if `unreachable_since` is nil",
 733                    Instances,
 734                    [:passthrough],
 735                    [] do
 736       actor = insert(:user)
 737       inbox = "http://200.site/users/nick1/inbox"
 738
 739       assert {:ok, _} =
 740                ActivityPub.publish_one(%{
 741                  inbox: inbox,
 742                  json: "{}",
 743                  actor: actor,
 744                  id: 1,
 745                  unreachable_since: nil
 746                })
 747
 748       refute called(Instances.set_reachable(inbox))
 749     end
 750
 751     test_with_mock "calls `Instances.set_unreachable` on target inbox on non-2xx HTTP response code",
 752                    Instances,
 753                    [:passthrough],
 754                    [] do
 755       actor = insert(:user)
 756       inbox = "http://404.site/users/nick1/inbox"
 757
 758       assert {:error, _} =
 759                ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 760
 761       assert called(Instances.set_unreachable(inbox))
 762     end
 763
 764     test_with_mock "it calls `Instances.set_unreachable` on target inbox on request error of any kind",
 765                    Instances,
 766                    [:passthrough],
 767                    [] do
 768       actor = insert(:user)
 769       inbox = "http://connrefused.site/users/nick1/inbox"
 770
 771       assert {:error, _} =
 772                ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 773
 774       assert called(Instances.set_unreachable(inbox))
 775     end
 776
 777     test_with_mock "does NOT call `Instances.set_unreachable` if target is reachable",
 778                    Instances,
 779                    [:passthrough],
 780                    [] do
 781       actor = insert(:user)
 782       inbox = "http://200.site/users/nick1/inbox"
 783
 784       assert {:ok, _} = ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 785
 786       refute called(Instances.set_unreachable(inbox))
 787     end
 788
 789     test_with_mock "does NOT call `Instances.set_unreachable` if target instance has non-nil `unreachable_since`",
 790                    Instances,
 791                    [:passthrough],
 792                    [] do
 793       actor = insert(:user)
 794       inbox = "http://connrefused.site/users/nick1/inbox"
 795
 796       assert {:error, _} =
 797                ActivityPub.publish_one(%{
 798                  inbox: inbox,
 799                  json: "{}",
 800                  actor: actor,
 801                  id: 1,
 802                  unreachable_since: NaiveDateTime.utc_now()
 803                })
 804
 805       refute called(Instances.set_unreachable(inbox))
 806     end
 807   end
 808
 809   def data_uri do
 810     File.read!("test/fixtures/avatar_data_uri")
 811   end
 812 end