git.squeep.com Git - akkoma/blob - test/pleroma/web/streamer_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StreamerTest do
   6   use Pleroma.DataCase
   7
   8   import Pleroma.Factory
   9
  10   alias Pleroma.Chat
  11   alias Pleroma.Chat.MessageReference
  12   alias Pleroma.Conversation.Participation
  13   alias Pleroma.List
  14   alias Pleroma.Object
  15   alias Pleroma.User
  16   alias Pleroma.Web.CommonAPI
  17   alias Pleroma.Web.Streamer
  18   alias Pleroma.Web.StreamerView
  19
  20   @moduletag needs_streamer: true, capture_log: true
  21
  22   setup do: clear_config([:instance, :skip_thread_containment])
  23
  24   describe "get_topic/_ (unauthenticated)" do
  25     test "allows public" do
  26       assert {:ok, "public"} = Streamer.get_topic("public", nil, nil)
  27       assert {:ok, "public:local"} = Streamer.get_topic("public:local", nil, nil)
  28       assert {:ok, "public:media"} = Streamer.get_topic("public:media", nil, nil)
  29       assert {:ok, "public:local:media"} = Streamer.get_topic("public:local:media", nil, nil)
  30     end
  31
  32     test "allows instance streams" do
  33       assert {:ok, "public:remote:lain.com"} =
  34                Streamer.get_topic("public:remote", nil, nil, %{"instance" => "lain.com"})
  35
  36       assert {:ok, "public:remote:media:lain.com"} =
  37                Streamer.get_topic("public:remote:media", nil, nil, %{"instance" => "lain.com"})
  38     end
  39
  40     test "allows hashtag streams" do
  41       assert {:ok, "hashtag:cofe"} = Streamer.get_topic("hashtag", nil, nil, %{"tag" => "cofe"})
  42     end
  43
  44     test "disallows user streams" do
  45       assert {:error, _} = Streamer.get_topic("user", nil, nil)
  46       assert {:error, _} = Streamer.get_topic("user:notification", nil, nil)
  47       assert {:error, _} = Streamer.get_topic("direct", nil, nil)
  48     end
  49
  50     test "disallows list streams" do
  51       assert {:error, _} = Streamer.get_topic("list", nil, nil, %{"list" => 42})
  52     end
  53   end
  54
  55   describe "get_topic/_ (authenticated)" do
  56     setup do: oauth_access(["read"])
  57
  58     test "allows public streams (regardless of OAuth token scopes)", %{
  59       user: user,
  60       token: read_oauth_token
  61     } do
  62       with oauth_token <- [nil, read_oauth_token] do
  63         assert {:ok, "public"} = Streamer.get_topic("public", user, oauth_token)
  64         assert {:ok, "public:local"} = Streamer.get_topic("public:local", user, oauth_token)
  65         assert {:ok, "public:media"} = Streamer.get_topic("public:media", user, oauth_token)
  66
  67         assert {:ok, "public:local:media"} =
  68                  Streamer.get_topic("public:local:media", user, oauth_token)
  69       end
  70     end
  71
  72     test "allows user streams (with proper OAuth token scopes)", %{
  73       user: user,
  74       token: read_oauth_token
  75     } do
  76       %{token: read_notifications_token} = oauth_access(["read:notifications"], user: user)
  77       %{token: read_statuses_token} = oauth_access(["read:statuses"], user: user)
  78       %{token: badly_scoped_token} = oauth_access(["irrelevant:scope"], user: user)
  79
  80       expected_user_topic = "user:#{user.id}"
  81       expected_notification_topic = "user:notification:#{user.id}"
  82       expected_direct_topic = "direct:#{user.id}"
  83       expected_pleroma_chat_topic = "user:pleroma_chat:#{user.id}"
  84
  85       for valid_user_token <- [read_oauth_token, read_statuses_token] do
  86         assert {:ok, ^expected_user_topic} = Streamer.get_topic("user", user, valid_user_token)
  87
  88         assert {:ok, ^expected_direct_topic} =
  89                  Streamer.get_topic("direct", user, valid_user_token)
  90
  91         assert {:ok, ^expected_pleroma_chat_topic} =
  92                  Streamer.get_topic("user:pleroma_chat", user, valid_user_token)
  93       end
  94
  95       for invalid_user_token <- [read_notifications_token, badly_scoped_token],
  96           user_topic <- ["user", "direct", "user:pleroma_chat"] do
  97         assert {:error, :unauthorized} = Streamer.get_topic(user_topic, user, invalid_user_token)
  98       end
  99
 100       for valid_notification_token <- [read_oauth_token, read_notifications_token] do
 101         assert {:ok, ^expected_notification_topic} =
 102                  Streamer.get_topic("user:notification", user, valid_notification_token)
 103       end
 104
 105       for invalid_notification_token <- [read_statuses_token, badly_scoped_token] do
 106         assert {:error, :unauthorized} =
 107                  Streamer.get_topic("user:notification", user, invalid_notification_token)
 108       end
 109     end
 110
 111     test "allows hashtag streams (regardless of OAuth token scopes)", %{
 112       user: user,
 113       token: read_oauth_token
 114     } do
 115       for oauth_token <- [nil, read_oauth_token] do
 116         assert {:ok, "hashtag:cofe"} =
 117                  Streamer.get_topic("hashtag", user, oauth_token, %{"tag" => "cofe"})
 118       end
 119     end
 120
 121     test "disallows registering to another user's stream", %{user: user, token: read_oauth_token} do
 122       another_user = insert(:user)
 123       assert {:error, _} = Streamer.get_topic("user:#{another_user.id}", user, read_oauth_token)
 124
 125       assert {:error, _} =
 126                Streamer.get_topic("user:notification:#{another_user.id}", user, read_oauth_token)
 127
 128       assert {:error, _} = Streamer.get_topic("direct:#{another_user.id}", user, read_oauth_token)
 129     end
 130
 131     test "allows list stream that are owned by the user (with `read` or `read:lists` scopes)", %{
 132       user: user,
 133       token: read_oauth_token
 134     } do
 135       %{token: read_lists_token} = oauth_access(["read:lists"], user: user)
 136       %{token: invalid_token} = oauth_access(["irrelevant:scope"], user: user)
 137       {:ok, list} = List.create("Test", user)
 138
 139       assert {:error, _} = Streamer.get_topic("list:#{list.id}", user, read_oauth_token)
 140
 141       for valid_token <- [read_oauth_token, read_lists_token] do
 142         assert {:ok, _} = Streamer.get_topic("list", user, valid_token, %{"list" => list.id})
 143       end
 144
 145       assert {:error, _} = Streamer.get_topic("list", user, invalid_token, %{"list" => list.id})
 146     end
 147
 148     test "disallows list stream that are not owned by the user", %{user: user, token: oauth_token} do
 149       another_user = insert(:user)
 150       {:ok, list} = List.create("Test", another_user)
 151
 152       assert {:error, _} = Streamer.get_topic("list:#{list.id}", user, oauth_token)
 153       assert {:error, _} = Streamer.get_topic("list", user, oauth_token, %{"list" => list.id})
 154     end
 155   end
 156
 157   describe "user streams" do
 158     setup do
 159       %{user: user, token: token} = oauth_access(["read"])
 160       notify = insert(:notification, user: user, activity: build(:note_activity))
 161       {:ok, %{user: user, notify: notify, token: token}}
 162     end
 163
 164     test "it streams the user's post in the 'user' stream", %{user: user, token: oauth_token} do
 165       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 166       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 167
 168       assert_receive {:render_with_user, _, _, ^activity}
 169       refute Streamer.filtered_by_user?(user, activity)
 170     end
 171
 172     test "it streams boosts of the user in the 'user' stream", %{user: user, token: oauth_token} do
 173       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 174
 175       other_user = insert(:user)
 176       {:ok, activity} = CommonAPI.post(other_user, %{status: "hey"})
 177       {:ok, announce} = CommonAPI.repeat(activity.id, user)
 178
 179       assert_receive {:render_with_user, Pleroma.Web.StreamerView, "update.json", ^announce}
 180       refute Streamer.filtered_by_user?(user, announce)
 181     end
 182
 183     test "it does not stream announces of the user's own posts in the 'user' stream", %{
 184       user: user,
 185       token: oauth_token
 186     } do
 187       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 188
 189       other_user = insert(:user)
 190       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 191       {:ok, announce} = CommonAPI.repeat(activity.id, other_user)
 192
 193       assert Streamer.filtered_by_user?(user, announce)
 194     end
 195
 196     test "it does stream notifications announces of the user's own posts in the 'user' stream", %{
 197       user: user,
 198       token: oauth_token
 199     } do
 200       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 201
 202       other_user = insert(:user)
 203       {:ok, activity} = CommonAPI.post(user, %{status: "hey"})
 204       {:ok, announce} = CommonAPI.repeat(activity.id, other_user)
 205
 206       notification =
 207         Pleroma.Notification
 208         |> Repo.get_by(%{user_id: user.id, activity_id: announce.id})
 209         |> Repo.preload(:activity)
 210
 211       refute Streamer.filtered_by_user?(user, notification)
 212     end
 213
 214     test "it streams boosts of mastodon user in the 'user' stream", %{
 215       user: user,
 216       token: oauth_token
 217     } do
 218       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 219
 220       other_user = insert(:user)
 221       {:ok, activity} = CommonAPI.post(other_user, %{status: "hey"})
 222
 223       data =
 224         File.read!("test/fixtures/mastodon-announce.json")
 225         |> Poison.decode!()
 226         |> Map.put("object", activity.data["object"])
 227         |> Map.put("actor", user.ap_id)
 228
 229       {:ok, %Pleroma.Activity{data: _data, local: false} = announce} =
 230         Pleroma.Web.ActivityPub.Transmogrifier.handle_incoming(data)
 231
 232       assert_receive {:render_with_user, Pleroma.Web.StreamerView, "update.json", ^announce}
 233       refute Streamer.filtered_by_user?(user, announce)
 234     end
 235
 236     test "it sends notify to in the 'user' stream", %{
 237       user: user,
 238       token: oauth_token,
 239       notify: notify
 240     } do
 241       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 242       Streamer.stream("user", notify)
 243
 244       assert_receive {:render_with_user, _, _, ^notify}
 245       refute Streamer.filtered_by_user?(user, notify)
 246     end
 247
 248     test "it sends notify to in the 'user:notification' stream", %{
 249       user: user,
 250       token: oauth_token,
 251       notify: notify
 252     } do
 253       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 254       Streamer.stream("user:notification", notify)
 255
 256       assert_receive {:render_with_user, _, _, ^notify}
 257       refute Streamer.filtered_by_user?(user, notify)
 258     end
 259
 260     test "it sends chat messages to the 'user:pleroma_chat' stream", %{
 261       user: user,
 262       token: oauth_token
 263     } do
 264       other_user = insert(:user)
 265
 266       {:ok, create_activity} = CommonAPI.post_chat_message(other_user, user, "hey cirno")
 267       object = Object.normalize(create_activity, false)
 268       chat = Chat.get(user.id, other_user.ap_id)
 269       cm_ref = MessageReference.for_chat_and_object(chat, object)
 270       cm_ref = %{cm_ref | chat: chat, object: object}
 271
 272       Streamer.get_topic_and_add_socket("user:pleroma_chat", user, oauth_token)
 273       Streamer.stream("user:pleroma_chat", {user, cm_ref})
 274
 275       text = StreamerView.render("chat_update.json", %{chat_message_reference: cm_ref})
 276
 277       assert text =~ "hey cirno"
 278       assert_receive {:text, ^text}
 279     end
 280
 281     test "it sends chat messages to the 'user' stream", %{user: user, token: oauth_token} do
 282       other_user = insert(:user)
 283
 284       {:ok, create_activity} = CommonAPI.post_chat_message(other_user, user, "hey cirno")
 285       object = Object.normalize(create_activity, false)
 286       chat = Chat.get(user.id, other_user.ap_id)
 287       cm_ref = MessageReference.for_chat_and_object(chat, object)
 288       cm_ref = %{cm_ref | chat: chat, object: object}
 289
 290       Streamer.get_topic_and_add_socket("user", user, oauth_token)
 291       Streamer.stream("user", {user, cm_ref})
 292
 293       text = StreamerView.render("chat_update.json", %{chat_message_reference: cm_ref})
 294
 295       assert text =~ "hey cirno"
 296       assert_receive {:text, ^text}
 297     end
 298
 299     test "it sends chat message notifications to the 'user:notification' stream", %{
 300       user: user,
 301       token: oauth_token
 302     } do
 303       other_user = insert(:user)
 304
 305       {:ok, create_activity} = CommonAPI.post_chat_message(other_user, user, "hey")
 306
 307       notify =
 308         Repo.get_by(Pleroma.Notification, user_id: user.id, activity_id: create_activity.id)
 309         |> Repo.preload(:activity)
 310
 311       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 312       Streamer.stream("user:notification", notify)
 313
 314       assert_receive {:render_with_user, _, _, ^notify}
 315       refute Streamer.filtered_by_user?(user, notify)
 316     end
 317
 318     test "it doesn't send notify to the 'user:notification' stream when a user is blocked", %{
 319       user: user,
 320       token: oauth_token
 321     } do
 322       blocked = insert(:user)
 323       {:ok, _user_relationship} = User.block(user, blocked)
 324
 325       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 326
 327       {:ok, activity} = CommonAPI.post(user, %{status: ":("})
 328       {:ok, _} = CommonAPI.favorite(blocked, activity.id)
 329
 330       refute_receive _
 331     end
 332
 333     test "it doesn't send notify to the 'user:notification' stream when a thread is muted", %{
 334       user: user,
 335       token: oauth_token
 336     } do
 337       user2 = insert(:user)
 338
 339       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 340       {:ok, _} = CommonAPI.add_mute(user, activity)
 341
 342       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 343
 344       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 345
 346       refute_receive _
 347       assert Streamer.filtered_by_user?(user, favorite_activity)
 348     end
 349
 350     test "it sends favorite to 'user:notification' stream'", %{
 351       user: user,
 352       token: oauth_token
 353     } do
 354       user2 = insert(:user, %{ap_id: "https://hecking-lewd-place.com/user/meanie"})
 355
 356       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 357       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 358       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 359
 360       assert_receive {:render_with_user, _, "notification.json", notif}
 361       assert notif.activity.id == favorite_activity.id
 362       refute Streamer.filtered_by_user?(user, notif)
 363     end
 364
 365     test "it doesn't send the 'user:notification' stream' when a domain is blocked", %{
 366       user: user,
 367       token: oauth_token
 368     } do
 369       user2 = insert(:user, %{ap_id: "https://hecking-lewd-place.com/user/meanie"})
 370
 371       {:ok, user} = User.block_domain(user, "hecking-lewd-place.com")
 372       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 373       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 374       {:ok, favorite_activity} = CommonAPI.favorite(user2, activity.id)
 375
 376       refute_receive _
 377       assert Streamer.filtered_by_user?(user, favorite_activity)
 378     end
 379
 380     test "it sends follow activities to the 'user:notification' stream", %{
 381       user: user,
 382       token: oauth_token
 383     } do
 384       user_url = user.ap_id
 385       user2 = insert(:user)
 386
 387       body =
 388         File.read!("test/fixtures/users_mock/localhost.json")
 389         |> String.replace("{{nickname}}", user.nickname)
 390         |> Jason.encode!()
 391
 392       Tesla.Mock.mock_global(fn
 393         %{method: :get, url: ^user_url} ->
 394           %Tesla.Env{status: 200, body: body}
 395       end)
 396
 397       Streamer.get_topic_and_add_socket("user:notification", user, oauth_token)
 398       {:ok, _follower, _followed, follow_activity} = CommonAPI.follow(user2, user)
 399
 400       assert_receive {:render_with_user, _, "notification.json", notif}
 401       assert notif.activity.id == follow_activity.id
 402       refute Streamer.filtered_by_user?(user, notif)
 403     end
 404   end
 405
 406   describe "public streams" do
 407     test "it sends to public (authenticated)" do
 408       %{user: user, token: oauth_token} = oauth_access(["read"])
 409       other_user = insert(:user)
 410
 411       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 412
 413       {:ok, activity} = CommonAPI.post(other_user, %{status: "Test"})
 414       assert_receive {:render_with_user, _, _, ^activity}
 415       refute Streamer.filtered_by_user?(other_user, activity)
 416     end
 417
 418     test "it sends to public (unauthenticated)" do
 419       user = insert(:user)
 420
 421       Streamer.get_topic_and_add_socket("public", nil, nil)
 422
 423       {:ok, activity} = CommonAPI.post(user, %{status: "Test"})
 424       activity_id = activity.id
 425       assert_receive {:text, event}
 426       assert %{"event" => "update", "payload" => payload} = Jason.decode!(event)
 427       assert %{"id" => ^activity_id} = Jason.decode!(payload)
 428
 429       {:ok, _} = CommonAPI.delete(activity.id, user)
 430       assert_receive {:text, event}
 431       assert %{"event" => "delete", "payload" => ^activity_id} = Jason.decode!(event)
 432     end
 433
 434     test "handles deletions" do
 435       %{user: user, token: oauth_token} = oauth_access(["read"])
 436       other_user = insert(:user)
 437       {:ok, activity} = CommonAPI.post(other_user, %{status: "Test"})
 438
 439       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 440
 441       {:ok, _} = CommonAPI.delete(activity.id, other_user)
 442       activity_id = activity.id
 443       assert_receive {:text, event}
 444       assert %{"event" => "delete", "payload" => ^activity_id} = Jason.decode!(event)
 445     end
 446   end
 447
 448   describe "thread_containment/2" do
 449     test "it filters to user if recipients invalid and thread containment is enabled" do
 450       Pleroma.Config.put([:instance, :skip_thread_containment], false)
 451       author = insert(:user)
 452       %{user: user, token: oauth_token} = oauth_access(["read"])
 453       User.follow(user, author, :follow_accept)
 454
 455       activity =
 456         insert(:note_activity,
 457           note:
 458             insert(:note,
 459               user: author,
 460               data: %{"to" => ["TEST-FFF"]}
 461             )
 462         )
 463
 464       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 465       Streamer.stream("public", activity)
 466       assert_receive {:render_with_user, _, _, ^activity}
 467       assert Streamer.filtered_by_user?(user, activity)
 468     end
 469
 470     test "it sends message if recipients invalid and thread containment is disabled" do
 471       Pleroma.Config.put([:instance, :skip_thread_containment], true)
 472       author = insert(:user)
 473       %{user: user, token: oauth_token} = oauth_access(["read"])
 474       User.follow(user, author, :follow_accept)
 475
 476       activity =
 477         insert(:note_activity,
 478           note:
 479             insert(:note,
 480               user: author,
 481               data: %{"to" => ["TEST-FFF"]}
 482             )
 483         )
 484
 485       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 486       Streamer.stream("public", activity)
 487
 488       assert_receive {:render_with_user, _, _, ^activity}
 489       refute Streamer.filtered_by_user?(user, activity)
 490     end
 491
 492     test "it sends message if recipients invalid and thread containment is enabled but user's thread containment is disabled" do
 493       Pleroma.Config.put([:instance, :skip_thread_containment], false)
 494       author = insert(:user)
 495       user = insert(:user, skip_thread_containment: true)
 496       %{token: oauth_token} = oauth_access(["read"], user: user)
 497       User.follow(user, author, :follow_accept)
 498
 499       activity =
 500         insert(:note_activity,
 501           note:
 502             insert(:note,
 503               user: author,
 504               data: %{"to" => ["TEST-FFF"]}
 505             )
 506         )
 507
 508       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 509       Streamer.stream("public", activity)
 510
 511       assert_receive {:render_with_user, _, _, ^activity}
 512       refute Streamer.filtered_by_user?(user, activity)
 513     end
 514   end
 515
 516   describe "blocks" do
 517     setup do: oauth_access(["read"])
 518
 519     test "it filters messages involving blocked users", %{user: user, token: oauth_token} do
 520       blocked_user = insert(:user)
 521       {:ok, _user_relationship} = User.block(user, blocked_user)
 522
 523       Streamer.get_topic_and_add_socket("public", user, oauth_token)
 524       {:ok, activity} = CommonAPI.post(blocked_user, %{status: "Test"})
 525       assert_receive {:render_with_user, _, _, ^activity}
 526       assert Streamer.filtered_by_user?(user, activity)
 527     end
 528
 529     test "it filters messages transitively involving blocked users", %{
 530       user: blocker,
 531       token: blocker_token
 532     } do
 533       blockee = insert(:user)
 534       friend = insert(:user)
 535
 536       Streamer.get_topic_and_add_socket("public", blocker, blocker_token)
 537
 538       {:ok, _user_relationship} = User.block(blocker, blockee)
 539
 540       {:ok, activity_one} = CommonAPI.post(friend, %{status: "hey! @#{blockee.nickname}"})
 541
 542       assert_receive {:render_with_user, _, _, ^activity_one}
 543       assert Streamer.filtered_by_user?(blocker, activity_one)
 544
 545       {:ok, activity_two} = CommonAPI.post(blockee, %{status: "hey! @#{friend.nickname}"})
 546
 547       assert_receive {:render_with_user, _, _, ^activity_two}
 548       assert Streamer.filtered_by_user?(blocker, activity_two)
 549
 550       {:ok, activity_three} = CommonAPI.post(blockee, %{status: "hey! @#{blocker.nickname}"})
 551
 552       assert_receive {:render_with_user, _, _, ^activity_three}
 553       assert Streamer.filtered_by_user?(blocker, activity_three)
 554     end
 555   end
 556
 557   describe "lists" do
 558     setup do: oauth_access(["read"])
 559
 560     test "it doesn't send unwanted DMs to list", %{user: user_a, token: user_a_token} do
 561       user_b = insert(:user)
 562       user_c = insert(:user)
 563
 564       {:ok, user_a} = User.follow(user_a, user_b)
 565
 566       {:ok, list} = List.create("Test", user_a)
 567       {:ok, list} = List.follow(list, user_b)
 568
 569       Streamer.get_topic_and_add_socket("list", user_a, user_a_token, %{"list" => list.id})
 570
 571       {:ok, _activity} =
 572         CommonAPI.post(user_b, %{
 573           status: "@#{user_c.nickname} Test",
 574           visibility: "direct"
 575         })
 576
 577       refute_receive _
 578     end
 579
 580     test "it doesn't send unwanted private posts to list", %{user: user_a, token: user_a_token} do
 581       user_b = insert(:user)
 582
 583       {:ok, list} = List.create("Test", user_a)
 584       {:ok, list} = List.follow(list, user_b)
 585
 586       Streamer.get_topic_and_add_socket("list", user_a, user_a_token, %{"list" => list.id})
 587
 588       {:ok, _activity} =
 589         CommonAPI.post(user_b, %{
 590           status: "Test",
 591           visibility: "private"
 592         })
 593
 594       refute_receive _
 595     end
 596
 597     test "it sends wanted private posts to list", %{user: user_a, token: user_a_token} do
 598       user_b = insert(:user)
 599
 600       {:ok, user_a} = User.follow(user_a, user_b)
 601
 602       {:ok, list} = List.create("Test", user_a)
 603       {:ok, list} = List.follow(list, user_b)
 604
 605       Streamer.get_topic_and_add_socket("list", user_a, user_a_token, %{"list" => list.id})
 606
 607       {:ok, activity} =
 608         CommonAPI.post(user_b, %{
 609           status: "Test",
 610           visibility: "private"
 611         })
 612
 613       assert_receive {:render_with_user, _, _, ^activity}
 614       refute Streamer.filtered_by_user?(user_a, activity)
 615     end
 616   end
 617
 618   describe "muted reblogs" do
 619     setup do: oauth_access(["read"])
 620
 621     test "it filters muted reblogs", %{user: user1, token: user1_token} do
 622       user2 = insert(:user)
 623       user3 = insert(:user)
 624       CommonAPI.follow(user1, user2)
 625       CommonAPI.hide_reblogs(user1, user2)
 626
 627       {:ok, create_activity} = CommonAPI.post(user3, %{status: "I'm kawen"})
 628
 629       Streamer.get_topic_and_add_socket("user", user1, user1_token)
 630       {:ok, announce_activity} = CommonAPI.repeat(create_activity.id, user2)
 631       assert_receive {:render_with_user, _, _, ^announce_activity}
 632       assert Streamer.filtered_by_user?(user1, announce_activity)
 633     end
 634
 635     test "it filters reblog notification for reblog-muted actors", %{
 636       user: user1,
 637       token: user1_token
 638     } do
 639       user2 = insert(:user)
 640       CommonAPI.follow(user1, user2)
 641       CommonAPI.hide_reblogs(user1, user2)
 642
 643       {:ok, create_activity} = CommonAPI.post(user1, %{status: "I'm kawen"})
 644       Streamer.get_topic_and_add_socket("user", user1, user1_token)
 645       {:ok, _announce_activity} = CommonAPI.repeat(create_activity.id, user2)
 646
 647       assert_receive {:render_with_user, _, "notification.json", notif}
 648       assert Streamer.filtered_by_user?(user1, notif)
 649     end
 650
 651     test "it send non-reblog notification for reblog-muted actors", %{
 652       user: user1,
 653       token: user1_token
 654     } do
 655       user2 = insert(:user)
 656       CommonAPI.follow(user1, user2)
 657       CommonAPI.hide_reblogs(user1, user2)
 658
 659       {:ok, create_activity} = CommonAPI.post(user1, %{status: "I'm kawen"})
 660       Streamer.get_topic_and_add_socket("user", user1, user1_token)
 661       {:ok, _favorite_activity} = CommonAPI.favorite(user2, create_activity.id)
 662
 663       assert_receive {:render_with_user, _, "notification.json", notif}
 664       refute Streamer.filtered_by_user?(user1, notif)
 665     end
 666   end
 667
 668   describe "muted threads" do
 669     test "it filters posts from muted threads" do
 670       user = insert(:user)
 671       %{user: user2, token: user2_token} = oauth_access(["read"])
 672       Streamer.get_topic_and_add_socket("user", user2, user2_token)
 673
 674       {:ok, user2, user, _activity} = CommonAPI.follow(user2, user)
 675       {:ok, activity} = CommonAPI.post(user, %{status: "super hot take"})
 676       {:ok, _} = CommonAPI.add_mute(user2, activity)
 677
 678       assert_receive {:render_with_user, _, _, ^activity}
 679       assert Streamer.filtered_by_user?(user2, activity)
 680     end
 681   end
 682
 683   describe "direct streams" do
 684     setup do: oauth_access(["read"])
 685
 686     test "it sends conversation update to the 'direct' stream", %{user: user, token: oauth_token} do
 687       another_user = insert(:user)
 688
 689       Streamer.get_topic_and_add_socket("direct", user, oauth_token)
 690
 691       {:ok, _create_activity} =
 692         CommonAPI.post(another_user, %{
 693           status: "hey @#{user.nickname}",
 694           visibility: "direct"
 695         })
 696
 697       assert_receive {:text, received_event}
 698
 699       assert %{"event" => "conversation", "payload" => received_payload} =
 700                Jason.decode!(received_event)
 701
 702       assert %{"last_status" => last_status} = Jason.decode!(received_payload)
 703       [participation] = Participation.for_user(user)
 704       assert last_status["pleroma"]["direct_conversation_id"] == participation.id
 705     end
 706
 707     test "it doesn't send conversation update to the 'direct' stream when the last message in the conversation is deleted",
 708          %{user: user, token: oauth_token} do
 709       another_user = insert(:user)
 710
 711       Streamer.get_topic_and_add_socket("direct", user, oauth_token)
 712
 713       {:ok, create_activity} =
 714         CommonAPI.post(another_user, %{
 715           status: "hi @#{user.nickname}",
 716           visibility: "direct"
 717         })
 718
 719       create_activity_id = create_activity.id
 720       assert_receive {:render_with_user, _, _, ^create_activity}
 721       assert_receive {:text, received_conversation1}
 722       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 723
 724       {:ok, _} = CommonAPI.delete(create_activity_id, another_user)
 725
 726       assert_receive {:text, received_event}
 727
 728       assert %{"event" => "delete", "payload" => ^create_activity_id} =
 729                Jason.decode!(received_event)
 730
 731       refute_receive _
 732     end
 733
 734     test "it sends conversation update to the 'direct' stream when a message is deleted", %{
 735       user: user,
 736       token: oauth_token
 737     } do
 738       another_user = insert(:user)
 739       Streamer.get_topic_and_add_socket("direct", user, oauth_token)
 740
 741       {:ok, create_activity} =
 742         CommonAPI.post(another_user, %{
 743           status: "hi @#{user.nickname}",
 744           visibility: "direct"
 745         })
 746
 747       {:ok, create_activity2} =
 748         CommonAPI.post(another_user, %{
 749           status: "hi @#{user.nickname} 2",
 750           in_reply_to_status_id: create_activity.id,
 751           visibility: "direct"
 752         })
 753
 754       assert_receive {:render_with_user, _, _, ^create_activity}
 755       assert_receive {:render_with_user, _, _, ^create_activity2}
 756       assert_receive {:text, received_conversation1}
 757       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 758       assert_receive {:text, received_conversation1}
 759       assert %{"event" => "conversation", "payload" => _} = Jason.decode!(received_conversation1)
 760
 761       {:ok, _} = CommonAPI.delete(create_activity2.id, another_user)
 762
 763       assert_receive {:text, received_event}
 764       assert %{"event" => "delete", "payload" => _} = Jason.decode!(received_event)
 765
 766       assert_receive {:text, received_event}
 767
 768       assert %{"event" => "conversation", "payload" => received_payload} =
 769                Jason.decode!(received_event)
 770
 771       assert %{"last_status" => last_status} = Jason.decode!(received_payload)
 772       assert last_status["id"] == to_string(create_activity.id)
 773     end
 774   end
 775 end