git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_controller_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubControllerTest do
   2   use Pleroma.Web.ConnCase
   3   import Pleroma.Factory
   4   alias Pleroma.Web.ActivityPub.{UserView, ObjectView}
   5   alias Pleroma.{Repo, User}
   6   alias Pleroma.Activity
   7
   8   describe "/users/:nickname" do
   9     test "it returns a json representation of the user", %{conn: conn} do
  10       user = insert(:user)
  11
  12       conn =
  13         conn
  14         |> put_req_header("accept", "application/activity+json")
  15         |> get("/users/#{user.nickname}")
  16
  17       user = Repo.get(User, user.id)
  18
  19       assert json_response(conn, 200) == UserView.render("user.json", %{user: user})
  20     end
  21   end
  22
  23   describe "/object/:uuid" do
  24     test "it returns a json representation of the object", %{conn: conn} do
  25       note = insert(:note)
  26       uuid = String.split(note.data["id"], "/") |> List.last()
  27
  28       conn =
  29         conn
  30         |> put_req_header("accept", "application/activity+json")
  31         |> get("/objects/#{uuid}")
  32
  33       assert json_response(conn, 200) == ObjectView.render("object.json", %{object: note})
  34     end
  35   end
  36
  37   describe "/users/:nickname/inbox" do
  38     test "it inserts an incoming activity into the database", %{conn: conn} do
  39       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
  40
  41       conn =
  42         conn
  43         |> assign(:valid_signature, true)
  44         |> put_req_header("content-type", "application/activity+json")
  45         |> post("/inbox", data)
  46
  47       assert "ok" == json_response(conn, 200)
  48       :timer.sleep(500)
  49       assert Activity.get_by_ap_id(data["id"])
  50     end
  51   end
  52
  53   describe "/users/:nickname/followers" do
  54     test "it returns the followers in a collection", %{conn: conn} do
  55       user = insert(:user)
  56       user_two = insert(:user)
  57       User.follow(user, user_two)
  58
  59       result =
  60         conn
  61         |> get("/users/#{user_two.nickname}/followers")
  62         |> json_response(200)
  63
  64       assert result["first"]["orderedItems"] == [user.ap_id]
  65     end
  66
  67     test "it works for more than 10 users", %{conn: conn} do
  68       user = insert(:user)
  69
  70       Enum.each(1..15, fn _ ->
  71         other_user = insert(:user)
  72         User.follow(other_user, user)
  73       end)
  74
  75       result =
  76         conn
  77         |> get("/users/#{user.nickname}/followers")
  78         |> json_response(200)
  79
  80       assert length(result["first"]["orderedItems"]) == 10
  81       assert result["first"]["totalItems"] == 15
  82       assert result["totalItems"] == 15
  83
  84       result =
  85         conn
  86         |> get("/users/#{user.nickname}/followers?page=2")
  87         |> json_response(200)
  88
  89       assert length(result["orderedItems"]) == 5
  90       assert result["totalItems"] == 15
  91     end
  92   end
  93
  94   describe "/users/:nickname/following" do
  95     test "it returns the following in a collection", %{conn: conn} do
  96       user = insert(:user)
  97       user_two = insert(:user)
  98       User.follow(user, user_two)
  99
 100       result =
 101         conn
 102         |> get("/users/#{user.nickname}/following")
 103         |> json_response(200)
 104
 105       assert result["first"]["orderedItems"] == [user_two.ap_id]
 106     end
 107
 108     test "it works for more than 10 users", %{conn: conn} do
 109       user = insert(:user)
 110
 111       Enum.each(1..15, fn _ ->
 112         user = Repo.get(User, user.id)
 113         other_user = insert(:user)
 114         User.follow(user, other_user)
 115       end)
 116
 117       result =
 118         conn
 119         |> get("/users/#{user.nickname}/following")
 120         |> json_response(200)
 121
 122       assert length(result["first"]["orderedItems"]) == 10
 123       assert result["first"]["totalItems"] == 15
 124       assert result["totalItems"] == 15
 125
 126       result =
 127         conn
 128         |> get("/users/#{user.nickname}/following?page=2")
 129         |> json_response(200)
 130
 131       assert length(result["orderedItems"]) == 5
 132       assert result["totalItems"] == 15
 133     end
 134   end
 135 end