git.squeep.com Git - akkoma/blob - test/support/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Tests.Helpers do
   6   @moduledoc """
   7   Helpers for use in tests.
   8   """
   9   alias Pleroma.Config
  10
  11   require Logger
  12
  13   defmacro clear_config(config_path) do
  14     quote do
  15       clear_config(unquote(config_path)) do
  16       end
  17     end
  18   end
  19
  20   defmacro clear_config(config_path, do: yield) do
  21     quote do
  22       initial_setting = Config.fetch(unquote(config_path))
  23
  24       unquote(yield)
  25
  26       on_exit(fn ->
  27         case initial_setting do
  28           :error ->
  29             Config.delete(unquote(config_path))
  30
  31           {:ok, value} ->
  32             Config.put(unquote(config_path), value)
  33         end
  34       end)
  35
  36       :ok
  37     end
  38   end
  39
  40   defmacro clear_config(config_path, temp_setting) do
  41     # NOTE: `clear_config([section, key], value)` != `clear_config([section], key: value)` (!)
  42     # Displaying a warning to prevent unintentional clearing of all but one keys in section
  43     if Keyword.keyword?(temp_setting) and length(temp_setting) == 1 do
  44       Logger.warn(
  45         "Please change to `clear_config([section]); clear_config([section, key], value)`: " <>
  46           "#{inspect(config_path)}, #{inspect(temp_setting)}"
  47       )
  48     end
  49
  50     quote do
  51       clear_config(unquote(config_path)) do
  52         Config.put(unquote(config_path), unquote(temp_setting))
  53       end
  54     end
  55   end
  56
  57   def require_migration(migration_name) do
  58     [{module, _}] = Code.require_file("#{migration_name}.exs", "priv/repo/migrations")
  59     {:ok, %{migration: module}}
  60   end
  61
  62   defmacro __using__(_opts) do
  63     quote do
  64       import Pleroma.Tests.Helpers,
  65         only: [
  66           clear_config: 1,
  67           clear_config: 2
  68         ]
  69
  70       def time_travel(entity, seconds) do
  71         new_time = NaiveDateTime.add(entity.inserted_at, seconds)
  72
  73         entity
  74         |> Ecto.Changeset.change(%{inserted_at: new_time, updated_at: new_time})
  75         |> Pleroma.Repo.update()
  76       end
  77
  78       def to_datetime(%NaiveDateTime{} = naive_datetime) do
  79         naive_datetime
  80         |> DateTime.from_naive!("Etc/UTC")
  81         |> DateTime.truncate(:second)
  82       end
  83
  84       def to_datetime(datetime) when is_binary(datetime) do
  85         datetime
  86         |> NaiveDateTime.from_iso8601!()
  87         |> to_datetime()
  88       end
  89
  90       def collect_ids(collection) do
  91         collection
  92         |> Enum.map(& &1.id)
  93         |> Enum.sort()
  94       end
  95
  96       def refresh_record(%{id: id, __struct__: model} = _),
  97         do: refresh_record(model, %{id: id})
  98
  99       def refresh_record(model, %{id: id} = _) do
 100         Pleroma.Repo.get_by(model, id: id)
 101       end
 102
 103       # Used for comparing json rendering during tests.
 104       def render_json(view, template, assigns) do
 105         assigns = Map.new(assigns)
 106
 107         view.render(template, assigns)
 108         |> Jason.encode!()
 109         |> Jason.decode!()
 110       end
 111
 112       def stringify_keys(nil), do: nil
 113
 114       def stringify_keys(key) when key in [true, false], do: key
 115       def stringify_keys(key) when is_atom(key), do: Atom.to_string(key)
 116
 117       def stringify_keys(map) when is_map(map) do
 118         map
 119         |> Enum.map(fn {k, v} -> {stringify_keys(k), stringify_keys(v)} end)
 120         |> Enum.into(%{})
 121       end
 122
 123       def stringify_keys([head | rest] = list) when is_list(list) do
 124         [stringify_keys(head) | stringify_keys(rest)]
 125       end
 126
 127       def stringify_keys(key), do: key
 128
 129       defmacro guards_config(config_path) do
 130         quote do
 131           initial_setting = Config.get(config_path)
 132
 133           Config.put(config_path, true)
 134           on_exit(fn -> Config.put(config_path, initial_setting) end)
 135         end
 136       end
 137     end
 138   end
 139 end