git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   2   use Pleroma.DataCase
   3   alias Pleroma.Web.ActivityPub.ActivityPub
   4   alias Pleroma.Web.ActivityPub.Utils
   5   alias Pleroma.{Activity, Object, User}
   6   alias Pleroma.Builders.ActivityBuilder
   7
   8   import Pleroma.Factory
   9
  10   describe "building a user from his ap id" do
  11     test "it returns a user" do
  12       user_id = "http://mastodon.example.org/users/admin"
  13       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  14       assert user.ap_id == user_id
  15       assert user.nickname == "admin@mastodon.example.org"
  16       assert user.info["source_data"]
  17       assert user.info["ap_enabled"]
  18       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  19     end
  20   end
  21
  22   describe "insertion" do
  23     test "returns the activity if one with the same id is already in" do
  24       activity = insert(:note_activity)
  25       {:ok, new_activity} = ActivityPub.insert(activity.data)
  26
  27       assert activity == new_activity
  28     end
  29
  30     test "inserts a given map into the activity database, giving it an id if it has none." do
  31       data = %{
  32         "ok" => true
  33       }
  34
  35       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  36       assert activity.data["ok"] == data["ok"]
  37       assert is_binary(activity.data["id"])
  38
  39       given_id = "bla"
  40
  41       data = %{
  42         "ok" => true,
  43         "id" => given_id,
  44         "context" => "blabla"
  45       }
  46
  47       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  48       assert activity.data["ok"] == data["ok"]
  49       assert activity.data["id"] == given_id
  50       assert activity.data["context"] == "blabla"
  51       assert activity.data["context_id"]
  52     end
  53
  54     test "adds a context when none is there" do
  55       data = %{
  56         "id" => "some_id",
  57         "object" => %{
  58           "id" => "object_id"
  59         }
  60       }
  61
  62       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  63
  64       assert is_binary(activity.data["context"])
  65       assert is_binary(activity.data["object"]["context"])
  66       assert activity.data["context_id"]
  67       assert activity.data["object"]["context_id"]
  68     end
  69
  70     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
  71       data = %{
  72         "object" => %{
  73           "type" => "Note",
  74           "ok" => true
  75         }
  76       }
  77
  78       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  79       assert is_binary(activity.data["object"]["id"])
  80       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
  81     end
  82   end
  83
  84   describe "create activities" do
  85     test "removes doubled 'to' recipients" do
  86       {:ok, activity} =
  87         ActivityPub.create(%{
  88           to: ["user1", "user1", "user2"],
  89           actor: %User{ap_id: "1"},
  90           context: "",
  91           object: %{}
  92         })
  93
  94       assert activity.data["to"] == ["user1", "user2"]
  95       assert activity.actor == "1"
  96       assert activity.recipients == ["user1", "user2"]
  97     end
  98   end
  99
 100   describe "fetch activities for recipients" do
 101     test "retrieve the activities for certain recipients" do
 102       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 103       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 104       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 105
 106       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 107       assert length(activities) == 2
 108       assert activities == [activity_one, activity_two]
 109     end
 110   end
 111
 112   describe "fetch activities in context" do
 113     test "retrieves activities that have a given context" do
 114       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 115       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 116       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 117       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 118       activity_five = insert(:note_activity)
 119       user = insert(:user)
 120
 121       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 122
 123       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 124       assert activities == [activity_two, activity]
 125     end
 126   end
 127
 128   test "doesn't return blocked activities" do
 129     activity_one = insert(:note_activity)
 130     activity_two = insert(:note_activity)
 131     user = insert(:user)
 132     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 133
 134     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 135
 136     assert Enum.member?(activities, activity_two)
 137     refute Enum.member?(activities, activity_one)
 138
 139     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 140
 141     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 142
 143     assert Enum.member?(activities, activity_two)
 144     assert Enum.member?(activities, activity_one)
 145
 146     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 147
 148     assert Enum.member?(activities, activity_two)
 149     assert Enum.member?(activities, activity_one)
 150   end
 151
 152   describe "public fetch activities" do
 153     test "retrieves public activities" do
 154       _activities = ActivityPub.fetch_public_activities()
 155
 156       %{public: public} = ActivityBuilder.public_and_non_public()
 157
 158       activities = ActivityPub.fetch_public_activities()
 159       assert length(activities) == 1
 160       assert Enum.at(activities, 0) == public
 161     end
 162
 163     test "retrieves a maximum of 20 activities" do
 164       activities = ActivityBuilder.insert_list(30)
 165       last_expected = List.last(activities)
 166
 167       activities = ActivityPub.fetch_public_activities()
 168       last = List.last(activities)
 169
 170       assert length(activities) == 20
 171       assert last == last_expected
 172     end
 173
 174     test "retrieves ids starting from a since_id" do
 175       activities = ActivityBuilder.insert_list(30)
 176       later_activities = ActivityBuilder.insert_list(10)
 177       since_id = List.last(activities).id
 178       last_expected = List.last(later_activities)
 179
 180       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 181       last = List.last(activities)
 182
 183       assert length(activities) == 10
 184       assert last == last_expected
 185     end
 186
 187     test "retrieves ids up to max_id" do
 188       _first_activities = ActivityBuilder.insert_list(10)
 189       activities = ActivityBuilder.insert_list(20)
 190       later_activities = ActivityBuilder.insert_list(10)
 191       max_id = List.first(later_activities).id
 192       last_expected = List.last(activities)
 193
 194       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 195       last = List.last(activities)
 196
 197       assert length(activities) == 20
 198       assert last == last_expected
 199     end
 200   end
 201
 202   describe "like an object" do
 203     test "adds a like activity to the db" do
 204       note_activity = insert(:note_activity)
 205       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 206       user = insert(:user)
 207       user_two = insert(:user)
 208
 209       {:ok, like_activity, object} = ActivityPub.like(user, object)
 210
 211       assert like_activity.data["actor"] == user.ap_id
 212       assert like_activity.data["type"] == "Like"
 213       assert like_activity.data["object"] == object.data["id"]
 214       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 215       assert like_activity.data["context"] == object.data["context"]
 216       assert object.data["like_count"] == 1
 217       assert object.data["likes"] == [user.ap_id]
 218
 219       # Just return the original activity if the user already liked it.
 220       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 221
 222       assert like_activity == same_like_activity
 223       assert object.data["likes"] == [user.ap_id]
 224
 225       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 226       assert note_activity.data["object"]["like_count"] == 1
 227
 228       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 229       assert object.data["like_count"] == 2
 230     end
 231   end
 232
 233   describe "unliking" do
 234     test "unliking a previously liked object" do
 235       note_activity = insert(:note_activity)
 236       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 237       user = insert(:user)
 238
 239       # Unliking something that hasn't been liked does nothing
 240       {:ok, object} = ActivityPub.unlike(user, object)
 241       assert object.data["like_count"] == 0
 242
 243       {:ok, like_activity, object} = ActivityPub.like(user, object)
 244       assert object.data["like_count"] == 1
 245
 246       {:ok, object} = ActivityPub.unlike(user, object)
 247       assert object.data["like_count"] == 0
 248
 249       assert Repo.get(Activity, like_activity.id) == nil
 250     end
 251   end
 252
 253   describe "announcing an object" do
 254     test "adds an announce activity to the db" do
 255       note_activity = insert(:note_activity)
 256       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 257       user = insert(:user)
 258
 259       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 260       assert object.data["announcement_count"] == 1
 261       assert object.data["announcements"] == [user.ap_id]
 262
 263       assert announce_activity.data["to"] == [
 264                User.ap_followers(user),
 265                note_activity.data["actor"]
 266              ]
 267
 268       assert announce_activity.data["object"] == object.data["id"]
 269       assert announce_activity.data["actor"] == user.ap_id
 270       assert announce_activity.data["context"] == object.data["context"]
 271     end
 272   end
 273
 274   describe "unannouncing an object" do
 275     test "unannouncing a previously announced object" do
 276       note_activity = insert(:note_activity)
 277       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 278       user = insert(:user)
 279
 280       # Unannouncing an object that is not announced does nothing
 281       #{:ok, object} = ActivityPub.unannounce(user, object)
 282       #assert object.data["announcement_count"] == 0
 283
 284       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 285       assert object.data["announcement_count"] == 1
 286
 287       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 288       assert object.data["announcement_count"] == 0
 289
 290       assert unannounce_activity.data["to"] == [
 291                User.ap_followers(user),
 292                note_activity.data["actor"]
 293       ]
 294       assert unannounce_activity.data["type"] == "Undo"
 295       assert unannounce_activity.data["object"] == object.data["id"]
 296       assert unannounce_activity.data["actor"] == user.ap_id
 297       assert unannounce_activity.data["context"] == object.data["context"]
 298
 299       assert Repo.get(Activity, announce_activity.id) == nil
 300     end
 301   end
 302
 303   describe "uploading files" do
 304     test "copies the file to the configured folder" do
 305       file = %Plug.Upload{
 306         content_type: "image/jpg",
 307         path: Path.absname("test/fixtures/image.jpg"),
 308         filename: "an_image.jpg"
 309       }
 310
 311       {:ok, %Object{} = object} = ActivityPub.upload(file)
 312       assert object.data["name"] == "an_image.jpg"
 313     end
 314
 315     test "works with base64 encoded images" do
 316       file = %{
 317         "img" => data_uri()
 318       }
 319
 320       {:ok, %Object{}} = ActivityPub.upload(file)
 321     end
 322   end
 323
 324   describe "fetch the latest Follow" do
 325     test "fetches the latest Follow activity" do
 326       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 327       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 328       followed = Repo.get_by(User, ap_id: activity.data["object"])
 329
 330       assert activity == Utils.fetch_latest_follow(follower, followed)
 331     end
 332   end
 333
 334   describe "fetching an object" do
 335     test "it fetches an object" do
 336       {:ok, object} =
 337         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 338
 339       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 340       assert activity.data["id"]
 341
 342       {:ok, object_again} =
 343         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 344
 345       assert [attachment] = object.data["attachment"]
 346       assert is_list(attachment["url"])
 347
 348       assert object == object_again
 349     end
 350
 351     test "it works with objects only available via Ostatus" do
 352       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 353       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 354       assert activity.data["id"]
 355
 356       {:ok, object_again} =
 357         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 358
 359       assert object == object_again
 360     end
 361
 362     test "it correctly stitches up conversations between ostatus and ap" do
 363       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 364       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 365
 366       object = Object.get_by_ap_id(object.data["inReplyTo"])
 367       assert object
 368     end
 369   end
 370
 371   describe "following / unfollowing" do
 372     test "creates a follow activity" do
 373       follower = insert(:user)
 374       followed = insert(:user)
 375
 376       {:ok, activity} = ActivityPub.follow(follower, followed)
 377       assert activity.data["type"] == "Follow"
 378       assert activity.data["actor"] == follower.ap_id
 379       assert activity.data["object"] == followed.ap_id
 380     end
 381
 382     test "creates an undo activity for the last follow" do
 383       follower = insert(:user)
 384       followed = insert(:user)
 385
 386       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 387       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 388
 389       assert activity.data["type"] == "Undo"
 390       assert activity.data["actor"] == follower.ap_id
 391       assert activity.data["object"] == follow_activity.data["id"]
 392     end
 393   end
 394
 395   describe "deletion" do
 396     test "it creates a delete activity and deletes the original object" do
 397       note = insert(:note_activity)
 398       object = Object.get_by_ap_id(note.data["object"]["id"])
 399       {:ok, delete} = ActivityPub.delete(object)
 400
 401       assert delete.data["type"] == "Delete"
 402       assert delete.data["actor"] == note.data["actor"]
 403       assert delete.data["object"] == note.data["object"]["id"]
 404
 405       assert Repo.get(Activity, delete.id) != nil
 406
 407       assert Repo.get(Object, object.id) == nil
 408     end
 409   end
 410
 411   describe "update" do
 412     test "it creates an update activity with the new user data" do
 413       user = insert(:user)
 414       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 415       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 416
 417       {:ok, update} =
 418         ActivityPub.update(%{
 419           actor: user_data["id"],
 420           to: [user.follower_address],
 421           cc: [],
 422           object: user_data
 423         })
 424
 425       assert update.data["actor"] == user.ap_id
 426       assert update.data["to"] == [user.follower_address]
 427       assert update.data["object"]["id"] == user_data["id"]
 428       assert update.data["object"]["type"] == user_data["type"]
 429     end
 430   end
 431
 432   def data_uri do
 433     File.read!("test/fixtures/avatar_data_uri")
 434   end
 435 end