git.squeep.com Git - akkoma/blob - test/pleroma/web/mastodon_api/controllers/timeline_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   import Pleroma.Factory
   9   import Tesla.Mock
  10
  11   alias Pleroma.User
  12   alias Pleroma.Web.CommonAPI
  13
  14   setup do
  15     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  16     :ok
  17   end
  18
  19   describe "home" do
  20     setup do: oauth_access(["read:statuses"])
  21
  22     test "does NOT embed account/pleroma/relationship in statuses", %{
  23       user: user,
  24       conn: conn
  25     } do
  26       other_user = insert(:user)
  27
  28       {:ok, _} = CommonAPI.post(other_user, %{status: "hi @#{user.nickname}"})
  29
  30       response =
  31         conn
  32         |> assign(:user, user)
  33         |> get("/api/v1/timelines/home")
  34         |> json_response_and_validate_schema(200)
  35
  36       assert Enum.all?(response, fn n ->
  37                get_in(n, ["account", "pleroma", "relationship"]) == %{}
  38              end)
  39     end
  40
  41     test "the home timeline when the direct messages are excluded", %{user: user, conn: conn} do
  42       {:ok, public_activity} = CommonAPI.post(user, %{status: ".", visibility: "public"})
  43       {:ok, direct_activity} = CommonAPI.post(user, %{status: ".", visibility: "direct"})
  44
  45       {:ok, unlisted_activity} = CommonAPI.post(user, %{status: ".", visibility: "unlisted"})
  46
  47       {:ok, private_activity} = CommonAPI.post(user, %{status: ".", visibility: "private"})
  48
  49       conn = get(conn, "/api/v1/timelines/home?exclude_visibilities[]=direct")
  50
  51       assert status_ids = json_response_and_validate_schema(conn, :ok) |> Enum.map(& &1["id"])
  52       assert public_activity.id in status_ids
  53       assert unlisted_activity.id in status_ids
  54       assert private_activity.id in status_ids
  55       refute direct_activity.id in status_ids
  56     end
  57
  58     test "muted emotions", %{user: user, conn: conn} do
  59       other_user = insert(:user)
  60       {:ok, activity} = CommonAPI.post(user, %{status: "."})
  61
  62       {:ok, _} = CommonAPI.react_with_emoji(activity.id, other_user, "🎅")
  63       User.mute(user, other_user)
  64
  65       result =
  66         conn
  67         |> assign(:user, user)
  68         |> get("/api/v1/timelines/home")
  69         |> json_response_and_validate_schema(200)
  70
  71       assert [
  72                %{
  73                  "pleroma" => %{
  74                    "emoji_reactions" => []
  75                  }
  76                }
  77              ] = result
  78
  79       result =
  80         conn
  81         |> assign(:user, user)
  82         |> get("/api/v1/timelines/home?with_muted=true")
  83         |> json_response_and_validate_schema(200)
  84
  85       assert [
  86                %{
  87                  "pleroma" => %{
  88                    "emoji_reactions" => [%{"count" => 1, "me" => false, "name" => "🎅"}]
  89                  }
  90                }
  91              ] = result
  92     end
  93
  94     test "filtering", %{conn: conn, user: user} do
  95       local_user = insert(:user)
  96       {:ok, user, local_user} = User.follow(user, local_user)
  97       {:ok, local_activity} = CommonAPI.post(local_user, %{status: "Status"})
  98       with_media = create_with_media_activity(local_user)
  99
 100       remote_user = insert(:user, local: false)
 101       {:ok, _user, remote_user} = User.follow(user, remote_user)
 102       remote_activity = create_remote_activity(remote_user)
 103
 104       without_filter_ids =
 105         conn
 106         |> get("/api/v1/timelines/home")
 107         |> json_response_and_validate_schema(200)
 108         |> Enum.map(& &1["id"])
 109
 110       assert local_activity.id in without_filter_ids
 111       assert remote_activity.id in without_filter_ids
 112       assert with_media.id in without_filter_ids
 113
 114       only_local_ids =
 115         conn
 116         |> get("/api/v1/timelines/home?local=true")
 117         |> json_response_and_validate_schema(200)
 118         |> Enum.map(& &1["id"])
 119
 120       assert local_activity.id in only_local_ids
 121       refute remote_activity.id in only_local_ids
 122       assert with_media.id in only_local_ids
 123
 124       only_local_media_ids =
 125         conn
 126         |> get("/api/v1/timelines/home?local=true&only_media=true")
 127         |> json_response_and_validate_schema(200)
 128         |> Enum.map(& &1["id"])
 129
 130       refute local_activity.id in only_local_media_ids
 131       refute remote_activity.id in only_local_media_ids
 132       assert with_media.id in only_local_media_ids
 133
 134       remote_ids =
 135         conn
 136         |> get("/api/v1/timelines/home?remote=true")
 137         |> json_response_and_validate_schema(200)
 138         |> Enum.map(& &1["id"])
 139
 140       refute local_activity.id in remote_ids
 141       assert remote_activity.id in remote_ids
 142       refute with_media.id in remote_ids
 143
 144       assert conn
 145              |> get("/api/v1/timelines/home?remote=true&only_media=true")
 146              |> json_response_and_validate_schema(200) == []
 147
 148       assert conn
 149              |> get("/api/v1/timelines/home?remote=true&local=true")
 150              |> json_response_and_validate_schema(200) == []
 151     end
 152   end
 153
 154   describe "public" do
 155     @tag capture_log: true
 156     test "the public timeline", %{conn: conn} do
 157       user = insert(:user)
 158
 159       {:ok, activity} = CommonAPI.post(user, %{status: "test"})
 160       with_media = create_with_media_activity(user)
 161
 162       remote = insert(:note_activity, local: false)
 163
 164       assert conn
 165              |> get("/api/v1/timelines/public?local=False")
 166              |> json_response_and_validate_schema(:ok)
 167              |> length == 3
 168
 169       local_ids =
 170         conn
 171         |> get("/api/v1/timelines/public?local=True")
 172         |> json_response_and_validate_schema(:ok)
 173         |> Enum.map(& &1["id"])
 174
 175       assert activity.id in local_ids
 176       assert with_media.id in local_ids
 177       refute remote.id in local_ids
 178
 179       local_ids =
 180         conn
 181         |> get("/api/v1/timelines/public?local=True")
 182         |> json_response_and_validate_schema(:ok)
 183         |> Enum.map(& &1["id"])
 184
 185       assert activity.id in local_ids
 186       assert with_media.id in local_ids
 187       refute remote.id in local_ids
 188
 189       local_ids =
 190         conn
 191         |> get("/api/v1/timelines/public?local=True&only_media=true")
 192         |> json_response_and_validate_schema(:ok)
 193         |> Enum.map(& &1["id"])
 194
 195       refute activity.id in local_ids
 196       assert with_media.id in local_ids
 197       refute remote.id in local_ids
 198
 199       local_ids =
 200         conn
 201         |> get("/api/v1/timelines/public?local=1")
 202         |> json_response_and_validate_schema(:ok)
 203         |> Enum.map(& &1["id"])
 204
 205       assert activity.id in local_ids
 206       assert with_media.id in local_ids
 207       refute remote.id in local_ids
 208
 209       remote_id = remote.id
 210
 211       assert [%{"id" => ^remote_id}] =
 212                conn
 213                |> get("/api/v1/timelines/public?remote=true")
 214                |> json_response_and_validate_schema(:ok)
 215
 216       with_media_id = with_media.id
 217
 218       assert [%{"id" => ^with_media_id}] =
 219                conn
 220                |> get("/api/v1/timelines/public?only_media=true")
 221                |> json_response_and_validate_schema(:ok)
 222
 223       assert conn
 224              |> get("/api/v1/timelines/public?remote=true&only_media=true")
 225              |> json_response_and_validate_schema(:ok) == []
 226
 227       # does not contain repeats
 228       {:ok, _} = CommonAPI.repeat(activity.id, user)
 229
 230       assert [_, _] =
 231                conn
 232                |> get("/api/v1/timelines/public?local=true")
 233                |> json_response_and_validate_schema(:ok)
 234     end
 235
 236     test "the public timeline includes only public statuses for an authenticated user" do
 237       %{user: user, conn: conn} = oauth_access(["read:statuses"])
 238
 239       {:ok, _activity} = CommonAPI.post(user, %{status: "test"})
 240       {:ok, _activity} = CommonAPI.post(user, %{status: "test", visibility: "private"})
 241       {:ok, _activity} = CommonAPI.post(user, %{status: "test", visibility: "unlisted"})
 242       {:ok, _activity} = CommonAPI.post(user, %{status: "test", visibility: "direct"})
 243
 244       res_conn = get(conn, "/api/v1/timelines/public")
 245       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
 246     end
 247
 248     test "doesn't return replies if follower is posting with blocked user" do
 249       %{conn: conn, user: blocker} = oauth_access(["read:statuses"])
 250       [blockee, friend] = insert_list(2, :user)
 251       {:ok, blocker, friend} = User.follow(blocker, friend)
 252       {:ok, _} = User.block(blocker, blockee)
 253
 254       conn = assign(conn, :user, blocker)
 255
 256       {:ok, %{id: activity_id} = activity} = CommonAPI.post(friend, %{status: "hey!"})
 257
 258       {:ok, reply_from_blockee} =
 259         CommonAPI.post(blockee, %{status: "heya", in_reply_to_status_id: activity})
 260
 261       {:ok, _reply_from_friend} =
 262         CommonAPI.post(friend, %{status: "status", in_reply_to_status_id: reply_from_blockee})
 263
 264       # Still shows replies from yourself
 265       {:ok, %{id: reply_from_me}} =
 266         CommonAPI.post(blocker, %{status: "status", in_reply_to_status_id: reply_from_blockee})
 267
 268       response =
 269         get(conn, "/api/v1/timelines/public")
 270         |> json_response_and_validate_schema(200)
 271
 272       assert length(response) == 2
 273       [%{"id" => ^reply_from_me}, %{"id" => ^activity_id}] = response
 274     end
 275
 276     test "doesn't return posts from users who blocked you when :blockers_visible is disabled" do
 277       clear_config([:activitypub, :blockers_visible], false)
 278
 279       %{conn: conn, user: blockee} = oauth_access(["read:statuses"])
 280       blocker = insert(:user)
 281       {:ok, _} = User.block(blocker, blockee)
 282
 283       conn = assign(conn, :user, blockee)
 284
 285       {:ok, _} = CommonAPI.post(blocker, %{status: "hey!"})
 286
 287       response =
 288         get(conn, "/api/v1/timelines/public")
 289         |> json_response_and_validate_schema(200)
 290
 291       assert response == []
 292     end
 293
 294     test "doesn't return replies if follow is posting with users from blocked domain" do
 295       %{conn: conn, user: blocker} = oauth_access(["read:statuses"])
 296       friend = insert(:user)
 297       blockee = insert(:user, ap_id: "https://example.com/users/blocked")
 298       {:ok, blocker, friend} = User.follow(blocker, friend)
 299       {:ok, blocker} = User.block_domain(blocker, "example.com")
 300
 301       conn = assign(conn, :user, blocker)
 302
 303       {:ok, %{id: activity_id} = activity} = CommonAPI.post(friend, %{status: "hey!"})
 304
 305       {:ok, reply_from_blockee} =
 306         CommonAPI.post(blockee, %{status: "heya", in_reply_to_status_id: activity})
 307
 308       {:ok, _reply_from_friend} =
 309         CommonAPI.post(friend, %{status: "status", in_reply_to_status_id: reply_from_blockee})
 310
 311       res_conn = get(conn, "/api/v1/timelines/public")
 312
 313       activities = json_response_and_validate_schema(res_conn, 200)
 314       [%{"id" => ^activity_id}] = activities
 315     end
 316
 317     test "can be filtered by instance", %{conn: conn} do
 318       user = insert(:user, ap_id: "https://lain.com/users/lain")
 319       insert(:note_activity, local: false)
 320       insert(:note_activity, local: false)
 321
 322       {:ok, _} = CommonAPI.post(user, %{status: "test"})
 323
 324       conn = get(conn, "/api/v1/timelines/public?instance=lain.com")
 325
 326       assert length(json_response_and_validate_schema(conn, :ok)) == 1
 327     end
 328
 329     test "muted emotions", %{conn: conn} do
 330       user = insert(:user)
 331       token = insert(:oauth_token, user: user, scopes: ["read:statuses"])
 332
 333       conn =
 334         conn
 335         |> assign(:user, user)
 336         |> assign(:token, token)
 337
 338       other_user = insert(:user)
 339       {:ok, activity} = CommonAPI.post(user, %{status: "."})
 340
 341       {:ok, _} = CommonAPI.react_with_emoji(activity.id, other_user, "🎅")
 342       User.mute(user, other_user)
 343
 344       result =
 345         conn
 346         |> get("/api/v1/timelines/public")
 347         |> json_response_and_validate_schema(200)
 348
 349       assert [
 350                %{
 351                  "pleroma" => %{
 352                    "emoji_reactions" => []
 353                  }
 354                }
 355              ] = result
 356
 357       result =
 358         conn
 359         |> get("/api/v1/timelines/public?with_muted=true")
 360         |> json_response_and_validate_schema(200)
 361
 362       assert [
 363                %{
 364                  "pleroma" => %{
 365                    "emoji_reactions" => [%{"count" => 1, "me" => false, "name" => "🎅"}]
 366                  }
 367                }
 368              ] = result
 369     end
 370
 371     test "should return local-only posts for authenticated users" do
 372       user = insert(:user)
 373       %{user: _reader, conn: conn} = oauth_access(["read:statuses"])
 374
 375       {:ok, %{id: id}} = CommonAPI.post(user, %{status: "#2hu #2HU", visibility: "local"})
 376
 377       result =
 378         conn
 379         |> get("/api/v1/timelines/public")
 380         |> json_response_and_validate_schema(200)
 381
 382       assert [%{"id" => ^id}] = result
 383     end
 384
 385     test "should not return local-only posts for users without read:statuses" do
 386       user = insert(:user)
 387       %{user: _reader, conn: conn} = oauth_access([])
 388
 389       {:ok, _activity} = CommonAPI.post(user, %{status: "#2hu #2HU", visibility: "local"})
 390
 391       result =
 392         conn
 393         |> get("/api/v1/timelines/public")
 394         |> json_response_and_validate_schema(200)
 395
 396       assert [] = result
 397     end
 398
 399     test "should not return local-only posts for anonymous users" do
 400       user = insert(:user)
 401
 402       {:ok, _activity} = CommonAPI.post(user, %{status: "#2hu #2HU", visibility: "local"})
 403
 404       result =
 405         build_conn()
 406         |> get("/api/v1/timelines/public")
 407         |> json_response_and_validate_schema(200)
 408
 409       assert [] = result
 410     end
 411
 412     test "should return 404 if disabled" do
 413       clear_config([:instance, :federated_timeline_available], false)
 414
 415       result =
 416         build_conn()
 417         |> get("/api/v1/timelines/public")
 418         |> json_response_and_validate_schema(404)
 419
 420       assert %{"error" => "Federated timeline is disabled"} = result
 421     end
 422
 423     test "should not return 404 if local is specified" do
 424       clear_config([:instance, :federated_timeline_available], false)
 425
 426       result =
 427         build_conn()
 428         |> get("/api/v1/timelines/public?local=true")
 429         |> json_response_and_validate_schema(200)
 430     end
 431   end
 432
 433   defp local_and_remote_activities do
 434     insert(:note_activity)
 435     insert(:note_activity, local: false)
 436     :ok
 437   end
 438
 439   describe "public with restrict unauthenticated timeline for local and federated timelines" do
 440     setup do: local_and_remote_activities()
 441
 442     setup do: clear_config([:restrict_unauthenticated, :timelines, :local], true)
 443
 444     setup do: clear_config([:restrict_unauthenticated, :timelines, :federated], true)
 445
 446     test "if user is unauthenticated", %{conn: conn} do
 447       res_conn = get(conn, "/api/v1/timelines/public?local=true")
 448
 449       assert json_response_and_validate_schema(res_conn, :unauthorized) == %{
 450                "error" => "authorization required for timeline view"
 451              }
 452
 453       res_conn = get(conn, "/api/v1/timelines/public?local=false")
 454
 455       assert json_response_and_validate_schema(res_conn, :unauthorized) == %{
 456                "error" => "authorization required for timeline view"
 457              }
 458     end
 459
 460     test "if user is authenticated" do
 461       %{conn: conn} = oauth_access(["read:statuses"])
 462
 463       res_conn = get(conn, "/api/v1/timelines/public?local=true")
 464       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
 465
 466       res_conn = get(conn, "/api/v1/timelines/public?local=false")
 467       assert length(json_response_and_validate_schema(res_conn, 200)) == 2
 468     end
 469   end
 470
 471   describe "public with restrict unauthenticated timeline for local" do
 472     setup do: local_and_remote_activities()
 473
 474     setup do: clear_config([:restrict_unauthenticated, :timelines, :local], true)
 475
 476     test "if user is unauthenticated", %{conn: conn} do
 477       res_conn = get(conn, "/api/v1/timelines/public?local=true")
 478
 479       assert json_response_and_validate_schema(res_conn, :unauthorized) == %{
 480                "error" => "authorization required for timeline view"
 481              }
 482
 483       res_conn = get(conn, "/api/v1/timelines/public?local=false")
 484       assert length(json_response_and_validate_schema(res_conn, 200)) == 2
 485     end
 486
 487     test "if user is authenticated", %{conn: _conn} do
 488       %{conn: conn} = oauth_access(["read:statuses"])
 489
 490       res_conn = get(conn, "/api/v1/timelines/public?local=true")
 491       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
 492
 493       res_conn = get(conn, "/api/v1/timelines/public?local=false")
 494       assert length(json_response_and_validate_schema(res_conn, 200)) == 2
 495     end
 496   end
 497
 498   describe "public with restrict unauthenticated timeline for remote" do
 499     setup do: local_and_remote_activities()
 500
 501     setup do: clear_config([:restrict_unauthenticated, :timelines, :federated], true)
 502
 503     test "if user is unauthenticated", %{conn: conn} do
 504       res_conn = get(conn, "/api/v1/timelines/public?local=true")
 505       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
 506
 507       res_conn = get(conn, "/api/v1/timelines/public?local=false")
 508
 509       assert json_response_and_validate_schema(res_conn, :unauthorized) == %{
 510                "error" => "authorization required for timeline view"
 511              }
 512     end
 513
 514     test "if user is authenticated", %{conn: _conn} do
 515       %{conn: conn} = oauth_access(["read:statuses"])
 516
 517       res_conn = get(conn, "/api/v1/timelines/public?local=true")
 518       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
 519
 520       res_conn = get(conn, "/api/v1/timelines/public?local=false")
 521       assert length(json_response_and_validate_schema(res_conn, 200)) == 2
 522     end
 523   end
 524
 525   describe "direct" do
 526     test "direct timeline", %{conn: conn} do
 527       user_one = insert(:user)
 528       user_two = insert(:user)
 529
 530       {:ok, user_two, user_one} = User.follow(user_two, user_one)
 531
 532       {:ok, direct} =
 533         CommonAPI.post(user_one, %{
 534           status: "Hi @#{user_two.nickname}!",
 535           visibility: "direct"
 536         })
 537
 538       {:ok, _follower_only} =
 539         CommonAPI.post(user_one, %{
 540           status: "Hi @#{user_two.nickname}!",
 541           visibility: "private"
 542         })
 543
 544       conn_user_two =
 545         conn
 546         |> assign(:user, user_two)
 547         |> assign(:token, insert(:oauth_token, user: user_two, scopes: ["read:statuses"]))
 548
 549       # Only direct should be visible here
 550       res_conn = get(conn_user_two, "/api/v1/timelines/direct")
 551
 552       assert [status] = json_response_and_validate_schema(res_conn, :ok)
 553
 554       assert %{"visibility" => "direct"} = status
 555       assert status["url"] != direct.data["id"]
 556
 557       # User should be able to see their own direct message
 558       res_conn =
 559         build_conn()
 560         |> assign(:user, user_one)
 561         |> assign(:token, insert(:oauth_token, user: user_one, scopes: ["read:statuses"]))
 562         |> get("/api/v1/timelines/direct")
 563
 564       [status] = json_response_and_validate_schema(res_conn, :ok)
 565
 566       assert %{"visibility" => "direct"} = status
 567
 568       # Both should be visible here
 569       res_conn = get(conn_user_two, "/api/v1/timelines/home")
 570
 571       [_s1, _s2] = json_response_and_validate_schema(res_conn, :ok)
 572
 573       # Test pagination
 574       Enum.each(1..20, fn _ ->
 575         {:ok, _} =
 576           CommonAPI.post(user_one, %{
 577             status: "Hi @#{user_two.nickname}!",
 578             visibility: "direct"
 579           })
 580       end)
 581
 582       res_conn = get(conn_user_two, "/api/v1/timelines/direct")
 583
 584       statuses = json_response_and_validate_schema(res_conn, :ok)
 585       assert length(statuses) == 20
 586
 587       max_id = List.last(statuses)["id"]
 588
 589       res_conn = get(conn_user_two, "/api/v1/timelines/direct?max_id=#{max_id}")
 590
 591       assert [status] = json_response_and_validate_schema(res_conn, :ok)
 592
 593       assert status["url"] != direct.data["id"]
 594     end
 595
 596     test "doesn't include DMs from blocked users" do
 597       %{user: blocker, conn: conn} = oauth_access(["read:statuses"])
 598       blocked = insert(:user)
 599       other_user = insert(:user)
 600       {:ok, _user_relationship} = User.block(blocker, blocked)
 601
 602       {:ok, _blocked_direct} =
 603         CommonAPI.post(blocked, %{
 604           status: "Hi @#{blocker.nickname}!",
 605           visibility: "direct"
 606         })
 607
 608       {:ok, direct} =
 609         CommonAPI.post(other_user, %{
 610           status: "Hi @#{blocker.nickname}!",
 611           visibility: "direct"
 612         })
 613
 614       res_conn = get(conn, "/api/v1/timelines/direct")
 615
 616       [status] = json_response_and_validate_schema(res_conn, :ok)
 617       assert status["id"] == direct.id
 618     end
 619   end
 620
 621   describe "list" do
 622     setup do: oauth_access(["read:lists"])
 623
 624     test "does not contain retoots", %{user: user, conn: conn} do
 625       other_user = insert(:user)
 626       {:ok, activity_one} = CommonAPI.post(user, %{status: "Marisa is cute."})
 627       {:ok, activity_two} = CommonAPI.post(other_user, %{status: "Marisa is stupid."})
 628       {:ok, _} = CommonAPI.repeat(activity_one.id, other_user)
 629
 630       {:ok, list} = Pleroma.List.create("name", user)
 631       {:ok, list} = Pleroma.List.follow(list, other_user)
 632
 633       conn = get(conn, "/api/v1/timelines/list/#{list.id}")
 634
 635       assert [%{"id" => id}] = json_response_and_validate_schema(conn, :ok)
 636
 637       assert id == to_string(activity_two.id)
 638     end
 639
 640     test "works with pagination", %{user: user, conn: conn} do
 641       other_user = insert(:user)
 642       {:ok, list} = Pleroma.List.create("name", user)
 643       {:ok, list} = Pleroma.List.follow(list, other_user)
 644
 645       Enum.each(1..30, fn i ->
 646         CommonAPI.post(other_user, %{status: "post number #{i}"})
 647       end)
 648
 649       res =
 650         get(conn, "/api/v1/timelines/list/#{list.id}?limit=1")
 651         |> json_response_and_validate_schema(:ok)
 652
 653       assert length(res) == 1
 654
 655       [first] = res
 656
 657       res =
 658         get(conn, "/api/v1/timelines/list/#{list.id}?max_id=#{first["id"]}&limit=30")
 659         |> json_response_and_validate_schema(:ok)
 660
 661       assert length(res) == 29
 662     end
 663
 664     test "list timeline", %{user: user, conn: conn} do
 665       other_user = insert(:user)
 666       {:ok, _activity_one} = CommonAPI.post(user, %{status: "Marisa is cute."})
 667       {:ok, activity_two} = CommonAPI.post(other_user, %{status: "Marisa is cute."})
 668       {:ok, list} = Pleroma.List.create("name", user)
 669       {:ok, list} = Pleroma.List.follow(list, other_user)
 670
 671       conn = get(conn, "/api/v1/timelines/list/#{list.id}")
 672
 673       assert [%{"id" => id}] = json_response_and_validate_schema(conn, :ok)
 674
 675       assert id == to_string(activity_two.id)
 676     end
 677
 678     test "list timeline does not leak non-public statuses for unfollowed users", %{
 679       user: user,
 680       conn: conn
 681     } do
 682       other_user = insert(:user)
 683       {:ok, activity_one} = CommonAPI.post(other_user, %{status: "Marisa is cute."})
 684
 685       {:ok, _activity_two} =
 686         CommonAPI.post(other_user, %{
 687           status: "Marisa is cute.",
 688           visibility: "private"
 689         })
 690
 691       {:ok, list} = Pleroma.List.create("name", user)
 692       {:ok, list} = Pleroma.List.follow(list, other_user)
 693
 694       conn = get(conn, "/api/v1/timelines/list/#{list.id}")
 695
 696       assert [%{"id" => id}] = json_response_and_validate_schema(conn, :ok)
 697
 698       assert id == to_string(activity_one.id)
 699     end
 700
 701     test "muted emotions", %{user: user, conn: conn} do
 702       user2 = insert(:user)
 703       user3 = insert(:user)
 704       {:ok, activity} = CommonAPI.post(user2, %{status: "."})
 705
 706       {:ok, _} = CommonAPI.react_with_emoji(activity.id, user3, "🎅")
 707       User.mute(user, user3)
 708
 709       {:ok, list} = Pleroma.List.create("name", user)
 710       {:ok, list} = Pleroma.List.follow(list, user2)
 711
 712       result =
 713         conn
 714         |> get("/api/v1/timelines/list/#{list.id}")
 715         |> json_response_and_validate_schema(200)
 716
 717       assert [
 718                %{
 719                  "pleroma" => %{
 720                    "emoji_reactions" => []
 721                  }
 722                }
 723              ] = result
 724
 725       result =
 726         conn
 727         |> get("/api/v1/timelines/list/#{list.id}?with_muted=true")
 728         |> json_response_and_validate_schema(200)
 729
 730       assert [
 731                %{
 732                  "pleroma" => %{
 733                    "emoji_reactions" => [%{"count" => 1, "me" => false, "name" => "🎅"}]
 734                  }
 735                }
 736              ] = result
 737     end
 738
 739     test "filtering", %{user: user, conn: conn} do
 740       {:ok, list} = Pleroma.List.create("name", user)
 741
 742       local_user = insert(:user)
 743       {:ok, local_activity} = CommonAPI.post(local_user, %{status: "Marisa is stupid."})
 744       with_media = create_with_media_activity(local_user)
 745       {:ok, list} = Pleroma.List.follow(list, local_user)
 746
 747       remote_user = insert(:user, local: false)
 748       remote_activity = create_remote_activity(remote_user)
 749       {:ok, list} = Pleroma.List.follow(list, remote_user)
 750
 751       all_ids =
 752         conn
 753         |> get("/api/v1/timelines/list/#{list.id}")
 754         |> json_response_and_validate_schema(200)
 755         |> Enum.map(& &1["id"])
 756
 757       assert local_activity.id in all_ids
 758       assert with_media.id in all_ids
 759       assert remote_activity.id in all_ids
 760
 761       only_local_ids =
 762         conn
 763         |> get("/api/v1/timelines/list/#{list.id}?local=true")
 764         |> json_response_and_validate_schema(200)
 765         |> Enum.map(& &1["id"])
 766
 767       assert local_activity.id in only_local_ids
 768       assert with_media.id in only_local_ids
 769       refute remote_activity.id in only_local_ids
 770
 771       only_local_media_ids =
 772         conn
 773         |> get("/api/v1/timelines/list/#{list.id}?local=true&only_media=true")
 774         |> json_response_and_validate_schema(200)
 775         |> Enum.map(& &1["id"])
 776
 777       refute local_activity.id in only_local_media_ids
 778       assert with_media.id in only_local_media_ids
 779       refute remote_activity.id in only_local_media_ids
 780
 781       remote_ids =
 782         conn
 783         |> get("/api/v1/timelines/list/#{list.id}?remote=true")
 784         |> json_response_and_validate_schema(200)
 785         |> Enum.map(& &1["id"])
 786
 787       refute local_activity.id in remote_ids
 788       refute with_media.id in remote_ids
 789       assert remote_activity.id in remote_ids
 790
 791       assert conn
 792              |> get("/api/v1/timelines/list/#{list.id}?remote=true&only_media=true")
 793              |> json_response_and_validate_schema(200) == []
 794
 795       only_media_ids =
 796         conn
 797         |> get("/api/v1/timelines/list/#{list.id}?only_media=true")
 798         |> json_response_and_validate_schema(200)
 799         |> Enum.map(& &1["id"])
 800
 801       refute local_activity.id in only_media_ids
 802       assert with_media.id in only_media_ids
 803       refute remote_activity.id in only_media_ids
 804
 805       assert conn
 806              |> get("/api/v1/timelines/list/#{list.id}?only_media=true&local=true&remote=true")
 807              |> json_response_and_validate_schema(200) == []
 808     end
 809   end
 810
 811   describe "hashtag" do
 812     setup do: oauth_access(["n/a"])
 813
 814     @tag capture_log: true
 815     test "hashtag timeline", %{conn: conn} do
 816       following = insert(:user)
 817
 818       {:ok, activity} = CommonAPI.post(following, %{status: "test #2hu"})
 819       with_media = create_with_media_activity(following)
 820
 821       remote = insert(:user, local: false)
 822       remote_activity = create_remote_activity(remote)
 823
 824       all_ids =
 825         conn
 826         |> get("/api/v1/timelines/tag/2hu")
 827         |> json_response_and_validate_schema(:ok)
 828         |> Enum.map(& &1["id"])
 829
 830       assert activity.id in all_ids
 831       assert with_media.id in all_ids
 832       assert remote_activity.id in all_ids
 833
 834       # works for different capitalization too
 835       all_ids =
 836         conn
 837         |> get("/api/v1/timelines/tag/2HU")
 838         |> json_response_and_validate_schema(:ok)
 839         |> Enum.map(& &1["id"])
 840
 841       assert activity.id in all_ids
 842       assert with_media.id in all_ids
 843       assert remote_activity.id in all_ids
 844
 845       local_ids =
 846         conn
 847         |> get("/api/v1/timelines/tag/2hu?local=true")
 848         |> json_response_and_validate_schema(:ok)
 849         |> Enum.map(& &1["id"])
 850
 851       assert activity.id in local_ids
 852       assert with_media.id in local_ids
 853       refute remote_activity.id in local_ids
 854
 855       remote_ids =
 856         conn
 857         |> get("/api/v1/timelines/tag/2hu?remote=true")
 858         |> json_response_and_validate_schema(:ok)
 859         |> Enum.map(& &1["id"])
 860
 861       refute activity.id in remote_ids
 862       refute with_media.id in remote_ids
 863       assert remote_activity.id in remote_ids
 864
 865       media_ids =
 866         conn
 867         |> get("/api/v1/timelines/tag/2hu?only_media=true")
 868         |> json_response_and_validate_schema(:ok)
 869         |> Enum.map(& &1["id"])
 870
 871       refute activity.id in media_ids
 872       assert with_media.id in media_ids
 873       refute remote_activity.id in media_ids
 874
 875       media_local_ids =
 876         conn
 877         |> get("/api/v1/timelines/tag/2hu?only_media=true&local=true")
 878         |> json_response_and_validate_schema(:ok)
 879         |> Enum.map(& &1["id"])
 880
 881       refute activity.id in media_local_ids
 882       assert with_media.id in media_local_ids
 883       refute remote_activity.id in media_local_ids
 884
 885       ids =
 886         conn
 887         |> get("/api/v1/timelines/tag/2hu?only_media=true&local=true&remote=true")
 888         |> json_response_and_validate_schema(:ok)
 889         |> Enum.map(& &1["id"])
 890
 891       refute activity.id in ids
 892       refute with_media.id in ids
 893       refute remote_activity.id in ids
 894
 895       assert conn
 896              |> get("/api/v1/timelines/tag/2hu?only_media=true&remote=true")
 897              |> json_response_and_validate_schema(:ok) == []
 898     end
 899
 900     test "multi-hashtag timeline", %{conn: conn} do
 901       user = insert(:user)
 902
 903       {:ok, activity_test} = CommonAPI.post(user, %{status: "#test"})
 904       {:ok, activity_test1} = CommonAPI.post(user, %{status: "#test #test1"})
 905       {:ok, activity_none} = CommonAPI.post(user, %{status: "#test #none"})
 906
 907       any_test = get(conn, "/api/v1/timelines/tag/test?any[]=test1")
 908
 909       [status_none, status_test1, status_test] = json_response_and_validate_schema(any_test, :ok)
 910
 911       assert to_string(activity_test.id) == status_test["id"]
 912       assert to_string(activity_test1.id) == status_test1["id"]
 913       assert to_string(activity_none.id) == status_none["id"]
 914
 915       restricted_test = get(conn, "/api/v1/timelines/tag/test?all[]=test1&none[]=none")
 916
 917       assert [status_test1] == json_response_and_validate_schema(restricted_test, :ok)
 918
 919       all_test = get(conn, "/api/v1/timelines/tag/test?all[]=none")
 920
 921       assert [status_none] == json_response_and_validate_schema(all_test, :ok)
 922     end
 923
 924     test "muted emotions", %{conn: conn} do
 925       user = insert(:user)
 926       token = insert(:oauth_token, user: user, scopes: ["read:statuses"])
 927
 928       conn =
 929         conn
 930         |> assign(:user, user)
 931         |> assign(:token, token)
 932
 933       other_user = insert(:user)
 934       {:ok, activity} = CommonAPI.post(user, %{status: "test #2hu"})
 935
 936       {:ok, _} = CommonAPI.react_with_emoji(activity.id, other_user, "🎅")
 937       User.mute(user, other_user)
 938
 939       result =
 940         conn
 941         |> get("/api/v1/timelines/tag/2hu")
 942         |> json_response_and_validate_schema(200)
 943
 944       assert [
 945                %{
 946                  "pleroma" => %{
 947                    "emoji_reactions" => []
 948                  }
 949                }
 950              ] = result
 951
 952       result =
 953         conn
 954         |> get("/api/v1/timelines/tag/2hu?with_muted=true")
 955         |> json_response_and_validate_schema(200)
 956
 957       assert [
 958                %{
 959                  "pleroma" => %{
 960                    "emoji_reactions" => [%{"count" => 1, "me" => false, "name" => "🎅"}]
 961                  }
 962                }
 963              ] = result
 964     end
 965   end
 966
 967   describe "hashtag timeline handling of :restrict_unauthenticated setting" do
 968     setup do
 969       user = insert(:user)
 970       {:ok, activity1} = CommonAPI.post(user, %{status: "test #tag1"})
 971       {:ok, _activity2} = CommonAPI.post(user, %{status: "test #tag1"})
 972
 973       activity1
 974       |> Ecto.Changeset.change(%{local: false})
 975       |> Pleroma.Repo.update()
 976
 977       base_uri = "/api/v1/timelines/tag/tag1"
 978       error_response = %{"error" => "authorization required for timeline view"}
 979
 980       %{base_uri: base_uri, error_response: error_response}
 981     end
 982
 983     defp ensure_authenticated_access(base_uri) do
 984       %{conn: auth_conn} = oauth_access(["read:statuses"])
 985
 986       res_conn = get(auth_conn, "#{base_uri}?local=true")
 987       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
 988
 989       res_conn = get(auth_conn, "#{base_uri}?local=false")
 990       assert length(json_response_and_validate_schema(res_conn, 200)) == 2
 991     end
 992
 993     test "with default settings on private instances, returns 403 for unauthenticated users", %{
 994       conn: conn,
 995       base_uri: base_uri,
 996       error_response: error_response
 997     } do
 998       clear_config([:instance, :public], false)
 999       clear_config([:restrict_unauthenticated, :timelines])
