git.squeep.com Git - akkoma/blob - test/tasks/database_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Mix.Tasks.Pleroma.DatabaseTest do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI
  11
  12   use Pleroma.DataCase
  13
  14   import Pleroma.Factory
  15
  16   setup_all do
  17     Mix.shell(Mix.Shell.Process)
  18
  19     on_exit(fn ->
  20       Mix.shell(Mix.Shell.IO)
  21     end)
  22
  23     :ok
  24   end
  25
  26   describe "running remove_embedded_objects" do
  27     test "it replaces objects with references" do
  28       user = insert(:user)
  29       {:ok, activity} = CommonAPI.post(user, %{"status" => "test"})
  30       new_data = Map.put(activity.data, "object", activity.object.data)
  31
  32       {:ok, activity} =
  33         activity
  34         |> Activity.change(%{data: new_data})
  35         |> Repo.update()
  36
  37       assert is_map(activity.data["object"])
  38
  39       Mix.Tasks.Pleroma.Database.run(["remove_embedded_objects"])
  40
  41       activity = Activity.get_by_id_with_object(activity.id)
  42       assert is_binary(activity.data["object"])
  43     end
  44   end
  45
  46   describe "prune_objects" do
  47     test "it prunes old objects from the database" do
  48       insert(:note)
  49       deadline = Pleroma.Config.get([:instance, :remote_post_retention_days]) + 1
  50
  51       date =
  52         Timex.now()
  53         |> Timex.shift(days: -deadline)
  54         |> Timex.to_naive_datetime()
  55         |> NaiveDateTime.truncate(:second)
  56
  57       %{id: id} =
  58         :note
  59         |> insert()
  60         |> Ecto.Changeset.change(%{inserted_at: date})
  61         |> Repo.update!()
  62
  63       assert length(Repo.all(Object)) == 2
  64
  65       Mix.Tasks.Pleroma.Database.run(["prune_objects"])
  66
  67       assert length(Repo.all(Object)) == 1
  68       refute Object.get_by_id(id)
  69     end
  70   end
  71
  72   describe "running update_users_following_followers_counts" do
  73     test "following and followers count are updated" do
  74       [user, user2] = insert_pair(:user)
  75       {:ok, %User{following: following, info: info} = user} = User.follow(user, user2)
  76
  77       assert length(following) == 2
  78       assert info.follower_count == 0
  79
  80       info_cng = Ecto.Changeset.change(info, %{follower_count: 3})
  81
  82       {:ok, user} =
  83         user
  84         |> Ecto.Changeset.change(%{following: following ++ following})
  85         |> Ecto.Changeset.put_embed(:info, info_cng)
  86         |> Repo.update()
  87
  88       assert length(user.following) == 4
  89       assert user.info.follower_count == 3
  90
  91       assert :ok == Mix.Tasks.Pleroma.Database.run(["update_users_following_followers_counts"])
  92
  93       user = User.get_by_id(user.id)
  94
  95       assert length(user.following) == 2
  96       assert user.info.follower_count == 0
  97     end
  98   end
  99
 100   describe "running fix_likes_collections" do
 101     test "it turns OrderedCollection likes into empty arrays" do
 102       [user, user2] = insert_pair(:user)
 103
 104       {:ok, %{id: id, object: object}} = CommonAPI.post(user, %{"status" => "test"})
 105       {:ok, %{object: object2}} = CommonAPI.post(user, %{"status" => "test test"})
 106
 107       CommonAPI.favorite(id, user2)
 108
 109       likes = %{
 110         "first" =>
 111           "http://mastodon.example.org/objects/dbdbc507-52c8-490d-9b7c-1e1d52e5c132/likes?page=1",
 112         "id" => "http://mastodon.example.org/objects/dbdbc507-52c8-490d-9b7c-1e1d52e5c132/likes",
 113         "totalItems" => 3,
 114         "type" => "OrderedCollection"
 115       }
 116
 117       new_data = Map.put(object2.data, "likes", likes)
 118
 119       object2
 120       |> Ecto.Changeset.change(%{data: new_data})
 121       |> Repo.update()
 122
 123       assert length(Object.get_by_id(object.id).data["likes"]) == 1
 124       assert is_map(Object.get_by_id(object2.id).data["likes"])
 125
 126       assert :ok == Mix.Tasks.Pleroma.Database.run(["fix_likes_collections"])
 127
 128       assert length(Object.get_by_id(object.id).data["likes"]) == 1
 129       assert Enum.empty?(Object.get_by_id(object2.id).data["likes"])
 130     end
 131   end
 132 end