git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.{Activity, Object, User}
  11   alias Pleroma.Builders.ActivityBuilder
  12
  13   import Pleroma.Factory
  14   import Tesla.Mock
  15
  16   setup do
  17     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  18     :ok
  19   end
  20
  21   describe "building a user from his ap id" do
  22     test "it returns a user" do
  23       user_id = "http://mastodon.example.org/users/admin"
  24       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  25       assert user.ap_id == user_id
  26       assert user.nickname == "admin@mastodon.example.org"
  27       assert user.info.source_data
  28       assert user.info.ap_enabled
  29       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  30     end
  31   end
  32
  33   describe "insertion" do
  34     test "drops activities beyond a certain limit" do
  35       limit = Pleroma.Config.get([:instance, :remote_limit])
  36
  37       random_text =
  38         :crypto.strong_rand_bytes(limit + 1)
  39         |> Base.encode64()
  40         |> binary_part(0, limit + 1)
  41
  42       data = %{
  43         "ok" => true,
  44         "object" => %{
  45           "content" => random_text
  46         }
  47       }
  48
  49       assert {:error, {:remote_limit_error, _}} = ActivityPub.insert(data)
  50     end
  51
  52     test "returns the activity if one with the same id is already in" do
  53       activity = insert(:note_activity)
  54       {:ok, new_activity} = ActivityPub.insert(activity.data)
  55
  56       assert activity == new_activity
  57     end
  58
  59     test "inserts a given map into the activity database, giving it an id if it has none." do
  60       data = %{
  61         "ok" => true
  62       }
  63
  64       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  65       assert activity.data["ok"] == data["ok"]
  66       assert is_binary(activity.data["id"])
  67
  68       given_id = "bla"
  69
  70       data = %{
  71         "ok" => true,
  72         "id" => given_id,
  73         "context" => "blabla"
  74       }
  75
  76       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  77       assert activity.data["ok"] == data["ok"]
  78       assert activity.data["id"] == given_id
  79       assert activity.data["context"] == "blabla"
  80       assert activity.data["context_id"]
  81     end
  82
  83     test "adds a context when none is there" do
  84       data = %{
  85         "id" => "some_id",
  86         "object" => %{
  87           "id" => "object_id"
  88         }
  89       }
  90
  91       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
  92
  93       assert is_binary(activity.data["context"])
  94       assert is_binary(activity.data["object"]["context"])
  95       assert activity.data["context_id"]
  96       assert activity.data["object"]["context_id"]
  97     end
  98
  99     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
 100       data = %{
 101         "object" => %{
 102           "type" => "Note",
 103           "ok" => true
 104         }
 105       }
 106
 107       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 108       assert is_binary(activity.data["object"]["id"])
 109       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
 110     end
 111   end
 112
 113   describe "create activities" do
 114     test "removes doubled 'to' recipients" do
 115       user = insert(:user)
 116
 117       {:ok, activity} =
 118         ActivityPub.create(%{
 119           to: ["user1", "user1", "user2"],
 120           actor: user,
 121           context: "",
 122           object: %{}
 123         })
 124
 125       assert activity.data["to"] == ["user1", "user2"]
 126       assert activity.actor == user.ap_id
 127       assert activity.recipients == ["user1", "user2"]
 128     end
 129   end
 130
 131   describe "fetch activities for recipients" do
 132     test "retrieve the activities for certain recipients" do
 133       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 134       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 135       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 136
 137       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 138       assert length(activities) == 2
 139       assert activities == [activity_one, activity_two]
 140     end
 141   end
 142
 143   describe "fetch activities in context" do
 144     test "retrieves activities that have a given context" do
 145       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 146       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 147       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 148       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 149       activity_five = insert(:note_activity)
 150       user = insert(:user)
 151
 152       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 153
 154       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 155       assert activities == [activity_two, activity]
 156     end
 157   end
 158
 159   test "doesn't return blocked activities" do
 160     activity_one = insert(:note_activity)
 161     activity_two = insert(:note_activity)
 162     activity_three = insert(:note_activity)
 163     user = insert(:user)
 164     booster = insert(:user)
 165     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 166
 167     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 168
 169     assert Enum.member?(activities, activity_two)
 170     assert Enum.member?(activities, activity_three)
 171     refute Enum.member?(activities, activity_one)
 172
 173     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 174
 175     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 176
 177     assert Enum.member?(activities, activity_two)
 178     assert Enum.member?(activities, activity_three)
 179     assert Enum.member?(activities, activity_one)
 180
 181     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 182     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 183     %Activity{} = boost_activity = Activity.get_create_activity_by_object_ap_id(id)
 184     activity_three = Repo.get(Activity, activity_three.id)
 185
 186     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 187
 188     assert Enum.member?(activities, activity_two)
 189     refute Enum.member?(activities, activity_three)
 190     refute Enum.member?(activities, boost_activity)
 191     assert Enum.member?(activities, activity_one)
 192
 193     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 194
 195     assert Enum.member?(activities, activity_two)
 196     assert Enum.member?(activities, activity_three)
 197     assert Enum.member?(activities, boost_activity)
 198     assert Enum.member?(activities, activity_one)
 199   end
 200
 201   test "excludes reblogs on request" do
 202     user = insert(:user)
 203     {:ok, expected_activity} = ActivityBuilder.insert(%{"type" => "Create"}, %{:user => user})
 204     {:ok, _} = ActivityBuilder.insert(%{"type" => "Announce"}, %{:user => user})
 205
 206     [activity] = ActivityPub.fetch_user_activities(user, nil, %{"exclude_reblogs" => "true"})
 207
 208     assert activity == expected_activity
 209   end
 210
 211   describe "public fetch activities" do
 212     test "doesn't retrieve unlisted activities" do
 213       user = insert(:user)
 214
 215       {:ok, _unlisted_activity} =
 216         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 217
 218       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 219
 220       [activity] = ActivityPub.fetch_public_activities()
 221
 222       assert activity == listed_activity
 223     end
 224
 225     test "retrieves public activities" do
 226       _activities = ActivityPub.fetch_public_activities()
 227
 228       %{public: public} = ActivityBuilder.public_and_non_public()
 229
 230       activities = ActivityPub.fetch_public_activities()
 231       assert length(activities) == 1
 232       assert Enum.at(activities, 0) == public
 233     end
 234
 235     test "retrieves a maximum of 20 activities" do
 236       activities = ActivityBuilder.insert_list(30)
 237       last_expected = List.last(activities)
 238
 239       activities = ActivityPub.fetch_public_activities()
 240       last = List.last(activities)
 241
 242       assert length(activities) == 20
 243       assert last == last_expected
 244     end
 245
 246     test "retrieves ids starting from a since_id" do
 247       activities = ActivityBuilder.insert_list(30)
 248       later_activities = ActivityBuilder.insert_list(10)
 249       since_id = List.last(activities).id
 250       last_expected = List.last(later_activities)
 251
 252       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 253       last = List.last(activities)
 254
 255       assert length(activities) == 10
 256       assert last == last_expected
 257     end
 258
 259     test "retrieves ids up to max_id" do
 260       _first_activities = ActivityBuilder.insert_list(10)
 261       activities = ActivityBuilder.insert_list(20)
 262       later_activities = ActivityBuilder.insert_list(10)
 263       max_id = List.first(later_activities).id
 264       last_expected = List.last(activities)
 265
 266       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 267       last = List.last(activities)
 268
 269       assert length(activities) == 20
 270       assert last == last_expected
 271     end
 272   end
 273
 274   describe "like an object" do
 275     test "adds a like activity to the db" do
 276       note_activity = insert(:note_activity)
 277       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 278       user = insert(:user)
 279       user_two = insert(:user)
 280
 281       {:ok, like_activity, object} = ActivityPub.like(user, object)
 282
 283       assert like_activity.data["actor"] == user.ap_id
 284       assert like_activity.data["type"] == "Like"
 285       assert like_activity.data["object"] == object.data["id"]
 286       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 287       assert like_activity.data["context"] == object.data["context"]
 288       assert object.data["like_count"] == 1
 289       assert object.data["likes"] == [user.ap_id]
 290
 291       # Just return the original activity if the user already liked it.
 292       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 293
 294       assert like_activity == same_like_activity
 295       assert object.data["likes"] == [user.ap_id]
 296
 297       [note_activity] = Activity.all_by_object_ap_id(object.data["id"])
 298       assert note_activity.data["object"]["like_count"] == 1
 299
 300       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 301       assert object.data["like_count"] == 2
 302     end
 303   end
 304
 305   describe "unliking" do
 306     test "unliking a previously liked object" do
 307       note_activity = insert(:note_activity)
 308       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 309       user = insert(:user)
 310
 311       # Unliking something that hasn't been liked does nothing
 312       {:ok, object} = ActivityPub.unlike(user, object)
 313       assert object.data["like_count"] == 0
 314
 315       {:ok, like_activity, object} = ActivityPub.like(user, object)
 316       assert object.data["like_count"] == 1
 317
 318       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 319       assert object.data["like_count"] == 0
 320
 321       assert Repo.get(Activity, like_activity.id) == nil
 322     end
 323   end
 324
 325   describe "announcing an object" do
 326     test "adds an announce activity to the db" do
 327       note_activity = insert(:note_activity)
 328       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 329       user = insert(:user)
 330
 331       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 332       assert object.data["announcement_count"] == 1
 333       assert object.data["announcements"] == [user.ap_id]
 334
 335       assert announce_activity.data["to"] == [
 336                User.ap_followers(user),
 337                note_activity.data["actor"]
 338              ]
 339
 340       assert announce_activity.data["object"] == object.data["id"]
 341       assert announce_activity.data["actor"] == user.ap_id
 342       assert announce_activity.data["context"] == object.data["context"]
 343     end
 344   end
 345
 346   describe "unannouncing an object" do
 347     test "unannouncing a previously announced object" do
 348       note_activity = insert(:note_activity)
 349       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 350       user = insert(:user)
 351
 352       # Unannouncing an object that is not announced does nothing
 353       # {:ok, object} = ActivityPub.unannounce(user, object)
 354       # assert object.data["announcement_count"] == 0
 355
 356       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 357       assert object.data["announcement_count"] == 1
 358
 359       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 360       assert object.data["announcement_count"] == 0
 361
 362       assert unannounce_activity.data["to"] == [
 363                User.ap_followers(user),
 364                announce_activity.data["actor"]
 365              ]
 366
 367       assert unannounce_activity.data["type"] == "Undo"
 368       assert unannounce_activity.data["object"] == announce_activity.data
 369       assert unannounce_activity.data["actor"] == user.ap_id
 370       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 371
 372       assert Repo.get(Activity, announce_activity.id) == nil
 373     end
 374   end
 375
 376   describe "uploading files" do
 377     test "copies the file to the configured folder" do
 378       file = %Plug.Upload{
 379         content_type: "image/jpg",
 380         path: Path.absname("test/fixtures/image.jpg"),
 381         filename: "an_image.jpg"
 382       }
 383
 384       {:ok, %Object{} = object} = ActivityPub.upload(file)
 385       assert object.data["name"] == "an_image.jpg"
 386     end
 387
 388     test "works with base64 encoded images" do
 389       file = %{
 390         "img" => data_uri()
 391       }
 392
 393       {:ok, %Object{}} = ActivityPub.upload(file)
 394     end
 395   end
 396
 397   describe "fetch the latest Follow" do
 398     test "fetches the latest Follow activity" do
 399       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 400       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 401       followed = Repo.get_by(User, ap_id: activity.data["object"])
 402
 403       assert activity == Utils.fetch_latest_follow(follower, followed)
 404     end
 405   end
 406
 407   describe "fetching an object" do
 408     test "it fetches an object" do
 409       {:ok, object} =
 410         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 411
 412       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 413       assert activity.data["id"]
 414
 415       {:ok, object_again} =
 416         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 417
 418       assert [attachment] = object.data["attachment"]
 419       assert is_list(attachment["url"])
 420
 421       assert object == object_again
 422     end
 423
 424     test "it works with objects only available via Ostatus" do
 425       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 426       assert activity = Activity.get_create_activity_by_object_ap_id(object.data["id"])
 427       assert activity.data["id"]
 428
 429       {:ok, object_again} =
 430         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 431
 432       assert object == object_again
 433     end
 434
 435     test "it correctly stitches up conversations between ostatus and ap" do
 436       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 437       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 438
 439       object = Object.get_by_ap_id(object.data["inReplyTo"])
 440       assert object
 441     end
 442   end
 443
 444   describe "following / unfollowing" do
 445     test "creates a follow activity" do
 446       follower = insert(:user)
 447       followed = insert(:user)
 448
 449       {:ok, activity} = ActivityPub.follow(follower, followed)
 450       assert activity.data["type"] == "Follow"
 451       assert activity.data["actor"] == follower.ap_id
 452       assert activity.data["object"] == followed.ap_id
 453     end
 454
 455     test "creates an undo activity for the last follow" do
 456       follower = insert(:user)
 457       followed = insert(:user)
 458
 459       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 460       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 461
 462       assert activity.data["type"] == "Undo"
 463       assert activity.data["actor"] == follower.ap_id
 464
 465       assert is_map(activity.data["object"])
 466       assert activity.data["object"]["type"] == "Follow"
 467       assert activity.data["object"]["object"] == followed.ap_id
 468       assert activity.data["object"]["id"] == follow_activity.data["id"]
 469     end
 470   end
 471
 472   describe "blocking / unblocking" do
 473     test "creates a block activity" do
 474       blocker = insert(:user)
 475       blocked = insert(:user)
 476
 477       {:ok, activity} = ActivityPub.block(blocker, blocked)
 478
 479       assert activity.data["type"] == "Block"
 480       assert activity.data["actor"] == blocker.ap_id
 481       assert activity.data["object"] == blocked.ap_id
 482     end
 483
 484     test "creates an undo activity for the last block" do
 485       blocker = insert(:user)
 486       blocked = insert(:user)
 487
 488       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 489       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 490
 491       assert activity.data["type"] == "Undo"
 492       assert activity.data["actor"] == blocker.ap_id
 493
 494       assert is_map(activity.data["object"])
 495       assert activity.data["object"]["type"] == "Block"
 496       assert activity.data["object"]["object"] == blocked.ap_id
 497       assert activity.data["object"]["id"] == block_activity.data["id"]
 498     end
 499   end
 500
 501   describe "deletion" do
 502     test "it creates a delete activity and deletes the original object" do
 503       note = insert(:note_activity)
 504       object = Object.get_by_ap_id(note.data["object"]["id"])
 505       {:ok, delete} = ActivityPub.delete(object)
 506
 507       assert delete.data["type"] == "Delete"
 508       assert delete.data["actor"] == note.data["actor"]
 509       assert delete.data["object"] == note.data["object"]["id"]
 510
 511       assert Repo.get(Activity, delete.id) != nil
 512
 513       assert Repo.get(Object, object.id).data["type"] == "Tombstone"
 514     end
 515   end
 516
 517   describe "timeline post-processing" do
 518     test "it filters broken threads" do
 519       user1 = insert(:user)
 520       user2 = insert(:user)
 521       user3 = insert(:user)
 522
 523       {:ok, user1} = User.follow(user1, user3)
 524       assert User.following?(user1, user3)
 525
 526       {:ok, user2} = User.follow(user2, user3)
 527       assert User.following?(user2, user3)
 528
 529       {:ok, user3} = User.follow(user3, user2)
 530       assert User.following?(user3, user2)
 531
 532       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 533
 534       {:ok, private_activity_1} =
 535         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 536
 537       {:ok, private_activity_2} =
 538         CommonAPI.post(user2, %{
 539           "status" => "hi 3",
 540           "visibility" => "private",
 541           "in_reply_to_status_id" => private_activity_1.id
 542         })
 543
 544       {:ok, private_activity_3} =
 545         CommonAPI.post(user3, %{
 546           "status" => "hi 4",
 547           "visibility" => "private",
 548           "in_reply_to_status_id" => private_activity_2.id
 549         })
 550
 551       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 552
 553       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 554
 555       assert [public_activity, private_activity_1, private_activity_3] == activities
 556       assert length(activities) == 3
 557
 558       activities = ActivityPub.contain_timeline(activities, user1)
 559
 560       assert [public_activity, private_activity_1] == activities
 561       assert length(activities) == 2
 562     end
 563   end
 564
 565   test "it can fetch plume articles" do
 566     {:ok, object} =
 567       ActivityPub.fetch_object_from_id(
 568         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 569       )
 570
 571     assert object
 572   end
 573
 574   describe "update" do
 575     test "it creates an update activity with the new user data" do
 576       user = insert(:user)
 577       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 578       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 579
 580       {:ok, update} =
 581         ActivityPub.update(%{
 582           actor: user_data["id"],
 583           to: [user.follower_address],
 584           cc: [],
 585           object: user_data
 586         })
 587
 588       assert update.data["actor"] == user.ap_id
 589       assert update.data["to"] == [user.follower_address]
 590       assert update.data["object"]["id"] == user_data["id"]
 591       assert update.data["object"]["type"] == user_data["type"]
 592     end
 593   end
 594
 595   test "it can fetch peertube videos" do
 596     {:ok, object} =
 597       ActivityPub.fetch_object_from_id(
 598         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 599       )
 600
 601     assert object
 602   end
 603
 604   def data_uri do
 605     File.read!("test/fixtures/avatar_data_uri")
 606   end
 607 end