git.squeep.com Git - akkoma/blob - test/pleroma/web/streamer_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StreamerTest do
   6   use Pleroma.DataCase
   7
   8   import Pleroma.Factory
   9
  10   alias Pleroma.Chat
  11   alias Pleroma.Chat.MessageReference
  12   alias Pleroma.Conversation.Participation
  13   alias Pleroma.List
  14   alias Pleroma.Object
  15   alias Pleroma.User
  16   alias Pleroma.Web.CommonAPI
  17   alias Pleroma.Web.Streamer
  18   alias Pleroma.Web.StreamerView
  19
  20   @moduletag needs_streamer: true, capture_log: true
  21
  22   setup do: clear_config([:instance, :skip_thread_containment])
  23
  24   describe "get_topic/_ (unauthenticated)" do
  25     test "allows public" do
  26       assert {:ok, "public"} = Streamer.get_topic("public", nil, nil)
  27       assert {:ok, "public:local"} = Streamer.get_topic("public:local", nil, nil)
  28       assert {:ok, "public:media"} = Streamer.get_topic("public:media", nil, nil)
  29       assert {:ok, "public:local:media"} = Streamer.get_topic("public:local:media", nil, nil)
  30     end
  31
  32     test "allows instance streams" do
  33       assert {:ok, "public:remote:lain.com"} =
  34                Streamer.get_topic("public:remote", nil, nil, %{"instance" => "lain.com"})
  35
  36       assert {:ok, "public:remote:media:lain.com"} =
  37                Streamer.get_topic("public:remote:media", nil, nil, %{"instance" => "lain.com"})
  38     end
  39
  40     test "allows hashtag streams" do
  41       assert {:ok, "hashtag:cofe"} = Streamer.get_topic("hashtag", nil, nil, %{"tag" => "cofe"})
  42     end
  43
  44     test "disallows user streams" do
  45       assert {:error, _} = Streamer.get_topic("user", nil, nil)
  46       assert {:error, _} = Streamer.get_topic("user:notification", nil, nil)
  47       assert {:error, _} = Streamer.get_topic("direct", nil, nil)
  48     end
  49
  50     test "disallows list streams" do
  51       assert {:error, _} = Streamer.get_topic("list", nil, nil, %{"list" => 42})
  52     end
  53   end
  54
  55   describe "get_topic/_ (authenticated)" do
  56     setup do: oauth_access(["read"])
  57
  58     test "allows public streams (regardless of OAuth token scopes)", %{
  59       user: user,
  60       token: read_oauth_token
  61     } do
  62       with oauth_token <- [nil, read_oauth_token] do
  63         assert {:ok, "public"} = Streamer.get_topic("public", user, oauth_token)
  64         assert {:ok, "public:local"} = Streamer.get_topic("public:local", user, oauth_token)
  65         assert {:ok, "public:media"} = Streamer.get_topic("public:media", user, oauth_token)
  66
  67         assert {:ok, "public:local:media"} =
  68                  Streamer.get_topic("public:local:media", user, oauth_token)
  69       end
  70     end
  71
  72     test "allows user streams (with proper OAuth token scopes)", %{
  73       user: user,
  74       token: read_oauth_token
  75     } do
  76       %{token: read_notifications_token} = oauth_access(["read:notifications"], user: user)
  77       %{token: read_statuses_token} = oauth_access(["read:statuses"], user: user)
  78       %{token: badly_scoped_token} = oauth_access(["irrelevant:scope"], user: user)
  79
  80       expected_user_topic = "user:#{user.id}"
  81       expected_notification_topic = "user:notification:#{user.id}"
  82       expected_direct_topic = "direct:#{user.id}"
  83       expected_pleroma_chat_topic = "user:pleroma_chat:#{user.id}"
  84
  85       for valid_user_token <- [read_oauth_token, read_statuses_token] do
  86         assert {:ok, ^expected_user_topic} = Streamer.get_topic("user", user, valid_user_token)
  87
  88         assert {:ok, ^expected_direct_topic} =
  89                  Streamer.get_topic("direct", user, valid_user_token)
  90
  91         assert {:ok, ^expected_pleroma_chat_topic} =
  92                  Streamer.get_topic("user:pleroma_chat", user, valid_user_token)
  93       end
  94
  95       for invalid_user_token <- [read_notifications_token, badly_scoped_token],
  96           user_topic <- ["user", "direct", "user:pleroma_chat"] do
  97         assert {:error, :unauthorized} = Streamer.get_topic(user_topic, user, invalid_user_token)
  98       end
  99
 100       for valid_notification_token <- [read_oauth_token, read_notifications_token] do
 101         assert {:ok, ^expected_notification_topic} =
 102                  Streamer.get_topic("user:notification", user, valid_notification_token)
 103       end
 104
 105       for invalid_notification_token <- [read_statuses_token, badly_scoped_token] do
 106         assert {:error, :unauthorized} =
 107                  Streamer.get_topic("user:notification", user, invalid_notification_token)
 108       end
 109     end
 110
 111     test "allows hashtag streams (regardless of OAuth token scopes)", %{
 112       user: user,
 113       token: read_oauth_token
 114     } do
 115       for oauth_token <- [nil, read_oauth_token] do
 116         assert {:ok, "hashtag:cofe"} =
 117                  Streamer.get_topic("hashtag", user, oauth_token, %{"tag" => "cofe"})
 118       end
 119     end
 120
 121     test "disallows registering to another user's stream", %{user: user, token: read_oauth_token} do
 122       another_user = insert(:user)
 123       assert {:error, _} = Streamer.get_topic("user:#{another_user.id}", user, read_oauth_token)
 124
 125       assert {:error, _} =
 126                Streamer.get_topic("user:notification:#{another_user.id}", user, read_oauth_token)
 127
 128       assert {:error, _} = Streamer.get_topic("direct:#{another_user.id}", user, read_oauth_token)
 129     end
 130
 131     test "allows list stream that are owned by the user (with `read` or `read:lists` scopes)", %{
 132       user: user,
 133       token: read_oauth_token
 134     } do
 135       %{token: read_lists_token} = oauth_access(["read:lists"], user: user)
 136       %{token: invalid_token} = oauth_access(["irrelevant:scope"], user: user)
 137       {:ok, list} = List.create("Test", user)
 138
 139       assert {:error, _} = Streamer.get_topic("list:#{list.id}", user, read_oauth_token)
 140
 141       for valid_token <- [read_oauth_token, read_lists_token] do
 142         assert {:ok, _} = Streamer.get_topic("list", user, valid_token, %{"list" => list.id})
 143       end
 144
 145       assert {:error, _} = Streamer.get_topic("list", user, invalid_token, %{"list" => list.id})
 146     end
 147
 148     test "disallows list stream that are not owned by the user", %{user: user, token: oauth_token} do
 149       another_user = insert(:user)
 150       {:ok, list} = List.create("Test", another_user)
 151
 152       assert {:error, _} = Streamer.get_topic("list:#{list.id}", user, oauth_token)
 153       assert {:error, _} = Streamer.get_topic("list", user, oauth_token, %{"list" => list.id})
 154     end
 155   end
 156
 157   describe "user streams" do
 158     setup do
 159       %{user: user, token: token} = oauth_access(["read"])
 160       notify = insert(:notification, user: user, activity: build(:note_activity))
 161       {:ok, %{user: user, notify: notify, token: token}}
 162     end
 163
 164     test "it streams the user's post in the 'user' stream", %{user: user, token: oauth_token} do
 165       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 166       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 167
 168       assert_receive {:render_with_user, _, _, ^activity}
 169       refute Streamer.filtered_by_user?(user, activity)
 170     end
 171
 172     test "it streams boosts of the user in the 'user' stream", %{user: user, token: oauth_token} do
 173       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 174
 175       other_user = insert(:user)
 176       {:ok, activity} = CommonAPI.post(other_user, %{status: "hey"})
 177       {:ok, announce} = CommonAPI.repeat(activity.id, user)
 178
 179       assert_receive {:render_with_user, Pleroma.Web.StreamerView, "update.json", ^announce}
 180       refute Streamer.filtered_by_user?(user, announce)
 181     end
 182
 183     test "it does not stream announces of the user's own posts in the 'user' stream", %{
 184       user: user,
 185       token: oauth_token
 186     } do
 187       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 188
 189       other_user = insert(:user)
 190       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 191       {:ok, announce} = CommonAPI.repeat(activity.id, other_user)
 192
 193       assert Streamer.filtered_by_user?(user, announce)
 194     end
 195
 196     test "it does stream notifications announces of the user's own posts in the 'user' stream", %{
 197       user: user,
 198       token: oauth_token
 199     } do
 200       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 201
 202       other_user = insert(:user)
 203       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 204       {:ok, announce} = CommonAPI.repeat(activity.id, other_user)
 205
 206       notification =
 207         Pleroma.Notification
 208         |> Repo.get_by(%{user_id: user.id, activity_id: announce.id})
 209         |> Repo.preload(:activity)
 210
 211       refute Streamer.filtered_by_user?(user, notification)
 212     end
 213
 214     test "it streams boosts of mastodon user in the 'user' stream", %{
 215       user: user,
 216       token: oauth_token
 217     } do
 218       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 219
 220       other_user = insert(:user)
 221       {:ok, activity} = CommonAPI.post(other_user, %{status: "hey"})
 222
 223       data =
 224         File.read!("test/fixtures/mastodon-announce.json")
 225         |> Poison.decode!()
 226         |> Map.put("object", activity.data["object"])
 227         |> Map.put("actor", user.ap_id)
 228
 229       {:ok, %Pleroma.Activity{data: _data, local: false} = announce} =
 230         Pleroma.Web.ActivityPub.Transmogrifier.handle_incoming(data)
 231
 232       assert_receive {:render_with_user, Pleroma.Web.StreamerView, "update.json", ^announce}
 233       refute Streamer.filtered_by_user?(user, announce)
 234     end
 235
 236     test "it sends notify to in the 'user' stream", %{
 237       user: user,
 238       token: oauth_token,
 239       notify: notify
 240     } do
 241       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 242       Streamer.stream("user", notify)
 243
 244       assert_receive {:render_with_user, _, _, ^notify}
 245       refute Streamer.filtered_by_user?(user, notify)
 246     end
 247
 248     test "it sends notify to in the 'user:notification' stream", %{
 249       user: user,
 250       token: oauth_token,
 251       notify: notify
 252     } do
 253       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 254       Streamer.stream("user:notification", notify)
 255
 256       assert_receive {:render_with_user, _, _, ^notify}
 257       refute Streamer.filtered_by_user?(user, notify)
 258     end
 259
 260     test "it sends chat messages to the 'user:pleroma_chat' stream", %{
 261       user: user,
 262       token: oauth_token
 263     } do
 264       other_user = insert(:user)
 265
 266       {:ok, create_activity} =
 267         CommonAPI.post_chat_message(other_user, user, "hey cirno", idempotency_key: "123")
 268
 269       object = Object.normalize(create_activity, false)
 270       chat = Chat.get(user.id, other_user.ap_id)
 271       cm_ref = MessageReference.for_chat_and_object(chat, object)
 272       cm_ref = %{cm_ref | chat: chat, object: object}
 273
 274       Streamer.get_topic_and_add_socket("user:pleroma_chat", user, oauth_token)
 275       Streamer.stream("user:pleroma_chat", {user, cm_ref})
 276
 277       text = StreamerView.render("chat_update.json", %{chat_message_reference: cm_ref})
 278
 279       assert text =~ "hey cirno"
 280       assert_receive {:text, ^text}
 281     end
 282
 283     test "it sends chat messages to the 'user' stream", %{user: user, token: oauth_token} do
 284       other_user = insert(:user)
 285
 286       {:ok, create_activity} = CommonAPI.post_chat_message(other_user, user, "hey cirno")
 287       object = Object.normalize(create_activity, false)
 288       chat = Chat.get(user.id, other_user.ap_id)
 289       cm_ref = MessageReference.for_chat_and_object(chat, object)
 290       cm_ref = %{cm_ref | chat: chat, object: object}
 291
 292       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 293       Streamer.stream("user", {user, cm_ref})
 294
 295       text = StreamerView.render("chat_update.json", %{chat_message_reference: cm_ref})
 296
 297       assert text =~ "hey cirno"
 298       assert_receive {:text, ^text}
 299     end
 300
 301     test "it sends chat message notifications to the 'user:notification' stream", %{
 302       user: user,
 303       token: oauth_token
 304     } do
 305       other_user = insert(:user)
 306
 307       {:ok, create_activity} = CommonAPI.post_chat_message(other_user, user, "hey")
 308
 309       notify =
 310         Repo.get_by(Pleroma.Notification, user_id: user.id, activity_id: create_activity.id)
 311         |> Repo.preload(:activity)
 312
 313       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 314       Streamer.stream("user:notification", notify)
 315
 316       assert_receive {:render_with_user, _, _, ^notify}
 317       refute Streamer.filtered_by_user?(user, notify)
 318     end
 319
 320     test "it doesn't send notify to the 'user:notification' stream when a user is blocked", %{
 321       user: user,
 322       token: oauth_token
 323     } do
 324       blocked = insert(:user)
 325       {:ok, _user_relationship} = User.block(user, blocked)
 326
 327       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 328
 329       {:ok, activity} = CommonAPI.post(user, %{status: ":("})
 330       {:ok, _} = CommonAPI.favorite(blocked, activity.id)
 331
 332       refute_receive _
 333     end
 334
 335     test "it doesn't send notify to the 'user:notification' stream when a thread is muted", %{
 336       user: user,
 337       token: oauth_token
 338     } do
 339       user2 = insert(:user)
 340
 341       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 342       {:ok, _} = CommonAPI.add_mute(user, activity)
 343
 344       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 345
 346       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 347
 348       refute_receive _
 349       assert Streamer.filtered_by_user?(user, favorite_activity)
 350     end
 351
 352     test "it sends favorite to 'user:notification' stream'", %{
 353       user: user,
 354       token: oauth_token
 355     } do
 356       user2 = insert(:user, %{ap_id: "https://hecking-lewd-place.com/user/meanie"})
 357
 358       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 359       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 360       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 361
 362       assert_receive {:render_with_user, _, "notification.json", notif}
 363       assert notif.activity.id == favorite_activity.id
 364       refute Streamer.filtered_by_user?(user, notif)
 365     end
 366
 367     test "it doesn't send the 'user:notification' stream' when a domain is blocked", %{
 368       user: user,
 369       token: oauth_token
 370     } do
 371       user2 = insert(:user, %{ap_id: "https://hecking-lewd-place.com/user/meanie"})
 372
 373       {:ok, user} = User.block_domain(user, "hecking-lewd-place.com")
 374       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 375       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 376       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 377
 378       refute_receive _
 379       assert Streamer.filtered_by_user?(user, favorite_activity)
 380     end
 381
 382     test "it sends follow activities to the 'user:notification' stream", %{
 383       user: user,
 384       token: oauth_token
 385     } do
 386       user_url = user.ap_id
 387       user2 = insert(:user)
 388
 389       body =
 390         File.read!("test/fixtures/users_mock/localhost.json")
 391         |> String.replace("{{nickname}}", user.nickname)
 392         |> Jason.encode!()
 393
 394       Tesla.Mock.mock_global(fn
 395         %{method: :get, url: ^user_url} ->
 396           %Tesla.Env{status: 200, body: body}
 397       end)
 398
 399       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 400       {:ok, _follower, _followed, follow_activity} = CommonAPI.follow(user2, user)
 401
 402       assert_receive {:render_with_user, _, "notification.json", notif}
 403       assert notif.activity.id == follow_activity.id
 404       refute Streamer.filtered_by_user?(user, notif)
 405     end
 406   end
 407
 408   describe "public streams" do
 409     test "it sends to public (authenticated)" do
 410       %{user: user, token: oauth_token} = oauth_access(["read"])
 411       other_user = insert(:user)
 412
 413       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 414
 415       {:ok, activity} = CommonAPI.post(other_user, %{status: "Test"})
 416       assert_receive {:render_with_user, _, _, ^activity}
 417       refute Streamer.filtered_by_user?(other_user, activity)
 418     end
 419
 420     test "it sends to public (unauthenticated)" do
 421       user = insert(:user)
 422
 423       Streamer.get_topic_and_add_socket("public", nil, nil)
 424
 425       {:ok, activity} = CommonAPI.post(user, %{status: "Test"})
 426       activity_id = activity.id
 427       assert_receive {:text, event}
 428       assert %{"event" => "update", "payload" => payload} = Jason.decode!(event)
 429       assert %{"id" => ^activity_id} = Jason.decode!(payload)
 430
 431       {:ok, _} = CommonAPI.delete(activity.id, user)
 432       assert_receive {:text, event}
 433       assert %{"event" => "delete", "payload" => ^activity_id} = Jason.decode!(event)
 434     end
 435
 436     test "handles deletions" do
 437       %{user: user, token: oauth_token} = oauth_access(["read"])
 438       other_user = insert(:user)
 439       {:ok, activity} = CommonAPI.post(other_user, %{status: "Test"})
 440
 441       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 442
 443       {:ok, _} = CommonAPI.delete(activity.id, other_user)
 444       activity_id = activity.id
 445       assert_receive {:text, event}
 446       assert %{"event" => "delete", "payload" => ^activity_id} = Jason.decode!(event)
 447     end
 448   end
 449
 450   describe "thread_containment/2" do
 451     test "it filters to user if recipients invalid and thread containment is enabled" do
 452       Pleroma.Config.put([:instance, :skip_thread_containment], false)
 453       author = insert(:user)
 454       %{user: user, token: oauth_token} = oauth_access(["read"])
 455       User.follow(user, author, :follow_accept)
 456
 457       activity =
 458         insert(:note_activity,
 459           note:
 460             insert(:note,
 461               user: author,
 462               data: %{"to" => ["TEST-FFF"]}
 463             )
 464         )
 465
 466       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 467       Streamer.stream("public", activity)
 468       assert_receive {:render_with_user, _, _, ^activity}
 469       assert Streamer.filtered_by_user?(user, activity)
 470     end
 471
 472     test "it sends message if recipients invalid and thread containment is disabled" do
 473       Pleroma.Config.put([:instance, :skip_thread_containment], true)
 474       author = insert(:user)
 475       %{user: user, token: oauth_token} = oauth_access(["read"])
 476       User.follow(user, author, :follow_accept)
 477
 478       activity =
 479         insert(:note_activity,
 480           note:
 481             insert(:note,
 482               user: author,
 483               data: %{"to" => ["TEST-FFF"]}
 484             )
 485         )
 486
 487       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 488       Streamer.stream("public", activity)
 489
 490       assert_receive {:render_with_user, _, _, ^activity}
 491       refute Streamer.filtered_by_user?(user, activity)
 492     end
 493
 494     test "it sends message if recipients invalid and thread containment is enabled but user's thread containment is disabled" do
 495       Pleroma.Config.put([:instance, :skip_thread_containment], false)
 496       author = insert(:user)
 497       user = insert(:user, skip_thread_containment: true)
 498       %{token: oauth_token} = oauth_access(["read"], user: user)
 499       User.follow(user, author, :follow_accept)
 500
 501       activity =
 502         insert(:note_activity,
 503           note:
 504             insert(:note,
 505               user: author,
 506               data: %{"to" => ["TEST-FFF"]}
 507             )
 508         )
 509
 510       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 511       Streamer.stream("public", activity)
 512
 513       assert_receive {:render_with_user, _, _, ^activity}
 514       refute Streamer.filtered_by_user?(user, activity)
 515     end
 516   end
 517
 518   describe "blocks" do
 519     setup do: oauth_access(["read"])
 520
 521     test "it filters messages involving blocked users", %{user: user, token: oauth_token} do
 522       blocked_user = insert(:user)
 523       {:ok, _user_relationship} = User.block(user, blocked_user)
 524
 525       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 526       {:ok, activity} = CommonAPI.post(blocked_user, %{status: "Test"})
 527       assert_receive {:render_with_user, _, _, ^activity}
 528       assert Streamer.filtered_by_user?(user, activity)
 529     end
 530
 531     test "it filters messages transitively involving blocked users", %{
 532       user: blocker,
 533       token: blocker_token
 534     } do
 535       blockee = insert(:user)
 536       friend = insert(:user)
 537
 538       Streamer.get_topic_and_add_socket("public", blocker, blocker_token)
 539
 540       {:ok, _user_relationship} = User.block(blocker, blockee)
 541
 542       {:ok, activity_one} = CommonAPI.post(friend, %{status: "hey! @#{blockee.nickname}"})
 543
 544       assert_receive {:render_with_user, _, _, ^activity_one}
 545       assert Streamer.filtered_by_user?(blocker, activity_one)
 546
 547       {:ok, activity_two} = CommonAPI.post(blockee, %{status: "hey! @#{friend.nickname}"})
 548
 549       assert_receive {:render_with_user, _, _, ^activity_two}
 550       assert Streamer.filtered_by_user?(blocker, activity_two)
 551
 552       {:ok, activity_three} = CommonAPI.post(blockee, %{status: "hey! @#{blocker.nickname}"})
 553
 554       assert_receive {:render_with_user, _, _, ^activity_three}
 555       assert Streamer.filtered_by_user?(blocker, activity_three)
 556     end
 557   end
 558
 559   describe "lists" do
 560     setup do: oauth_access(["read"])
 561
 562     test "it doesn't send unwanted DMs to list", %{user: user_a, token: user_a_token} do
 563       user_b = insert(:user)
 564       user_c = insert(:user)
 565
 566       {:ok, user_a} = User.follow(user_a, user_b)
 567
 568       {:ok, list} = List.create("Test", user_a)
 569       {:ok, list} = List.follow(list, user_b)
 570
 571       Streamer.get_topic_and_add_socket("list", user_a, user_a_token, %{"list" => list.id})
 572
 573       {:ok, _activity} =
 574         CommonAPI.post(user_b, %{
 575           status: "@#{user_c.nickname} Test",
 576           visibility: "direct"
 577         })
 578
 579       refute_receive _
 580     end
 581
 582     test "it doesn't send unwanted private posts to list", %{user: user_a, token: user_a_token} do
 583       user_b = insert(:user)
 584
 585       {:ok, list} = List.create("Test", user_a)
 586       {:ok, list} = List.follow(list, user_b)
 587
 588       Streamer.get_topic_and_add_socket("list", user_a, user_a_token, %{"list" => list.id})
 589
 590       {:ok, _activity} =
 591         CommonAPI.post(user_b, %{
 592           status: "Test",
 593           visibility: "private"
 594         })
 595
 596       refute_receive _
 597     end
 598
 599     test "it sends wanted private posts to list", %{user: user_a, token: user_a_token} do
 600       user_b = insert(:user)
 601
 602       {:ok, user_a} = User.follow(user_a, user_b)
 603
 604       {:ok, list} = List.create("Test", user_a)
 605       {:ok, list} = List.follow(list, user_b)
 606
 607       Streamer.get_topic_and_add_socket("list", user_a, user_a_token, %{"list" => list.id})
 608
 609       {:ok, activity} =
 610         CommonAPI.post(user_b, %{
 611           status: "Test",
 612           visibility: "private"
 613         })
 614
 615       assert_receive {:render_with_user, _, _, ^activity}
 616       refute Streamer.filtered_by_user?(user_a, activity)
 617     end
 618   end
 619
 620   describe "muted reblogs" do
 621     setup do: oauth_access(["read"])
 622
 623     test "it filters muted reblogs", %{user: user1, token: user1_token} do
 624       user2 = insert(:user)
 625       user3 = insert(:user)
 626       CommonAPI.follow(user1, user2)
 627       CommonAPI.hide_reblogs(user1, user2)
 628
 629       {:ok, create_activity} = CommonAPI.post(user3, %{status: "I'm kawen"})
 630
 631       Streamer.get_topic_and_add_socket("user", user1, user1_token)
 632       {:ok, announce_activity} = CommonAPI.repeat(create_activity.id, user2)
 633       assert_receive {:render_with_user, _, _, ^announce_activity}
 634       assert Streamer.filtered_by_user?(user1, announce_activity)
 635     end
 636
 637     test "it filters reblog notification for reblog-muted actors", %{
 638       user: user1,
 639       token: user1_token
 640     } do
 641       user2 = insert(:user)
 642       CommonAPI.follow(user1, user2)
 643       CommonAPI.hide_reblogs(user1, user2)
 644
 645       {:ok, create_activity} = CommonAPI.post(user1, %{status: "I'm kawen"})
 646       Streamer.get_topic_and_add_socket("user", user1, user1_token)
 647       {:ok, _announce_activity} = CommonAPI.repeat(create_activity.id, user2)
 648
 649       assert_receive {:render_with_user, _, "notification.json", notif}
 650       assert Streamer.filtered_by_user?(user1, notif)
 651     end
 652
 653     test "it send non-reblog notification for reblog-muted actors", %{
 654       user: user1,
 655       token: user1_token
 656     } do
 657       user2 = insert(:user)
 658       CommonAPI.follow(user1, user2)
 659       CommonAPI.hide_reblogs(user1, user2)
 660
 661       {:ok, create_activity} = CommonAPI.post(user1, %{status: "I'm kawen"})
 662       Streamer.get_topic_and_add_socket("user", user1, user1_token)
 663       {:ok, _favorite_activity} = CommonAPI.favorite(user2, create_activity.id)
 664
 665       assert_receive {:render_with_user, _, "notification.json", notif}
 666       refute Streamer.filtered_by_user?(user1, notif)
 667     end
 668   end
 669
 670   describe "muted threads" do
 671     test "it filters posts from muted threads" do
 672       user = insert(:user)
 673       %{user: user2, token: user2_token} = oauth_access(["read"])
 674       Streamer.get_topic_and_add_socket("user", user2, user2_token)
 675
 676       {:ok, user2, user, _activity} = CommonAPI.follow(user2, user)
 677       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 678       {:ok, _} = CommonAPI.add_mute(user2, activity)
 679
 680       assert_receive {:render_with_user, _, _, ^activity}
 681       assert Streamer.filtered_by_user?(user2, activity)
 682     end
 683   end
 684
 685   describe "direct streams" do
 686     setup do: oauth_access(["read"])
 687
 688     test "it sends conversation update to the 'direct' stream", %{user: user, token: oauth_token} do
 689       another_user = insert(:user)
 690
 691       Streamer.get_topic_and_add_socket("direct", user, oauth_token)
 692
 693       {:ok, _create_activity} =
 694         CommonAPI.post(another_user, %{
 695           status: "hey @#{user.nickname}",
 696           visibility: "direct"
 697         })
 698
 699       assert_receive {:text, received_event}
 700
 701       assert %{"event" => "conversation", "payload" => received_payload} =
 702                Jason.decode!(received_event)
 703
 704       assert %{"last_status" => last_status} = Jason.decode!(received_payload)
 705       [participation] = Participation.for_user(user)
 706       assert last_status["pleroma"]["direct_conversation_id"] == participation.id
 707     end
 708
 709     test "it doesn't send conversation update to the 'direct' stream when the last message in the conversation is deleted",
 710          %{user: user, token: oauth_token} do
 711       another_user = insert(:user)
 712
 713       Streamer.get_topic_and_add_socket("direct", user, oauth_token)
 714
 715       {:ok, create_activity} =
 716         CommonAPI.post(another_user, %{
 717           status: "hi @#{user.nickname}",
 718           visibility: "direct"
 719         })
 720
 721       create_activity_id = create_activity.id
 722       assert_receive {:render_with_user, _, _, ^create_activity}
 723       assert_receive {:text, received_conversation1}
 724       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 725
 726       {:ok, _} = CommonAPI.delete(create_activity_id, another_user)
 727
 728       assert_receive {:text, received_event}
 729
 730       assert %{"event" => "delete", "payload" => ^create_activity_id} =
 731                Jason.decode!(received_event)
 732
 733       refute_receive _
 734     end
 735
 736     test "it sends conversation update to the 'direct' stream when a message is deleted", %{
 737       user: user,
 738       token: oauth_token
 739     } do
 740       another_user = insert(:user)
 741       Streamer.get_topic_and_add_socket("direct", user, oauth_token)
 742
 743       {:ok, create_activity} =
 744         CommonAPI.post(another_user, %{
 745           status: "hi @#{user.nickname}",
 746           visibility: "direct"
 747         })
 748
 749       {:ok, create_activity2} =
 750         CommonAPI.post(another_user, %{
 751           status: "hi @#{user.nickname} 2",
 752           in_reply_to_status_id: create_activity.id,
 753           visibility: "direct"
 754         })
 755
 756       assert_receive {:render_with_user, _, _, ^create_activity}
 757       assert_receive {:render_with_user, _, _, ^create_activity2}
 758       assert_receive {:text, received_conversation1}
 759       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 760       assert_receive {:text, received_conversation1}
 761       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 762
 763       {:ok, _} = CommonAPI.delete(create_activity2.id, another_user)
 764
 765       assert_receive {:text, received_event}
 766       assert %{"event" => "delete", "payload" => _} = Jason.decode!(received_event)
 767
 768       assert_receive {:text, received_event}
 769
 770       assert %{"event" => "conversation", "payload" => received_payload} =
 771                Jason.decode!(received_event)
 772
 773       assert %{"last_status" => last_status} = Jason.decode!(received_payload)
 774       assert last_status["id"] == to_string(create_activity.id)
 775     end
 776   end
 777 end