git.squeep.com Git - akkoma/blob - test/pleroma/web/mastodon_api/controllers/conversation_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.ConversationControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI
  11
  12   import Pleroma.Factory
  13
  14   setup do: oauth_access(["read:statuses"])
  15
  16   describe "returns a list of conversations" do
  17     setup(%{user: user_one, conn: conn}) do
  18       user_two = insert(:user)
  19       user_three = insert(:user)
  20
  21       {:ok, user_two} = User.follow(user_two, user_one)
  22
  23       {:ok, %{user: user_one, user_two: user_two, user_three: user_three, conn: conn}}
  24     end
  25
  26     test "returns correct conversations", %{
  27       user: user_one,
  28       user_two: user_two,
  29       user_three: user_three,
  30       conn: conn
  31     } do
  32       assert Participation.unread_count(user_two) == 0
  33       {:ok, direct} = create_direct_message(user_one, [user_two, user_three])
  34
  35       assert Participation.unread_count(user_two) == 1
  36
  37       {:ok, _follower_only} =
  38         CommonAPI.post(user_one, %{
  39           status: "Hi @#{user_two.nickname}!",
  40           visibility: "private"
  41         })
  42
  43       res_conn = get(conn, "/api/v1/conversations")
  44
  45       assert response = json_response_and_validate_schema(res_conn, 200)
  46
  47       assert [
  48                %{
  49                  "id" => res_id,
  50                  "accounts" => res_accounts,
  51                  "last_status" => res_last_status,
  52                  "unread" => unread
  53                }
  54              ] = response
  55
  56       account_ids = Enum.map(res_accounts, & &1["id"])
  57       assert length(res_accounts) == 2
  58       assert user_two.id in account_ids
  59       assert user_three.id in account_ids
  60       assert is_binary(res_id)
  61       assert unread == false
  62       assert res_last_status["id"] == direct.id
  63       assert Participation.unread_count(user_one) == 0
  64     end
  65
  66     test "observes limit params", %{
  67       user: user_one,
  68       user_two: user_two,
  69       user_three: user_three,
  70       conn: conn
  71     } do
  72       {:ok, _} = create_direct_message(user_one, [user_two, user_three])
  73       {:ok, _} = create_direct_message(user_two, [user_one, user_three])
  74       {:ok, _} = create_direct_message(user_three, [user_two, user_one])
  75
  76       res_conn = get(conn, "/api/v1/conversations?limit=1")
  77
  78       assert response = json_response_and_validate_schema(res_conn, 200)
  79
  80       assert Enum.count(response) == 1
  81
  82       res_conn = get(conn, "/api/v1/conversations?limit=2")
  83
  84       assert response = json_response_and_validate_schema(res_conn, 200)
  85
  86       assert Enum.count(response) == 2
  87     end
  88   end
  89
  90   test "filters conversations by recipients", %{user: user_one, conn: conn} do
  91     user_two = insert(:user)
  92     user_three = insert(:user)
  93     {:ok, direct1} = create_direct_message(user_one, [user_two])
  94     {:ok, _direct2} = create_direct_message(user_one, [user_three])
  95     {:ok, direct3} = create_direct_message(user_one, [user_two, user_three])
  96     {:ok, _direct4} = create_direct_message(user_two, [user_three])
  97     {:ok, direct5} = create_direct_message(user_two, [user_one])
  98
  99     assert [conversation1, conversation2] =
 100              conn
 101              |> get("/api/v1/conversations?recipients[]=#{user_two.id}")
 102              |> json_response_and_validate_schema(200)
 103
 104     assert conversation1["last_status"]["id"] == direct5.id
 105     assert conversation2["last_status"]["id"] == direct1.id
 106
 107     [conversation1] =
 108       conn
 109       |> get("/api/v1/conversations?recipients[]=#{user_two.id}&recipients[]=#{user_three.id}")
 110       |> json_response_and_validate_schema(200)
 111
 112     assert conversation1["last_status"]["id"] == direct3.id
 113   end
 114
 115   test "updates the last_status on reply", %{user: user_one, conn: conn} do
 116     user_two = insert(:user)
 117     {:ok, direct} = create_direct_message(user_one, [user_two])
 118
 119     {:ok, direct_reply} =
 120       CommonAPI.post(user_two, %{
 121         status: "reply",
 122         visibility: "direct",
 123         in_reply_to_status_id: direct.id
 124       })
 125
 126     [%{"last_status" => res_last_status}] =
 127       conn
 128       |> get("/api/v1/conversations")
 129       |> json_response_and_validate_schema(200)
 130
 131     assert res_last_status["id"] == direct_reply.id
 132   end
 133
 134   test "the user marks a conversation as read", %{user: user_one, conn: conn} do
 135     user_two = insert(:user)
 136     {:ok, direct} = create_direct_message(user_one, [user_two])
 137
 138     assert Participation.unread_count(user_one) == 0
 139     assert Participation.unread_count(user_two) == 1
 140
 141     user_two_conn =
 142       build_conn()
 143       |> assign(:user, user_two)
 144       |> assign(
 145         :token,
 146         insert(:oauth_token, user: user_two, scopes: ["read:statuses", "write:conversations"])
 147       )
 148
 149     [%{"id" => direct_conversation_id, "unread" => true}] =
 150       user_two_conn
 151       |> get("/api/v1/conversations")
 152       |> json_response_and_validate_schema(200)
 153
 154     %{"unread" => false} =
 155       user_two_conn
 156       |> post("/api/v1/conversations/#{direct_conversation_id}/read")
 157       |> json_response_and_validate_schema(200)
 158
 159     assert Participation.unread_count(user_one) == 0
 160     assert Participation.unread_count(user_two) == 0
 161
 162     # The conversation is marked as unread on reply
 163     {:ok, _} =
 164       CommonAPI.post(user_two, %{
 165         status: "reply",
 166         visibility: "direct",
 167         in_reply_to_status_id: direct.id
 168       })
 169
 170     [%{"unread" => true}] =
 171       conn
 172       |> get("/api/v1/conversations")
 173       |> json_response_and_validate_schema(200)
 174
 175     assert Participation.unread_count(user_one) == 1
 176     assert Participation.unread_count(user_two) == 0
 177
 178     # A reply doesn't increment the user's unread_conversation_count if the conversation is unread
 179     {:ok, _} =
 180       CommonAPI.post(user_two, %{
 181         status: "reply",
 182         visibility: "direct",
 183         in_reply_to_status_id: direct.id
 184       })
 185
 186     assert Participation.unread_count(user_one) == 1
 187     assert Participation.unread_count(user_two) == 0
 188   end
 189
 190   test "(vanilla) Mastodon frontend behaviour", %{user: user_one, conn: conn} do
 191     user_two = insert(:user)
 192     {:ok, direct} = create_direct_message(user_one, [user_two])
 193
 194     res_conn = get(conn, "/api/v1/statuses/#{direct.id}/context")
 195
 196     assert %{"ancestors" => [], "descendants" => []} == json_response(res_conn, 200)
 197   end
 198
 199   defp create_direct_message(sender, recips) do
 200     hellos =
 201       recips
 202       |> Enum.map(fn s -> "@#{s.nickname}" end)
 203       |> Enum.join(", ")
 204
 205     CommonAPI.post(sender, %{
 206       status: "Hi #{hellos}!",
 207       visibility: "direct"
 208     })
 209   end
 210 end