git.squeep.com Git - akkoma/blob - test/support/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Tests.Helpers do
   6   @moduledoc """
   7   Helpers for use in tests.
   8   """
   9   alias Pleroma.Config
  10
  11   defmacro clear_config(config_path) do
  12     quote do
  13       clear_config(unquote(config_path)) do
  14       end
  15     end
  16   end
  17
  18   defmacro clear_config(config_path, do: yield) do
  19     quote do
  20       initial_setting = Config.get(unquote(config_path))
  21       unquote(yield)
  22       on_exit(fn -> Config.put(unquote(config_path), initial_setting) end)
  23       :ok
  24     end
  25   end
  26
  27   defmacro clear_config(config_path, temp_setting) do
  28     quote do
  29       clear_config(unquote(config_path)) do
  30         Config.put(unquote(config_path), unquote(temp_setting))
  31       end
  32     end
  33   end
  34
  35   defmacro __using__(_opts) do
  36     quote do
  37       import Pleroma.Tests.Helpers,
  38         only: [
  39           clear_config: 1,
  40           clear_config: 2
  41         ]
  42
  43       def to_datetime(%NaiveDateTime{} = naive_datetime) do
  44         naive_datetime
  45         |> DateTime.from_naive!("Etc/UTC")
  46         |> DateTime.truncate(:second)
  47       end
  48
  49       def to_datetime(datetime) when is_binary(datetime) do
  50         datetime
  51         |> NaiveDateTime.from_iso8601!()
  52         |> to_datetime()
  53       end
  54
  55       def collect_ids(collection) do
  56         collection
  57         |> Enum.map(& &1.id)
  58         |> Enum.sort()
  59       end
  60
  61       def refresh_record(%{id: id, __struct__: model} = _),
  62         do: refresh_record(model, %{id: id})
  63
  64       def refresh_record(model, %{id: id} = _) do
  65         Pleroma.Repo.get_by(model, id: id)
  66       end
  67
  68       # Used for comparing json rendering during tests.
  69       def render_json(view, template, assigns) do
  70         assigns = Map.new(assigns)
  71
  72         view.render(template, assigns)
  73         |> Poison.encode!()
  74         |> Poison.decode!()
  75       end
  76
  77       def stringify_keys(nil), do: nil
  78
  79       def stringify_keys(key) when key in [true, false], do: key
  80       def stringify_keys(key) when is_atom(key), do: Atom.to_string(key)
  81
  82       def stringify_keys(map) when is_map(map) do
  83         map
  84         |> Enum.map(fn {k, v} -> {stringify_keys(k), stringify_keys(v)} end)
  85         |> Enum.into(%{})
  86       end
  87
  88       def stringify_keys([head | rest] = list) when is_list(list) do
  89         [stringify_keys(head) | stringify_keys(rest)]
  90       end
  91
  92       def stringify_keys(key), do: key
  93
  94       defmacro guards_config(config_path) do
  95         quote do
  96           initial_setting = Config.get(config_path)
  97
  98           Config.put(config_path, true)
  99           on_exit(fn -> Config.put(config_path, initial_setting) end)
 100         end
 101       end
 102     end
 103   end
 104 end