git.squeep.com Git - akkoma/blob - test/tasks/relay_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.RelayTest do
   6   alias Pleroma.Activity
   7   alias Pleroma.Web.ActivityPub.{ActivityPub, Relay, Utils}
   8   alias Pleroma.User
   9   use Pleroma.DataCase
  10
  11   setup_all do
  12     Tesla.Mock.mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  13
  14     Mix.shell(Mix.Shell.Process)
  15
  16     on_exit(fn ->
  17       Mix.shell(Mix.Shell.IO)
  18     end)
  19
  20     :ok
  21   end
  22
  23   describe "running follow" do
  24     test "relay is followed" do
  25       target_instance = "http://mastodon.example.org/users/admin"
  26
  27       Mix.Tasks.Pleroma.Relay.run(["follow", target_instance])
  28
  29       local_user = Relay.get_actor()
  30       assert local_user.ap_id =~ "/relay"
  31
  32       target_user = User.get_by_ap_id(target_instance)
  33       refute target_user.local
  34
  35       activity = Utils.fetch_latest_follow(local_user, target_user)
  36       assert activity.data["type"] == "Follow"
  37       assert activity.data["actor"] == local_user.ap_id
  38       assert activity.data["object"] == target_user.ap_id
  39     end
  40   end
  41
  42   describe "running unfollow" do
  43     test "relay is unfollowed" do
  44       target_instance = "http://mastodon.example.org/users/admin"
  45
  46       Mix.Tasks.Pleroma.Relay.run(["follow", target_instance])
  47
  48       %User{ap_id: follower_id} = local_user = Relay.get_actor()
  49       target_user = User.get_by_ap_id(target_instance)
  50       follow_activity = Utils.fetch_latest_follow(local_user, target_user)
  51
  52       Mix.Tasks.Pleroma.Relay.run(["unfollow", target_instance])
  53
  54       cancelled_activity = Activity.get_by_ap_id(follow_activity.data["id"])
  55       assert cancelled_activity.data["state"] == "cancelled"
  56
  57       [undo_activity] =
  58         ActivityPub.fetch_activities([], %{
  59           "type" => "Undo",
  60           "actor_id" => follower_id,
  61           "limit" => 1
  62         })
  63
  64       assert undo_activity.data["type"] == "Undo"
  65       assert undo_activity.data["actor"] == local_user.ap_id
  66       assert undo_activity.data["object"] == cancelled_activity.data
  67     end
  68   end
  69 end