git.squeep.com Git - akkoma/blob - test/tasks/user_test.exs

   1 defmodule Mix.Tasks.Pleroma.UserTest do
   2   alias Pleroma.User
   3   use Pleroma.DataCase
   4
   5   import Pleroma.Factory
   6   import ExUnit.CaptureIO
   7
   8   setup_all do
   9     Mix.shell(Mix.Shell.Process)
  10
  11     on_exit(fn ->
  12       Mix.shell(Mix.Shell.IO)
  13     end)
  14
  15     :ok
  16   end
  17
  18   describe "running new" do
  19     test "user is created" do
  20       # just get random data
  21       unsaved = build(:user)
  22
  23       # prepare to answer yes
  24       send(self(), {:mix_shell_input, :yes?, true})
  25
  26       Mix.Tasks.Pleroma.User.run([
  27         "new",
  28         unsaved.nickname,
  29         unsaved.email,
  30         "--name",
  31         unsaved.name,
  32         "--bio",
  33         unsaved.bio,
  34         "--password",
  35         "test",
  36         "--moderator",
  37         "--admin"
  38       ])
  39
  40       assert_received {:mix_shell, :info, [message]}
  41       assert message =~ "user will be created"
  42
  43       assert_received {:mix_shell, :yes?, [message]}
  44       assert message =~ "Continue"
  45
  46       assert_received {:mix_shell, :info, [message]}
  47       assert message =~ "created"
  48
  49       user = User.get_by_nickname(unsaved.nickname)
  50       assert user.name == unsaved.name
  51       assert user.email == unsaved.email
  52       assert user.bio == unsaved.bio
  53       assert user.info.is_moderator
  54       assert user.info.is_admin
  55     end
  56
  57     test "user is not created" do
  58       unsaved = build(:user)
  59
  60       # prepare to answer no
  61       send(self(), {:mix_shell_input, :yes?, false})
  62
  63       Mix.Tasks.Pleroma.User.run(["new", unsaved.nickname, unsaved.email])
  64
  65       assert_received {:mix_shell, :info, [message]}
  66       assert message =~ "user will be created"
  67
  68       assert_received {:mix_shell, :yes?, [message]}
  69       assert message =~ "Continue"
  70
  71       assert_received {:mix_shell, :info, [message]}
  72       assert message =~ "will not be created"
  73
  74       refute User.get_by_nickname(unsaved.nickname)
  75     end
  76   end
  77
  78   describe "running rm" do
  79     test "user is deleted" do
  80       user = insert(:user)
  81
  82       Mix.Tasks.Pleroma.User.run(["rm", user.nickname])
  83
  84       assert_received {:mix_shell, :info, [message]}
  85       assert message =~ " deleted"
  86
  87       user = User.get_by_nickname(user.nickname)
  88       assert user.info.deactivated
  89     end
  90
  91     test "no user to delete" do
  92       Mix.Tasks.Pleroma.User.run(["rm", "nonexistent"])
  93
  94       assert_received {:mix_shell, :error, [message]}
  95       assert message =~ "No local user"
  96     end
  97   end
  98
  99   describe "running toggle_activated" do
 100     test "user is deactivated" do
 101       user = insert(:user)
 102
 103       Mix.Tasks.Pleroma.User.run(["toggle_activated", user.nickname])
 104
 105       assert_received {:mix_shell, :info, [message]}
 106       assert message =~ " deactivated"
 107
 108       user = User.get_by_nickname(user.nickname)
 109       assert user.info.deactivated
 110     end
 111
 112     test "user is activated" do
 113       user = insert(:user, info: %{deactivated: true})
 114
 115       Mix.Tasks.Pleroma.User.run(["toggle_activated", user.nickname])
 116
 117       assert_received {:mix_shell, :info, [message]}
 118       assert message =~ " activated"
 119
 120       user = User.get_by_nickname(user.nickname)
 121       refute user.info.deactivated
 122     end
 123
 124     test "no user to toggle" do
 125       Mix.Tasks.Pleroma.User.run(["toggle_activated", "nonexistent"])
 126
 127       assert_received {:mix_shell, :error, [message]}
 128       assert message =~ "No user"
 129     end
 130   end
 131
 132   describe "running unsubscribe" do
 133     test "user is unsubscribed" do
 134       followed = insert(:user)
 135       user = insert(:user, %{following: [User.ap_followers(followed)]})
 136
 137       Mix.Tasks.Pleroma.User.run(["unsubscribe", user.nickname])
 138
 139       assert_received {:mix_shell, :info, [message]}
 140       assert message =~ "Deactivating"
 141
 142       assert_received {:mix_shell, :info, [message]}
 143       assert message =~ "Unsubscribing"
 144
 145       # Note that the task has delay :timer.sleep(500)
 146       assert_received {:mix_shell, :info, [message]}
 147       assert message =~ "Successfully unsubscribed"
 148
 149       user = User.get_by_nickname(user.nickname)
 150       assert length(user.following) == 0
 151       assert user.info.deactivated
 152     end
 153
 154     test "no user to unsubscribe" do
 155       Mix.Tasks.Pleroma.User.run(["unsubscribe", "nonexistent"])
 156
 157       assert_received {:mix_shell, :error, [message]}
 158       assert message =~ "No user"
 159     end
 160   end
 161
 162   describe "running set" do
 163     test "All statuses set" do
 164       user = insert(:user)
 165
 166       Mix.Tasks.Pleroma.User.run(["set", user.nickname, "--moderator", "--admin", "--locked"])
 167
 168       assert_received {:mix_shell, :info, [message]}
 169       assert message =~ ~r/Moderator status .* true/
 170
 171       assert_received {:mix_shell, :info, [message]}
 172       assert message =~ ~r/Locked status .* true/
 173
 174       assert_received {:mix_shell, :info, [message]}
 175       assert message =~ ~r/Admin status .* true/
 176
 177       user = User.get_by_nickname(user.nickname)
 178       assert user.info.is_moderator
 179       assert user.info.locked
 180       assert user.info.is_admin
 181     end
 182
 183     test "All statuses unset" do
 184       user = insert(:user, info: %{is_moderator: true, locked: true, is_admin: true})
 185
 186       Mix.Tasks.Pleroma.User.run([
 187         "set",
 188         user.nickname,
 189         "--no-moderator",
 190         "--no-admin",
 191         "--no-locked"
 192       ])
 193
 194       assert_received {:mix_shell, :info, [message]}
 195       assert message =~ ~r/Moderator status .* false/
 196
 197       assert_received {:mix_shell, :info, [message]}
 198       assert message =~ ~r/Locked status .* false/
 199
 200       assert_received {:mix_shell, :info, [message]}
 201       assert message =~ ~r/Admin status .* false/
 202
 203       user = User.get_by_nickname(user.nickname)
 204       refute user.info.is_moderator
 205       refute user.info.locked
 206       refute user.info.is_admin
 207     end
 208
 209     test "no user to set status" do
 210       Mix.Tasks.Pleroma.User.run(["set", "nonexistent", "--moderator"])
 211
 212       assert_received {:mix_shell, :error, [message]}
 213       assert message =~ "No local user"
 214     end
 215   end
 216
 217   describe "running reset_password" do
 218     test "password reset token is generated" do
 219       user = insert(:user)
 220
 221       assert capture_io(fn ->
 222                Mix.Tasks.Pleroma.User.run(["reset_password", user.nickname])
 223              end) =~ "URL:"
 224
 225       assert_received {:mix_shell, :info, [message]}
 226       assert message =~ "Generated"
 227     end
 228
 229     test "no user to reset password" do
 230       Mix.Tasks.Pleroma.User.run(["reset_password", "nonexistent"])
 231
 232       assert_received {:mix_shell, :error, [message]}
 233       assert message =~ "No local user"
 234     end
 235   end
 236
 237   describe "running invite" do
 238     test "invite token is generated" do
 239       assert capture_io(fn ->
 240                Mix.Tasks.Pleroma.User.run(["invite"])
 241              end) =~ "http"
 242
 243       assert_received {:mix_shell, :info, [message]}
 244       assert message =~ "Generated"
 245     end
 246   end
 247 end