git.squeep.com Git - akkoma/blob - test/tasks/user.exs

   1 defmodule Mix.Tasks.Pleroma.UserTest do
   2   alias Pleroma.User
   3   use Pleroma.DataCase
   4
   5   import Pleroma.Factory
   6   import ExUnit.CaptureIO
   7
   8   setup_all do
   9     Mix.shell(Mix.Shell.Process)
  10
  11     on_exit(fn ->
  12       Mix.shell(Mix.Shell.IO)
  13     end)
  14
  15     :ok
  16   end
  17
  18   describe "running new" do
  19     test "user is created" do
  20       # just get random data
  21       unsaved = build(:user)
  22
  23       # prepare to answer yes
  24       send(self(), {:mix_shell_input, :yes?, true})
  25
  26       Mix.Tasks.Pleroma.User.run([
  27         "new",
  28         unsaved.nickname,
  29         unsaved.email,
  30         "--name",
  31         unsaved.name,
  32         "--bio",
  33         unsaved.bio,
  34         "--password",
  35         "test",
  36         "--moderator",
  37         "--admin"
  38       ])
  39
  40       assert_received {:mix_shell, :info, [message]}
  41       assert message =~ "user will be created"
  42       assert_received {:mix_shell, :yes?, [message]}
  43       assert message =~ "Continue"
  44       assert_received {:mix_shell, :info, [message]}
  45       assert message =~ "created"
  46
  47       user = User.get_by_nickname(unsaved.nickname)
  48       assert user.name == unsaved.name
  49       assert user.email == unsaved.email
  50       assert user.bio == unsaved.bio
  51       assert user.info.is_moderator
  52       assert user.info.is_admin
  53     end
  54
  55     test "user is not created" do
  56       unsaved = build(:user)
  57
  58       # prepare to answer no
  59       send(self(), {:mix_shell_input, :yes?, false})
  60       Mix.Tasks.Pleroma.User.run(["new", unsaved.nickname, unsaved.email])
  61       assert_received {:mix_shell, :info, [message]}
  62       assert message =~ "user will be created"
  63       assert_received {:mix_shell, :yes?, [message]}
  64       assert message =~ "Continue"
  65       assert_received {:mix_shell, :info, [message]}
  66       assert message =~ "will not be created"
  67
  68       refute User.get_by_nickname(unsaved.nickname)
  69     end
  70   end
  71
  72   describe "running rm" do
  73     test "user is deleted" do
  74       user = insert(:user)
  75
  76       Mix.Tasks.Pleroma.User.run(["rm", user.nickname])
  77       assert_received {:mix_shell, :info, [message]}
  78       assert message =~ " deleted"
  79
  80       user = User.get_by_nickname(user.nickname)
  81       assert user.info.deactivated
  82     end
  83
  84     test "no user to delete" do
  85       Mix.Tasks.Pleroma.User.run(["rm", "nonexistant"])
  86       assert_received {:mix_shell, :error, [message]}
  87       assert message =~ "No local user"
  88     end
  89   end
  90
  91   describe "running toggle_activated" do
  92     test "user is deactivated" do
  93       user = insert(:user)
  94
  95       Mix.Tasks.Pleroma.User.run(["toggle_activated", user.nickname])
  96       assert_received {:mix_shell, :info, [message]}
  97       assert message =~ " deactivated"
  98
  99       user = User.get_by_nickname(user.nickname)
 100       assert user.info.deactivated
 101     end
 102
 103     test "user is activated" do
 104       user = insert(:user, info: %{deactivated: true})
 105
 106       Mix.Tasks.Pleroma.User.run(["toggle_activated", user.nickname])
 107       assert_received {:mix_shell, :info, [message]}
 108       assert message =~ " activated"
 109
 110       user = User.get_by_nickname(user.nickname)
 111       refute user.info.deactivated
 112     end
 113
 114     test "no user to toggle" do
 115       Mix.Tasks.Pleroma.User.run(["toggle_activated", "nonexistant"])
 116       assert_received {:mix_shell, :error, [message]}
 117       assert message =~ "No user"
 118     end
 119   end
 120
 121   describe "running unsubscribe" do
 122     test "user is unsubscribed" do
 123       followed = insert(:user)
 124       user = insert(:user, %{following: [User.ap_followers(followed)]})
 125
 126       Mix.Tasks.Pleroma.User.run(["unsubscribe", user.nickname])
 127       assert_received {:mix_shell, :info, [message]}
 128       assert message =~ "Deactivating"
 129       assert_received {:mix_shell, :info, [message]}
 130       assert message =~ "Unsubscribing"
 131       # Note that the task has delay :timer.sleep(500)
 132       assert_received {:mix_shell, :info, [message]}
 133       assert message =~ "Successfully unsubscribed"
 134
 135       user = User.get_by_nickname(user.nickname)
 136       assert length(user.following) == 0
 137       assert user.info.deactivated
 138     end
 139
 140     test "no user to unsubscribe" do
 141       Mix.Tasks.Pleroma.User.run(["unsubscribe", "nonexistant"])
 142       assert_received {:mix_shell, :error, [message]}
 143       assert message =~ "No user"
 144     end
 145   end
 146
 147   describe "running set" do
 148     test "All statuses set" do
 149       user = insert(:user)
 150
 151       Mix.Tasks.Pleroma.User.run(["set", user.nickname, "--moderator", "--admin", "--locked"])
 152       assert_received {:mix_shell, :info, [message]}
 153       assert message =~ ~r"Moderator status .* true"
 154       assert_received {:mix_shell, :info, [message]}
 155       assert message =~ ~r"Locked status .* true"
 156       assert_received {:mix_shell, :info, [message]}
 157       assert message =~ ~r"Admin status .* true"
 158
 159       user = User.get_by_nickname(user.nickname)
 160       assert user.info.is_moderator
 161       assert user.info.locked
 162       assert user.info.is_admin
 163     end
 164
 165     test "All statuses unset" do
 166       user = insert(:user, info: %{is_moderator: true, locked: true, is_admin: true})
 167
 168       Mix.Tasks.Pleroma.User.run([
 169         "set",
 170         user.nickname,
 171         "--no-moderator",
 172         "--no-admin",
 173         "--no-locked"
 174       ])
 175
 176       assert_received {:mix_shell, :info, [message]}
 177       assert message =~ ~r"Moderator status .* false"
 178       assert_received {:mix_shell, :info, [message]}
 179       assert message =~ ~r"Locked status .* false"
 180       assert_received {:mix_shell, :info, [message]}
 181       assert message =~ ~r"Admin status .* false"
 182
 183       user = User.get_by_nickname(user.nickname)
 184       refute user.info.is_moderator
 185       refute user.info.locked
 186       refute user.info.is_admin
 187     end
 188
 189     test "no user to set status" do
 190       Mix.Tasks.Pleroma.User.run(["set", "nonexistant", "--moderator"])
 191       assert_received {:mix_shell, :error, [message]}
 192       assert message =~ "No local user"
 193     end
 194   end
 195
 196   describe "running reset_password" do
 197     test "password reset token is generated" do
 198       user = insert(:user)
 199
 200       assert capture_io(fn ->
 201                Mix.Tasks.Pleroma.User.run(["reset_password", user.nickname])
 202              end) =~ "URL:"
 203
 204       assert_received {:mix_shell, :info, [message]}
 205       assert message =~ "Generated"
 206     end
 207
 208     test "no user to reset password" do
 209       Mix.Tasks.Pleroma.User.run(["reset_password", "nonexistant"])
 210       assert_received {:mix_shell, :error, [message]}
 211       assert message =~ "No local user"
 212     end
 213   end
 214
 215   describe "running invite" do
 216     test "invite token is generated" do
 217       assert capture_io(fn ->
 218                Mix.Tasks.Pleroma.User.run(["invite"])
 219              end) =~ "http"
 220
 221       assert_received {:mix_shell, :info, [message]}
 222       assert message =~ "Generated"
 223     end
 224   end
 225 end