git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.{Activity, Object, User}
  11   alias Pleroma.Builders.ActivityBuilder
  12
  13   import Pleroma.Factory
  14   import Tesla.Mock
  15
  16   setup do
  17     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  18     :ok
  19   end
  20
  21   describe "fetching restricted by visibility" do
  22     test "it restricts by the appropriate visibility" do
  23       user = insert(:user)
  24
  25       {:ok, public_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "public"})
  26
  27       {:ok, direct_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  28
  29       {:ok, unlisted_activity} =
  30         CommonAPI.post(user, %{"status" => ".", "visibility" => "unlisted"})
  31
  32       {:ok, private_activity} =
  33         CommonAPI.post(user, %{"status" => ".", "visibility" => "private"})
  34
  35       activities =
  36         ActivityPub.fetch_activities([], %{:visibility => "direct", "actor_id" => user.ap_id})
  37
  38       assert activities == [direct_activity]
  39
  40       activities =
  41         ActivityPub.fetch_activities([], %{:visibility => "unlisted", "actor_id" => user.ap_id})
  42
  43       assert activities == [unlisted_activity]
  44
  45       activities =
  46         ActivityPub.fetch_activities([], %{:visibility => "private", "actor_id" => user.ap_id})
  47
  48       assert activities == [private_activity]
  49
  50       activities =
  51         ActivityPub.fetch_activities([], %{:visibility => "public", "actor_id" => user.ap_id})
  52
  53       assert activities == [public_activity]
  54     end
  55   end
  56
  57   describe "building a user from his ap id" do
  58     test "it returns a user" do
  59       user_id = "http://mastodon.example.org/users/admin"
  60       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  61       assert user.ap_id == user_id
  62       assert user.nickname == "admin@mastodon.example.org"
  63       assert user.info.source_data
  64       assert user.info.ap_enabled
  65       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  66     end
  67   end
  68
  69   describe "insertion" do
  70     test "drops activities beyond a certain limit" do
  71       limit = Pleroma.Config.get([:instance, :remote_limit])
  72
  73       random_text =
  74         :crypto.strong_rand_bytes(limit + 1)
  75         |> Base.encode64()
  76         |> binary_part(0, limit + 1)
  77
  78       data = %{
  79         "ok" => true,
  80         "object" => %{
  81           "content" => random_text
  82         }
  83       }
  84
  85       assert {:error, {:remote_limit_error, _}} = ActivityPub.insert(data)
  86     end
  87
  88     test "doesn't drop activities with content being null" do
  89       data = %{
  90         "ok" => true,
  91         "object" => %{
  92           "content" => nil
  93         }
  94       }
  95
  96       assert {:ok, _} = ActivityPub.insert(data)
  97     end
  98
  99     test "returns the activity if one with the same id is already in" do
 100       activity = insert(:note_activity)
 101       {:ok, new_activity} = ActivityPub.insert(activity.data)
 102
 103       assert activity == new_activity
 104     end
 105
 106     test "inserts a given map into the activity database, giving it an id if it has none." do
 107       data = %{
 108         "ok" => true
 109       }
 110
 111       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 112       assert activity.data["ok"] == data["ok"]
 113       assert is_binary(activity.data["id"])
 114
 115       given_id = "bla"
 116
 117       data = %{
 118         "ok" => true,
 119         "id" => given_id,
 120         "context" => "blabla"
 121       }
 122
 123       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 124       assert activity.data["ok"] == data["ok"]
 125       assert activity.data["id"] == given_id
 126       assert activity.data["context"] == "blabla"
 127       assert activity.data["context_id"]
 128     end
 129
 130     test "adds a context when none is there" do
 131       data = %{
 132         "id" => "some_id",
 133         "object" => %{
 134           "id" => "object_id"
 135         }
 136       }
 137
 138       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 139
 140       assert is_binary(activity.data["context"])
 141       assert is_binary(activity.data["object"]["context"])
 142       assert activity.data["context_id"]
 143       assert activity.data["object"]["context_id"]
 144     end
 145
 146     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
 147       data = %{
 148         "object" => %{
 149           "type" => "Note",
 150           "ok" => true
 151         }
 152       }
 153
 154       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 155       assert is_binary(activity.data["object"]["id"])
 156       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
 157     end
 158   end
 159
 160   describe "create activities" do
 161     test "removes doubled 'to' recipients" do
 162       user = insert(:user)
 163
 164       {:ok, activity} =
 165         ActivityPub.create(%{
 166           to: ["user1", "user1", "user2"],
 167           actor: user,
 168           context: "",
 169           object: %{}
 170         })
 171
 172       assert activity.data["to"] == ["user1", "user2"]
 173       assert activity.actor == user.ap_id
 174       assert activity.recipients == ["user1", "user2", user.ap_id]
 175     end
 176   end
 177
 178   describe "fetch activities for recipients" do
 179     test "retrieve the activities for certain recipients" do
 180       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 181       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 182       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 183
 184       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 185       assert length(activities) == 2
 186       assert activities == [activity_one, activity_two]
 187     end
 188   end
 189
 190   describe "fetch activities in context" do
 191     test "retrieves activities that have a given context" do
 192       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 193       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 194       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 195       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 196       activity_five = insert(:note_activity)
 197       user = insert(:user)
 198
 199       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 200
 201       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 202       assert activities == [activity_two, activity]
 203     end
 204   end
 205
 206   test "doesn't return blocked activities" do
 207     activity_one = insert(:note_activity)
 208     activity_two = insert(:note_activity)
 209     activity_three = insert(:note_activity)
 210     user = insert(:user)
 211     booster = insert(:user)
 212     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 213
 214     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 215
 216     assert Enum.member?(activities, activity_two)
 217     assert Enum.member?(activities, activity_three)
 218     refute Enum.member?(activities, activity_one)
 219
 220     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 221
 222     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 223
 224     assert Enum.member?(activities, activity_two)
 225     assert Enum.member?(activities, activity_three)
 226     assert Enum.member?(activities, activity_one)
 227
 228     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 229     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 230     %Activity{} = boost_activity = Activity.get_create_by_object_ap_id(id)
 231     activity_three = Repo.get(Activity, activity_three.id)
 232
 233     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 234
 235     assert Enum.member?(activities, activity_two)
 236     refute Enum.member?(activities, activity_three)
 237     refute Enum.member?(activities, boost_activity)
 238     assert Enum.member?(activities, activity_one)
 239
 240     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 241
 242     assert Enum.member?(activities, activity_two)
 243     assert Enum.member?(activities, activity_three)
 244     assert Enum.member?(activities, boost_activity)
 245     assert Enum.member?(activities, activity_one)
 246   end
 247
 248   test "excludes reblogs on request" do
 249     user = insert(:user)
 250     {:ok, expected_activity} = ActivityBuilder.insert(%{"type" => "Create"}, %{:user => user})
 251     {:ok, _} = ActivityBuilder.insert(%{"type" => "Announce"}, %{:user => user})
 252
 253     [activity] = ActivityPub.fetch_user_activities(user, nil, %{"exclude_reblogs" => "true"})
 254
 255     assert activity == expected_activity
 256   end
 257
 258   describe "public fetch activities" do
 259     test "doesn't retrieve unlisted activities" do
 260       user = insert(:user)
 261
 262       {:ok, _unlisted_activity} =
 263         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 264
 265       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 266
 267       [activity] = ActivityPub.fetch_public_activities()
 268
 269       assert activity == listed_activity
 270     end
 271
 272     test "retrieves public activities" do
 273       _activities = ActivityPub.fetch_public_activities()
 274
 275       %{public: public} = ActivityBuilder.public_and_non_public()
 276
 277       activities = ActivityPub.fetch_public_activities()
 278       assert length(activities) == 1
 279       assert Enum.at(activities, 0) == public
 280     end
 281
 282     test "retrieves a maximum of 20 activities" do
 283       activities = ActivityBuilder.insert_list(30)
 284       last_expected = List.last(activities)
 285
 286       activities = ActivityPub.fetch_public_activities()
 287       last = List.last(activities)
 288
 289       assert length(activities) == 20
 290       assert last == last_expected
 291     end
 292
 293     test "retrieves ids starting from a since_id" do
 294       activities = ActivityBuilder.insert_list(30)
 295       later_activities = ActivityBuilder.insert_list(10)
 296       since_id = List.last(activities).id
 297       last_expected = List.last(later_activities)
 298
 299       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 300       last = List.last(activities)
 301
 302       assert length(activities) == 10
 303       assert last == last_expected
 304     end
 305
 306     test "retrieves ids up to max_id" do
 307       _first_activities = ActivityBuilder.insert_list(10)
 308       activities = ActivityBuilder.insert_list(20)
 309       later_activities = ActivityBuilder.insert_list(10)
 310       max_id = List.first(later_activities).id
 311       last_expected = List.last(activities)
 312
 313       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 314       last = List.last(activities)
 315
 316       assert length(activities) == 20
 317       assert last == last_expected
 318     end
 319   end
 320
 321   describe "like an object" do
 322     test "adds a like activity to the db" do
 323       note_activity = insert(:note_activity)
 324       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 325       user = insert(:user)
 326       user_two = insert(:user)
 327
 328       {:ok, like_activity, object} = ActivityPub.like(user, object)
 329
 330       assert like_activity.data["actor"] == user.ap_id
 331       assert like_activity.data["type"] == "Like"
 332       assert like_activity.data["object"] == object.data["id"]
 333       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 334       assert like_activity.data["context"] == object.data["context"]
 335       assert object.data["like_count"] == 1
 336       assert object.data["likes"] == [user.ap_id]
 337
 338       # Just return the original activity if the user already liked it.
 339       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 340
 341       assert like_activity == same_like_activity
 342       assert object.data["likes"] == [user.ap_id]
 343
 344       [note_activity] = Activity.get_all_create_by_object_ap_id(object.data["id"])
 345       assert note_activity.data["object"]["like_count"] == 1
 346
 347       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 348       assert object.data["like_count"] == 2
 349     end
 350   end
 351
 352   describe "unliking" do
 353     test "unliking a previously liked object" do
 354       note_activity = insert(:note_activity)
 355       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 356       user = insert(:user)
 357
 358       # Unliking something that hasn't been liked does nothing
 359       {:ok, object} = ActivityPub.unlike(user, object)
 360       assert object.data["like_count"] == 0
 361
 362       {:ok, like_activity, object} = ActivityPub.like(user, object)
 363       assert object.data["like_count"] == 1
 364
 365       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 366       assert object.data["like_count"] == 0
 367
 368       assert Repo.get(Activity, like_activity.id) == nil
 369     end
 370   end
 371
 372   describe "announcing an object" do
 373     test "adds an announce activity to the db" do
 374       note_activity = insert(:note_activity)
 375       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 376       user = insert(:user)
 377
 378       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 379       assert object.data["announcement_count"] == 1
 380       assert object.data["announcements"] == [user.ap_id]
 381
 382       assert announce_activity.data["to"] == [
 383                User.ap_followers(user),
 384                note_activity.data["actor"]
 385              ]
 386
 387       assert announce_activity.data["object"] == object.data["id"]
 388       assert announce_activity.data["actor"] == user.ap_id
 389       assert announce_activity.data["context"] == object.data["context"]
 390     end
 391   end
 392
 393   describe "unannouncing an object" do
 394     test "unannouncing a previously announced object" do
 395       note_activity = insert(:note_activity)
 396       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 397       user = insert(:user)
 398
 399       # Unannouncing an object that is not announced does nothing
 400       # {:ok, object} = ActivityPub.unannounce(user, object)
 401       # assert object.data["announcement_count"] == 0
 402
 403       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 404       assert object.data["announcement_count"] == 1
 405
 406       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 407       assert object.data["announcement_count"] == 0
 408
 409       assert unannounce_activity.data["to"] == [
 410                User.ap_followers(user),
 411                announce_activity.data["actor"]
 412              ]
 413
 414       assert unannounce_activity.data["type"] == "Undo"
 415       assert unannounce_activity.data["object"] == announce_activity.data
 416       assert unannounce_activity.data["actor"] == user.ap_id
 417       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 418
 419       assert Repo.get(Activity, announce_activity.id) == nil
 420     end
 421   end
 422
 423   describe "uploading files" do
 424     test "copies the file to the configured folder" do
 425       file = %Plug.Upload{
 426         content_type: "image/jpg",
 427         path: Path.absname("test/fixtures/image.jpg"),
 428         filename: "an_image.jpg"
 429       }
 430
 431       {:ok, %Object{} = object} = ActivityPub.upload(file)
 432       assert object.data["name"] == "an_image.jpg"
 433     end
 434
 435     test "works with base64 encoded images" do
 436       file = %{
 437         "img" => data_uri()
 438       }
 439
 440       {:ok, %Object{}} = ActivityPub.upload(file)
 441     end
 442   end
 443
 444   describe "fetch the latest Follow" do
 445     test "fetches the latest Follow activity" do
 446       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 447       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 448       followed = Repo.get_by(User, ap_id: activity.data["object"])
 449
 450       assert activity == Utils.fetch_latest_follow(follower, followed)
 451     end
 452   end
 453
 454   describe "fetching an object" do
 455     test "it fetches an object" do
 456       {:ok, object} =
 457         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 458
 459       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 460       assert activity.data["id"]
 461
 462       {:ok, object_again} =
 463         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 464
 465       assert [attachment] = object.data["attachment"]
 466       assert is_list(attachment["url"])
 467
 468       assert object == object_again
 469     end
 470
 471     test "it works with objects only available via Ostatus" do
 472       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 473       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 474       assert activity.data["id"]
 475
 476       {:ok, object_again} =
 477         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 478
 479       assert object == object_again
 480     end
 481
 482     test "it correctly stitches up conversations between ostatus and ap" do
 483       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 484       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 485
 486       object = Object.get_by_ap_id(object.data["inReplyTo"])
 487       assert object
 488     end
 489   end
 490
 491   describe "following / unfollowing" do
 492     test "creates a follow activity" do
 493       follower = insert(:user)
 494       followed = insert(:user)
 495
 496       {:ok, activity} = ActivityPub.follow(follower, followed)
 497       assert activity.data["type"] == "Follow"
 498       assert activity.data["actor"] == follower.ap_id
 499       assert activity.data["object"] == followed.ap_id
 500     end
 501
 502     test "creates an undo activity for the last follow" do
 503       follower = insert(:user)
 504       followed = insert(:user)
 505
 506       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 507       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 508
 509       assert activity.data["type"] == "Undo"
 510       assert activity.data["actor"] == follower.ap_id
 511
 512       assert is_map(activity.data["object"])
 513       assert activity.data["object"]["type"] == "Follow"
 514       assert activity.data["object"]["object"] == followed.ap_id
 515       assert activity.data["object"]["id"] == follow_activity.data["id"]
 516     end
 517   end
 518
 519   describe "blocking / unblocking" do
 520     test "creates a block activity" do
 521       blocker = insert(:user)
 522       blocked = insert(:user)
 523
 524       {:ok, activity} = ActivityPub.block(blocker, blocked)
 525
 526       assert activity.data["type"] == "Block"
 527       assert activity.data["actor"] == blocker.ap_id
 528       assert activity.data["object"] == blocked.ap_id
 529     end
 530
 531     test "creates an undo activity for the last block" do
 532       blocker = insert(:user)
 533       blocked = insert(:user)
 534
 535       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 536       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 537
 538       assert activity.data["type"] == "Undo"
 539       assert activity.data["actor"] == blocker.ap_id
 540
 541       assert is_map(activity.data["object"])
 542       assert activity.data["object"]["type"] == "Block"
 543       assert activity.data["object"]["object"] == blocked.ap_id
 544       assert activity.data["object"]["id"] == block_activity.data["id"]
 545     end
 546   end
 547
 548   describe "deletion" do
 549     test "it creates a delete activity and deletes the original object" do
 550       note = insert(:note_activity)
 551       object = Object.get_by_ap_id(note.data["object"]["id"])
 552       {:ok, delete} = ActivityPub.delete(object)
 553
 554       assert delete.data["type"] == "Delete"
 555       assert delete.data["actor"] == note.data["actor"]
 556       assert delete.data["object"] == note.data["object"]["id"]
 557
 558       assert Repo.get(Activity, delete.id) != nil
 559
 560       assert Repo.get(Object, object.id).data["type"] == "Tombstone"
 561     end
 562   end
 563
 564   describe "timeline post-processing" do
 565     test "it filters broken threads" do
 566       user1 = insert(:user)
 567       user2 = insert(:user)
 568       user3 = insert(:user)
 569
 570       {:ok, user1} = User.follow(user1, user3)
 571       assert User.following?(user1, user3)
 572
 573       {:ok, user2} = User.follow(user2, user3)
 574       assert User.following?(user2, user3)
 575
 576       {:ok, user3} = User.follow(user3, user2)
 577       assert User.following?(user3, user2)
 578
 579       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 580
 581       {:ok, private_activity_1} =
 582         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 583
 584       {:ok, private_activity_2} =
 585         CommonAPI.post(user2, %{
 586           "status" => "hi 3",
 587           "visibility" => "private",
 588           "in_reply_to_status_id" => private_activity_1.id
 589         })
 590
 591       {:ok, private_activity_3} =
 592         CommonAPI.post(user3, %{
 593           "status" => "hi 4",
 594           "visibility" => "private",
 595           "in_reply_to_status_id" => private_activity_2.id
 596         })
 597
 598       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 599
 600       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 601
 602       assert [public_activity, private_activity_1, private_activity_3] == activities
 603       assert length(activities) == 3
 604
 605       activities = ActivityPub.contain_timeline(activities, user1)
 606
 607       assert [public_activity, private_activity_1] == activities
 608       assert length(activities) == 2
 609     end
 610   end
 611
 612   test "it can fetch plume articles" do
 613     {:ok, object} =
 614       ActivityPub.fetch_object_from_id(
 615         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 616       )
 617
 618     assert object
 619   end
 620
 621   describe "update" do
 622     test "it creates an update activity with the new user data" do
 623       user = insert(:user)
 624       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 625       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 626
 627       {:ok, update} =
 628         ActivityPub.update(%{
 629           actor: user_data["id"],
 630           to: [user.follower_address],
 631           cc: [],
 632           object: user_data
 633         })
 634
 635       assert update.data["actor"] == user.ap_id
 636       assert update.data["to"] == [user.follower_address]
 637       assert update.data["object"]["id"] == user_data["id"]
 638       assert update.data["object"]["type"] == user_data["type"]
 639     end
 640   end
 641
 642   test "it can fetch peertube videos" do
 643     {:ok, object} =
 644       ActivityPub.fetch_object_from_id(
 645         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 646       )
 647
 648     assert object
 649   end
 650
 651   test "returned pinned statuses" do
 652     Pleroma.Config.put([:instance, :max_pinned_statuses], 3)
 653     user = insert(:user)
 654
 655     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "HI!!!"})
 656     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 657     {:ok, activity_three} = CommonAPI.post(user, %{"status" => "HI!!!"})
 658
 659     CommonAPI.pin(activity_one.id, user)
 660     user = refresh_record(user)
 661
 662     CommonAPI.pin(activity_two.id, user)
 663     user = refresh_record(user)
 664
 665     CommonAPI.pin(activity_three.id, user)
 666     user = refresh_record(user)
 667
 668     activities = ActivityPub.fetch_user_activities(user, nil, %{"pinned" => "true"})
 669
 670     assert 3 = length(activities)
 671   end
 672
 673   def data_uri do
 674     File.read!("test/fixtures/avatar_data_uri")
 675   end
 676 end