git.squeep.com Git - akkoma/blob - test/pleroma/web/media_proxy_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxyTest do
   6   use ExUnit.Case
   7   use Pleroma.Tests.Helpers
   8
   9   alias Pleroma.Config
  10   alias Pleroma.Web.Endpoint
  11   alias Pleroma.Web.MediaProxy
  12
  13   defp decode_result(encoded) do
  14     {:ok, decoded} = MediaProxy.decode_url(encoded)
  15     decoded
  16   end
  17
  18   describe "when enabled" do
  19     setup do: clear_config([:media_proxy, :enabled], true)
  20
  21     test "ignores invalid url" do
  22       assert MediaProxy.url(nil) == nil
  23       assert MediaProxy.url("") == nil
  24     end
  25
  26     test "ignores relative url" do
  27       assert MediaProxy.url("/local") == "/local"
  28       assert MediaProxy.url("/") == "/"
  29     end
  30
  31     test "ignores local url" do
  32       local_url = Endpoint.url() <> "/hello"
  33       local_root = Endpoint.url()
  34       assert MediaProxy.url(local_url) == local_url
  35       assert MediaProxy.url(local_root) == local_root
  36     end
  37
  38     test "encodes and decodes URL" do
  39       url = "https://pleroma.soykaf.com/static/logo.png"
  40       encoded = MediaProxy.url(url)
  41
  42       assert String.starts_with?(
  43                encoded,
  44                Config.get([:media_proxy, :base_url], Pleroma.Web.Endpoint.url())
  45              )
  46
  47       assert String.ends_with?(encoded, "/logo.png")
  48
  49       assert decode_result(encoded) == url
  50     end
  51
  52     test "encodes and decodes URL without a path" do
  53       url = "https://pleroma.soykaf.com"
  54       encoded = MediaProxy.url(url)
  55       assert decode_result(encoded) == url
  56     end
  57
  58     test "encodes and decodes URL without an extension" do
  59       url = "https://pleroma.soykaf.com/path/"
  60       encoded = MediaProxy.url(url)
  61       assert String.ends_with?(encoded, "/path")
  62       assert decode_result(encoded) == url
  63     end
  64
  65     test "encodes and decodes URL and ignores query params for the path" do
  66       url = "https://pleroma.soykaf.com/static/logo.png?93939393939&bunny=true"
  67       encoded = MediaProxy.url(url)
  68       assert String.ends_with?(encoded, "/logo.png")
  69       assert decode_result(encoded) == url
  70     end
  71
  72     test "validates signature" do
  73       encoded = MediaProxy.url("https://pleroma.social")
  74
  75       clear_config(
  76         [Endpoint, :secret_key_base],
  77         "00000000000000000000000000000000000000000000000"
  78       )
  79
  80       [_, "proxy", sig, base64 | _] = URI.parse(encoded).path |> String.split("/")
  81       assert MediaProxy.decode_url(sig, base64) == {:error, :invalid_signature}
  82     end
  83
  84     def test_verify_request_path_and_url(request_path, url, expected_result) do
  85       assert MediaProxy.verify_request_path_and_url(request_path, url) == expected_result
  86
  87       assert MediaProxy.verify_request_path_and_url(
  88                %Plug.Conn{
  89                  params: %{"filename" => Path.basename(request_path)},
  90                  request_path: request_path
  91                },
  92                url
  93              ) == expected_result
  94     end
  95
  96     test "if first arg of `verify_request_path_and_url/2` is a Plug.Conn without \"filename\" " <>
  97            "parameter, `verify_request_path_and_url/2` returns :ok " do
  98       assert MediaProxy.verify_request_path_and_url(
  99                %Plug.Conn{params: %{}, request_path: "/some/path"},
 100                "https://instance.com/file.jpg"
 101              ) == :ok
 102
 103       assert MediaProxy.verify_request_path_and_url(
 104                %Plug.Conn{params: %{}, request_path: "/path/to/file.jpg"},
 105                "https://instance.com/file.jpg"
 106              ) == :ok
 107     end
 108
 109     test "`verify_request_path_and_url/2` preserves the encoded or decoded path" do
 110       test_verify_request_path_and_url(
 111         "/Hello world.jpg",
 112         "http://pleroma.social/Hello world.jpg",
 113         :ok
 114       )
 115
 116       test_verify_request_path_and_url(
 117         "/Hello%20world.jpg",
 118         "http://pleroma.social/Hello%20world.jpg",
 119         :ok
 120       )
 121
 122       test_verify_request_path_and_url(
 123         "/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 124         "http://pleroma.social/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 125         :ok
 126       )
 127
 128       test_verify_request_path_and_url(
 129         # Note: `conn.request_path` returns encoded url
 130         "/ANALYSE-DAI-_-LE-STABLECOIN-100-D%C3%89CENTRALIS%C3%89-BQ.jpg",
 131         "https://mydomain.com/uploads/2019/07/ANALYSE-DAI-_-LE-STABLECOIN-100-DÉCENTRALISÉ-BQ.jpg",
 132         :ok
 133       )
 134
 135       test_verify_request_path_and_url(
 136         "/my%2Flong%2Furl%2F2019%2F07%2FS",
 137         "http://pleroma.social/my%2Flong%2Furl%2F2019%2F07%2FS.jpg",
 138         {:wrong_filename, "my%2Flong%2Furl%2F2019%2F07%2FS.jpg"}
 139       )
 140     end
 141
 142     test "uses the configured base_url" do
 143       base_url = "https://cache.pleroma.social"
 144       clear_config([:media_proxy, :base_url], base_url)
 145
 146       url = "https://pleroma.soykaf.com/static/logo.png"
 147       encoded = MediaProxy.url(url)
 148
 149       assert String.starts_with?(encoded, base_url)
 150     end
 151
 152     # Some sites expect ASCII encoded characters in the URL to be preserved even if
 153     # unnecessary.
 154     # Issues: https://git.pleroma.social/pleroma/pleroma/issues/580
 155     #         https://git.pleroma.social/pleroma/pleroma/issues/1055
 156     test "preserve ASCII encoding" do
 157       url =
 158         "https://pleroma.com/%20/%21/%22/%23/%24/%25/%26/%27/%28/%29/%2A/%2B/%2C/%2D/%2E/%2F/%30/%31/%32/%33/%34/%35/%36/%37/%38/%39/%3A/%3B/%3C/%3D/%3E/%3F/%40/%41/%42/%43/%44/%45/%46/%47/%48/%49/%4A/%4B/%4C/%4D/%4E/%4F/%50/%51/%52/%53/%54/%55/%56/%57/%58/%59/%5A/%5B/%5C/%5D/%5E/%5F/%60/%61/%62/%63/%64/%65/%66/%67/%68/%69/%6A/%6B/%6C/%6D/%6E/%6F/%70/%71/%72/%73/%74/%75/%76/%77/%78/%79/%7A/%7B/%7C/%7D/%7E/%7F/%80/%81/%82/%83/%84/%85/%86/%87/%88/%89/%8A/%8B/%8C/%8D/%8E/%8F/%90/%91/%92/%93/%94/%95/%96/%97/%98/%99/%9A/%9B/%9C/%9D/%9E/%9F/%C2%A0/%A1/%A2/%A3/%A4/%A5/%A6/%A7/%A8/%A9/%AA/%AB/%AC/%C2%AD/%AE/%AF/%B0/%B1/%B2/%B3/%B4/%B5/%B6/%B7/%B8/%B9/%BA/%BB/%BC/%BD/%BE/%BF/%C0/%C1/%C2/%C3/%C4/%C5/%C6/%C7/%C8/%C9/%CA/%CB/%CC/%CD/%CE/%CF/%D0/%D1/%D2/%D3/%D4/%D5/%D6/%D7/%D8/%D9/%DA/%DB/%DC/%DD/%DE/%DF/%E0/%E1/%E2/%E3/%E4/%E5/%E6/%E7/%E8/%E9/%EA/%EB/%EC/%ED/%EE/%EF/%F0/%F1/%F2/%F3/%F4/%F5/%F6/%F7/%F8/%F9/%FA/%FB/%FC/%FD/%FE/%FF"
 159
 160       encoded = MediaProxy.url(url)
 161       assert decode_result(encoded) == url
 162     end
 163
 164     # This includes unsafe/reserved characters which are not interpreted as part of the URL
 165     # and would otherwise have to be ASCII encoded. It is our role to ensure the proxied URL
 166     # is unmodified, so we are testing these characters anyway.
 167     test "preserve non-unicode characters per RFC3986" do
 168       url =
 169         "https://pleroma.com/ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz1234567890-._~:/?#[]@!$&'()*+,;=|^`{}"
 170
 171       encoded = MediaProxy.url(url)
 172       assert decode_result(encoded) == url
 173     end
 174
 175     test "preserve unicode characters" do
 176       url = "https://ko.wikipedia.org/wiki/위키백과:대문"
 177
 178       encoded = MediaProxy.url(url)
 179       assert decode_result(encoded) == url
 180     end
 181   end
 182
 183   describe "when disabled" do
 184     setup do: clear_config([:media_proxy, :enabled], false)
 185
 186     test "does not encode remote urls" do
 187       assert MediaProxy.url("https://google.fr") == "https://google.fr"
 188     end
 189   end
 190
 191   describe "whitelist" do
 192     setup do: clear_config([:media_proxy, :enabled], true)
 193
 194     test "mediaproxy whitelist" do
 195       clear_config([:media_proxy, :whitelist], ["https://google.com", "https://feld.me"])
 196       url = "https://feld.me/foo.png"
 197
 198       unencoded = MediaProxy.url(url)
 199       assert unencoded == url
 200     end
 201
 202     # TODO: delete after removing support bare domains for media proxy whitelist
 203     test "mediaproxy whitelist bare domains whitelist (deprecated)" do
 204       clear_config([:media_proxy, :whitelist], ["google.com", "feld.me"])
 205       url = "https://feld.me/foo.png"
 206
 207       unencoded = MediaProxy.url(url)
 208       assert unencoded == url
 209     end
 210
 211     test "does not change whitelisted urls" do
 212       clear_config([:media_proxy, :whitelist], ["mycdn.akamai.com"])
 213       clear_config([:media_proxy, :base_url], "https://cache.pleroma.social")
 214
 215       media_url = "https://mycdn.akamai.com"
 216
 217       url = "#{media_url}/static/logo.png"
 218       encoded = MediaProxy.url(url)
 219
 220       assert String.starts_with?(encoded, media_url)
 221     end
 222
 223     test "ensure Pleroma.Upload base_url is always whitelisted" do
 224       media_url = "https://media.pleroma.social"
 225       clear_config([Pleroma.Upload, :base_url], media_url)
 226
 227       url = "#{media_url}/static/logo.png"
 228       encoded = MediaProxy.url(url)
 229
 230       assert String.starts_with?(encoded, media_url)
 231     end
 232   end
 233 end