1000
1001       for local <- [true, false] do
1002         res_conn = get(conn, "#{base_uri}?local=#{local}")
1003
1004         assert json_response_and_validate_schema(res_conn, :unauthorized) == error_response
1005       end
1006
1007       ensure_authenticated_access(base_uri)
1008     end
1009
1010     test "with `%{local: true, federated: true}`, returns 403 for unauthenticated users", %{
1011       conn: conn,
1012       base_uri: base_uri,
1013       error_response: error_response
1014     } do
1015       clear_config([:restrict_unauthenticated, :timelines, :local], true)
1016       clear_config([:restrict_unauthenticated, :timelines, :federated], true)
1017
1018       for local <- [true, false] do
1019         res_conn = get(conn, "#{base_uri}?local=#{local}")
1020
1021         assert json_response_and_validate_schema(res_conn, :unauthorized) == error_response
1022       end
1023
1024       ensure_authenticated_access(base_uri)
1025     end
1026
1027     test "with `%{local: false, federated: true}`, forbids unauthenticated access to federated timeline",
1028          %{conn: conn, base_uri: base_uri, error_response: error_response} do
1029       clear_config([:restrict_unauthenticated, :timelines, :local], false)
1030       clear_config([:restrict_unauthenticated, :timelines, :federated], true)
1031
1032       res_conn = get(conn, "#{base_uri}?local=true")
1033       assert length(json_response_and_validate_schema(res_conn, 200)) == 1
1034
1035       res_conn = get(conn, "#{base_uri}?local=false")
1036       assert json_response_and_validate_schema(res_conn, :unauthorized) == error_response
1037
1038       ensure_authenticated_access(base_uri)
1039     end
1040
1041     test "with `%{local: true, federated: false}`, forbids unauthenticated access to public timeline",
1042          %{conn: conn, base_uri: base_uri, error_response: error_response} do
1043       # (but not to local public activities which are delivered as part of federated timeline)
1044       clear_config([:restrict_unauthenticated, :timelines, :local], true)
1045       clear_config([:restrict_unauthenticated, :timelines, :federated], false)
1046
1047       res_conn = get(conn, "#{base_uri}?local=true")
1048       assert json_response_and_validate_schema(res_conn, :unauthorized) == error_response
1049
1050       # Note: local activities get delivered as part of federated timeline
1051       res_conn = get(conn, "#{base_uri}?local=false")
1052       assert length(json_response_and_validate_schema(res_conn, 200)) == 2
1053
1054       ensure_authenticated_access(base_uri)
1055     end
1056   end
1057
1058   describe "bubble" do
1059     test "filtering" do
1060       %{conn: conn, user: user} = oauth_access(["read:statuses"])
1061       clear_config([:instance, :local_bubble], [])
1062       # our endpoint host has a port in it so let's set the AP ID
1063       local_user = insert(:user, %{ap_id: "https://localhost/users/user"})
1064       remote_user = insert(:user, %{ap_id: "https://example.com/users/remote_user"})
1065       {:ok, user, local_user} = User.follow(user, local_user)
1066       {:ok, _user, remote_user} = User.follow(user, remote_user)
1067
1068       {:ok, local_activity} = CommonAPI.post(local_user, %{status: "Status"})
1069       remote_activity = create_remote_activity(remote_user)
1070
1071       # If nothing, only include ours
1072       clear_config([:instance, :local_bubble], [])
1073
1074       one_instance =
1075         conn
1076         |> get("/api/v1/timelines/bubble")
1077         |> json_response_and_validate_schema(200)
1078         |> Enum.map(& &1["id"])
1079
1080       assert local_activity.id in one_instance
1081
1082       # If we have others, also include theirs
1083       clear_config([:instance, :local_bubble], ["example.com"])
1084
1085       two_instances =
1086         conn
1087         |> get("/api/v1/timelines/bubble")
1088         |> json_response_and_validate_schema(200)
1089         |> Enum.map(& &1["id"])
1090
1091       assert local_activity.id in two_instances
1092       assert remote_activity.id in two_instances
1093     end
1094
1095     test "restrict_unauthenticated with bubble timeline", %{conn: conn} do
1096       clear_config([:restrict_unauthenticated, :timelines, :bubble], true)
1097
1098       conn
1099       |> get("/api/v1/timelines/bubble")
1100       |> json_response_and_validate_schema(:unauthorized)
1101
1102       clear_config([:restrict_unauthenticated, :timelines, :bubble], false)
1103
1104       conn
1105       |> get("/api/v1/timelines/bubble")
1106       |> json_response_and_validate_schema(200)
1107     end
1108   end
1109
1110   defp create_remote_activity(user) do
1111     obj =
1112       insert(:note, %{
1113         data: %{
1114           "to" => [
1115             "https://www.w3.org/ns/activitystreams#Public",
1116             User.ap_followers(user)
1117           ]
1118         },
1119         user: user
1120       })
1121
1122     insert(:note_activity, %{
1123       note: obj,
1124       recipients: [
1125         "https://www.w3.org/ns/activitystreams#Public",
1126         User.ap_followers(user)
1127       ],
1128       user: user,
1129       local: false
1130     })
1131   end
1132
1133   defp create_with_media_activity(user) do
1134     obj = insert(:attachment_note, user: user)
1135
1136     insert(:note_activity, %{
1137       note: obj,
1138       recipients: ["https://www.w3.org/ns/activitystreams#Public", User.ap_followers(user)],
1139       user: user
1140     })
1141   end
1142 end