git.squeep.com Git - akkoma/blob - test/pleroma/web/mastodon_api/controllers/instance_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.InstanceControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.User
   9   import Pleroma.Factory
  10
  11   test "get instance information", %{conn: conn} do
  12     conn = get(conn, "/api/v1/instance")
  13     assert result = json_response_and_validate_schema(conn, 200)
  14
  15     email = Pleroma.Config.get([:instance, :email])
  16     # Note: not checking for "max_toot_chars" since it's optional
  17     assert %{
  18              "uri" => _,
  19              "title" => _,
  20              "description" => _,
  21              "version" => _,
  22              "email" => from_config_email,
  23              "urls" => %{
  24                "streaming_api" => _
  25              },
  26              "stats" => _,
  27              "thumbnail" => _,
  28              "languages" => _,
  29              "registrations" => _,
  30              "approval_required" => _,
  31              "poll_limits" => _,
  32              "upload_limit" => _,
  33              "avatar_upload_limit" => _,
  34              "background_upload_limit" => _,
  35              "banner_upload_limit" => _,
  36              "background_image" => _,
  37              "chat_limit" => _,
  38              "description_limit" => _
  39            } = result
  40
  41     assert result["pleroma"]["metadata"]["account_activation_required"] != nil
  42     assert result["pleroma"]["metadata"]["features"]
  43     assert result["pleroma"]["metadata"]["federation"]
  44     assert result["pleroma"]["metadata"]["fields_limits"]
  45     assert result["pleroma"]["vapid_public_key"]
  46
  47     assert email == from_config_email
  48   end
  49
  50   test "get instance stats", %{conn: conn} do
  51     user = insert(:user, %{local: true})
  52
  53     user2 = insert(:user, %{local: true})
  54     {:ok, _user2} = User.deactivate(user2, !user2.deactivated)
  55
  56     insert(:user, %{local: false, nickname: "u@peer1.com"})
  57     insert(:user, %{local: false, nickname: "u@peer2.com"})
  58
  59     {:ok, _} = Pleroma.Web.CommonAPI.post(user, %{status: "cofe"})
  60
  61     Pleroma.Stats.force_update()
  62
  63     conn = get(conn, "/api/v1/instance")
  64
  65     assert result = json_response_and_validate_schema(conn, 200)
  66
  67     stats = result["stats"]
  68
  69     assert stats
  70     assert stats["user_count"] == 1
  71     assert stats["status_count"] == 1
  72     assert stats["domain_count"] == 2
  73   end
  74
  75   test "get peers", %{conn: conn} do
  76     insert(:user, %{local: false, nickname: "u@peer1.com"})
  77     insert(:user, %{local: false, nickname: "u@peer2.com"})
  78
  79     Pleroma.Stats.force_update()
  80
  81     conn = get(conn, "/api/v1/instance/peers")
  82
  83     assert result = json_response_and_validate_schema(conn, 200)
  84
  85     assert ["peer1.com", "peer2.com"] == Enum.sort(result)
  86   end
  87 end