git.squeep.com Git - akkoma/blob - test/user_test.exs

   1 defmodule Pleroma.UserTest do
   2   alias Pleroma.Builders.UserBuilder
   3   alias Pleroma.{User, Repo, Activity}
   4   alias Pleroma.Web.OStatus
   5   alias Pleroma.Web.Websub.WebsubClientSubscription
   6   alias Pleroma.Web.CommonAPI
   7   use Pleroma.DataCase
   8
   9   import Pleroma.Factory
  10   import Ecto.Query
  11
  12   test "ap_id returns the activity pub id for the user" do
  13     user = UserBuilder.build
  14
  15     expected_ap_id = "#{Pleroma.Web.base_url}/users/#{user.nickname}"
  16
  17     assert expected_ap_id == User.ap_id(user)
  18   end
  19
  20   test "ap_followers returns the followers collection for the user" do
  21     user = UserBuilder.build
  22
  23     expected_followers_collection = "#{User.ap_id(user)}/followers"
  24
  25     assert expected_followers_collection == User.ap_followers(user)
  26   end
  27
  28   test "follow takes a user and another user" do
  29     user = insert(:user)
  30     followed = insert(:user)
  31
  32     {:ok, user} = User.follow(user, followed)
  33
  34     user = Repo.get(User, user.id)
  35
  36     followed = User.get_by_ap_id(followed.ap_id)
  37     assert followed.info["follower_count"] == 1
  38
  39     assert User.ap_followers(followed) in user.following
  40   end
  41
  42   test "can't follow a deactivated users" do
  43     user = insert(:user)
  44     followed = insert(:user, info: %{"deactivated" => true})
  45
  46     {:error, _} = User.follow(user, followed)
  47   end
  48
  49   test "following a remote user will ensure a websub subscription is present" do
  50     user = insert(:user)
  51     {:ok, followed} = OStatus.make_user("shp@social.heldscal.la")
  52
  53     assert followed.local == false
  54
  55     {:ok, user} = User.follow(user, followed)
  56     assert User.ap_followers(followed) in user.following
  57
  58     query = from w in WebsubClientSubscription,
  59     where: w.topic == ^followed.info["topic"]
  60     websub = Repo.one(query)
  61
  62     assert websub
  63   end
  64
  65   test "unfollow takes a user and another user" do
  66     followed = insert(:user)
  67     user = insert(:user, %{following: [User.ap_followers(followed)]})
  68
  69     {:ok, user, _activity } = User.unfollow(user, followed)
  70
  71     user = Repo.get(User, user.id)
  72
  73     assert user.following == []
  74   end
  75
  76   test "unfollow doesn't unfollow yourself" do
  77     user = insert(:user)
  78
  79     {:error, _} = User.unfollow(user, user)
  80
  81     user = Repo.get(User, user.id)
  82     assert user.following == [user.ap_id]
  83   end
  84
  85
  86   test "test if a user is following another user" do
  87     followed = insert(:user)
  88     user = insert(:user, %{following: [User.ap_followers(followed)]})
  89
  90     assert User.following?(user, followed)
  91     refute User.following?(followed, user)
  92   end
  93
  94   describe "user registration" do
  95     @full_user_data %{
  96       bio: "A guy",
  97       name: "my name",
  98       nickname: "nick",
  99       password: "test",
 100       password_confirmation: "test",
 101       email: "email@example.com"
 102     }
 103
 104     test "it requires a bio, email, name, nickname and password" do
 105       @full_user_data
 106       |> Map.keys
 107       |> Enum.each(fn (key) ->
 108         params = Map.delete(@full_user_data, key)
 109         changeset = User.register_changeset(%User{}, params)
 110         assert changeset.valid? == false
 111       end)
 112     end
 113
 114     test "it sets the password_hash, ap_id and following fields" do
 115       changeset = User.register_changeset(%User{}, @full_user_data)
 116
 117       assert changeset.valid?
 118
 119       assert is_binary(changeset.changes[:password_hash])
 120       assert changeset.changes[:ap_id] == User.ap_id(%User{nickname: @full_user_data.nickname})
 121       assert changeset.changes[:following] == [User.ap_followers(%User{nickname: @full_user_data.nickname})]
 122       assert changeset.changes.follower_address == "#{changeset.changes.ap_id}/followers"
 123     end
 124   end
 125
 126   describe "fetching a user from nickname or trying to build one" do
 127     test "gets an existing user" do
 128       user = insert(:user)
 129       fetched_user = User.get_or_fetch_by_nickname(user.nickname)
 130
 131       assert user == fetched_user
 132     end
 133
 134     test "gets an existing user, case insensitive" do
 135       user = insert(:user, nickname: "nick")
 136       fetched_user = User.get_or_fetch_by_nickname("NICK")
 137
 138       assert user == fetched_user
 139     end
 140
 141     test "fetches an external user via ostatus if no user exists" do
 142       fetched_user = User.get_or_fetch_by_nickname("shp@social.heldscal.la")
 143       assert fetched_user.nickname == "shp@social.heldscal.la"
 144     end
 145
 146     test "returns nil if no user could be fetched" do
 147       fetched_user = User.get_or_fetch_by_nickname("nonexistant@social.heldscal.la")
 148       assert fetched_user == nil
 149     end
 150
 151     test "returns nil for nonexistant local user" do
 152       fetched_user = User.get_or_fetch_by_nickname("nonexistant")
 153       assert fetched_user == nil
 154     end
 155   end
 156
 157   test "returns an ap_id for a user" do
 158     user = insert(:user)
 159     assert User.ap_id(user) == Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :feed_redirect, user.nickname)
 160   end
 161
 162   test "returns an ap_followers link for a user" do
 163     user = insert(:user)
 164     assert User.ap_followers(user) == Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :feed_redirect, user.nickname) <> "/followers"
 165   end
 166
 167   describe "remote user creation changeset" do
 168     @valid_remote %{
 169       bio: "hello",
 170       name: "Someone",
 171       nickname: "a@b.de",
 172       ap_id: "http...",
 173       info: %{some: "info"},
 174       avatar: %{some: "avatar"}
 175     }
 176
 177     test "it confirms validity" do
 178       cs = User.remote_user_creation(@valid_remote)
 179       assert cs.valid?
 180     end
 181
 182     test "it sets the follower_adress" do
 183       cs = User.remote_user_creation(@valid_remote)
 184       # remote users get a fake local follower address
 185       assert cs.changes.follower_address == User.ap_followers(%User{ nickname: @valid_remote[:nickname] })
 186     end
 187
 188     test "it enforces the fqn format for nicknames" do
 189       cs = User.remote_user_creation(%{@valid_remote | nickname: "bla"})
 190       assert cs.changes.local == false
 191       assert cs.changes.avatar
 192       refute cs.valid?
 193     end
 194
 195     test "it has required fields" do
 196       [:name, :nickname, :ap_id]
 197       |> Enum.each(fn (field) ->
 198         cs = User.remote_user_creation(Map.delete(@valid_remote, field))
 199         refute cs.valid?
 200       end)
 201     end
 202
 203     test "it restricts some sizes" do
 204       [bio: 5000, name: 100]
 205       |> Enum.each(fn ({field, size}) ->
 206         string = String.pad_leading(".", size)
 207         cs = User.remote_user_creation(Map.put(@valid_remote, field, string))
 208         assert cs.valid?
 209
 210         string = String.pad_leading(".", size + 1)
 211         cs = User.remote_user_creation(Map.put(@valid_remote, field, string))
 212         refute cs.valid?
 213       end)
 214     end
 215   end
 216
 217   describe "followers and friends" do
 218     test "gets all followers for a given user" do
 219       user = insert(:user)
 220       follower_one = insert(:user)
 221       follower_two = insert(:user)
 222       not_follower = insert(:user)
 223
 224       {:ok, follower_one} = User.follow(follower_one, user)
 225       {:ok, follower_two} = User.follow(follower_two, user)
 226
 227       {:ok, res} = User.get_followers(user)
 228
 229       assert Enum.member?(res, follower_one)
 230       assert Enum.member?(res, follower_two)
 231       refute Enum.member?(res, not_follower)
 232     end
 233
 234     test "gets all friends (followed users) for a given user" do
 235       user = insert(:user)
 236       followed_one = insert(:user)
 237       followed_two = insert(:user)
 238       not_followed = insert(:user)
 239
 240       {:ok, user} = User.follow(user, followed_one)
 241       {:ok, user} = User.follow(user, followed_two)
 242
 243       {:ok, res} = User.get_friends(user)
 244
 245       followed_one = User.get_by_ap_id(followed_one.ap_id)
 246       followed_two = User.get_by_ap_id(followed_two.ap_id)
 247       assert Enum.member?(res, followed_one)
 248       assert Enum.member?(res, followed_two)
 249       refute Enum.member?(res, not_followed)
 250     end
 251   end
 252
 253   describe "updating note and follower count" do
 254     test "it sets the info->note_count property" do
 255       note = insert(:note)
 256
 257       user = User.get_by_ap_id(note.data["actor"])
 258
 259       assert user.info["note_count"] == nil
 260
 261       {:ok, user} = User.update_note_count(user)
 262
 263       assert user.info["note_count"] == 1
 264     end
 265
 266     test "it increases the info->note_count property" do
 267       note = insert(:note)
 268       user = User.get_by_ap_id(note.data["actor"])
 269
 270       assert user.info["note_count"] == nil
 271
 272       {:ok, user} = User.increase_note_count(user)
 273
 274       assert user.info["note_count"] == 1
 275
 276       {:ok, user} = User.increase_note_count(user)
 277
 278       assert user.info["note_count"] == 2
 279     end
 280
 281     test "it sets the info->follower_count property" do
 282       user = insert(:user)
 283       follower = insert(:user)
 284
 285       User.follow(follower, user)
 286
 287       assert user.info["follower_count"] == nil
 288
 289       {:ok, user} = User.update_follower_count(user)
 290
 291       assert user.info["follower_count"] == 1
 292     end
 293   end
 294
 295   describe "blocks" do
 296     test "it blocks people" do
 297       user = insert(:user)
 298       blocked_user = insert(:user)
 299
 300       refute User.blocks?(user, blocked_user)
 301
 302       {:ok, user} = User.block(user, blocked_user)
 303
 304       assert User.blocks?(user, blocked_user)
 305     end
 306
 307     test "it unblocks users" do
 308       user = insert(:user)
 309       blocked_user = insert(:user)
 310
 311       {:ok, user} = User.block(user, blocked_user)
 312       {:ok, user} = User.unblock(user, blocked_user)
 313
 314       refute User.blocks?(user, blocked_user)
 315     end
 316   end
 317
 318   test "get recipients from activity" do
 319     actor = insert(:user)
 320     user = insert(:user, local: true)
 321     user_two = insert(:user, local: false)
 322     addressed = insert(:user, local: true)
 323     addressed_remote = insert(:user, local: false)
 324     {:ok, activity} = CommonAPI.post(actor, %{"status" => "hey @#{addressed.nickname} @#{addressed_remote.nickname}"})
 325
 326     assert [addressed] == User.get_recipients_from_activity(activity)
 327
 328     {:ok, user} = User.follow(user, actor)
 329     {:ok, user_two} = User.follow(user_two, actor)
 330     recipients = User.get_recipients_from_activity(activity)
 331     assert length(recipients) == 2
 332     assert user in recipients
 333     assert addressed in recipients
 334   end
 335
 336   test ".deactivate deactivates a user" do
 337     user = insert(:user)
 338     assert false == !!user.info["deactivated"]
 339     {:ok, user} = User.deactivate(user)
 340     assert true == user.info["deactivated"]
 341   end
 342
 343   test ".delete deactivates a user, all follow relationships and all create activities" do
 344     user = insert(:user)
 345     followed = insert(:user)
 346     follower = insert(:user)
 347
 348     {:ok, user} = User.follow(user, followed)
 349     {:ok, follower} = User.follow(follower, user)
 350
 351     {:ok, activity} = CommonAPI.post(user, %{"status" => "2hu"})
 352     {:ok, activity_two} = CommonAPI.post(follower, %{"status" => "3hu"})
 353
 354     {:ok, _, _} = CommonAPI.favorite(activity_two.id, user)
 355     {:ok, _, _} = CommonAPI.favorite(activity.id, follower)
 356     {:ok, _, _} = CommonAPI.repeat(activity.id, follower)
 357
 358     :ok = User.delete(user)
 359
 360     followed = Repo.get(User, followed.id)
 361     follower = Repo.get(User, follower.id)
 362     user = Repo.get(User, user.id)
 363
 364     assert user.info["deactivated"]
 365
 366     refute User.following?(user, followed)
 367     refute User.following?(followed, follower)
 368
 369     # TODO: Remove favorites, repeats, delete activities.
 370
 371     refute Repo.get(Activity, activity.id)
 372   end
 373
 374   test "get_public_key_for_ap_id fetches a user that's not in the db" do
 375     assert {:ok, _key} = User.get_public_key_for_ap_id("http://mastodon.example.org/users/admin")
 376   end
 377 end