git.squeep.com Git - akkoma/blob - test/pleroma/web/mastodon_api/controllers/conversation_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.ConversationControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI
  11
  12   import Pleroma.Factory
  13
  14   setup do: oauth_access(["read:statuses"])
  15
  16   describe "returns a list of conversations" do
  17     setup(%{user: user_one, conn: conn}) do
  18       user_two = insert(:user)
  19       user_three = insert(:user)
  20
  21       {:ok, user_two} = User.follow(user_two, user_one)
  22
  23       {:ok, %{user: user_one, user_two: user_two, user_three: user_three, conn: conn}}
  24     end
  25
  26     test "returns correct conversations", %{
  27       user: user_one,
  28       user_two: user_two,
  29       user_three: user_three,
  30       conn: conn
  31     } do
  32       assert Participation.unread_count(user_two) == 0
  33       {:ok, direct} = create_direct_message(user_one, [user_two, user_three])
  34
  35       assert Participation.unread_count(user_two) == 1
  36
  37       {:ok, _follower_only} =
  38         CommonAPI.post(user_one, %{
  39           status: "Hi @#{user_two.nickname}!",
  40           visibility: "private"
  41         })
  42
  43       res_conn = get(conn, "/api/v1/conversations")
  44
  45       assert response = json_response_and_validate_schema(res_conn, 200)
  46
  47       assert [
  48                %{
  49                  "id" => res_id,
  50                  "accounts" => res_accounts,
  51                  "last_status" => res_last_status,
  52                  "unread" => unread
  53                }
  54              ] = response
  55
  56       account_ids = Enum.map(res_accounts, & &1["id"])
  57       assert length(res_accounts) == 2
  58       assert user_one.id not in account_ids
  59       assert user_two.id in account_ids
  60       assert user_three.id in account_ids
  61       assert is_binary(res_id)
  62       assert unread == false
  63       assert res_last_status["id"] == direct.id
  64       assert res_last_status["account"]["id"] == user_one.id
  65       assert Participation.unread_count(user_one) == 0
  66     end
  67
  68     test "special behaviour when conversation have only one user", %{
  69       user: user_one,
  70       user_two: user_two,
  71       conn: conn
  72     } do
  73       {:ok, direct} = create_direct_message(user_one, [])
  74
  75       res_conn = get(conn, "/api/v1/conversations")
  76
  77       assert response = json_response_and_validate_schema(res_conn, 200)
  78       assert [
  79                %{
  80                  "accounts" => res_accounts,
  81                  "last_status" => res_last_status
  82                }
  83              ] = response
  84       assert length(res_accounts) == 1
  85       assert res_accounts[0]["id"] == user_one.id
  86     end
  87
  88     test "observes limit params", %{
  89       user: user_one,
  90       user_two: user_two,
  91       user_three: user_three,
  92       conn: conn
  93     } do
  94       {:ok, _} = create_direct_message(user_one, [user_two, user_three])
  95       {:ok, _} = create_direct_message(user_two, [user_one, user_three])
  96       {:ok, _} = create_direct_message(user_three, [user_two, user_one])
  97
  98       res_conn = get(conn, "/api/v1/conversations?limit=1")
  99
 100       assert response = json_response_and_validate_schema(res_conn, 200)
 101
 102       assert Enum.count(response) == 1
 103
 104       res_conn = get(conn, "/api/v1/conversations?limit=2")
 105
 106       assert response = json_response_and_validate_schema(res_conn, 200)
 107
 108       assert Enum.count(response) == 2
 109     end
 110   end
 111
 112   test "filters conversations by recipients", %{user: user_one, conn: conn} do
 113     user_two = insert(:user)
 114     user_three = insert(:user)
 115     {:ok, direct1} = create_direct_message(user_one, [user_two])
 116     {:ok, _direct2} = create_direct_message(user_one, [user_three])
 117     {:ok, direct3} = create_direct_message(user_one, [user_two, user_three])
 118     {:ok, _direct4} = create_direct_message(user_two, [user_three])
 119     {:ok, direct5} = create_direct_message(user_two, [user_one])
 120
 121     assert [conversation1, conversation2] =
 122              conn
 123              |> get("/api/v1/conversations?recipients[]=#{user_two.id}")
 124              |> json_response_and_validate_schema(200)
 125
 126     assert conversation1["last_status"]["id"] == direct5.id
 127     assert conversation2["last_status"]["id"] == direct1.id
 128
 129     [conversation1] =
 130       conn
 131       |> get("/api/v1/conversations?recipients[]=#{user_two.id}&recipients[]=#{user_three.id}")
 132       |> json_response_and_validate_schema(200)
 133
 134     assert conversation1["last_status"]["id"] == direct3.id
 135   end
 136
 137   test "updates the last_status on reply", %{user: user_one, conn: conn} do
 138     user_two = insert(:user)
 139     {:ok, direct} = create_direct_message(user_one, [user_two])
 140
 141     {:ok, direct_reply} =
 142       CommonAPI.post(user_two, %{
 143         status: "reply",
 144         visibility: "direct",
 145         in_reply_to_status_id: direct.id
 146       })
 147
 148     [%{"last_status" => res_last_status}] =
 149       conn
 150       |> get("/api/v1/conversations")
 151       |> json_response_and_validate_schema(200)
 152
 153     assert res_last_status["id"] == direct_reply.id
 154   end
 155
 156   test "the user marks a conversation as read", %{user: user_one, conn: conn} do
 157     user_two = insert(:user)
 158     {:ok, direct} = create_direct_message(user_one, [user_two])
 159
 160     assert Participation.unread_count(user_one) == 0
 161     assert Participation.unread_count(user_two) == 1
 162
 163     user_two_conn =
 164       build_conn()
 165       |> assign(:user, user_two)
 166       |> assign(
 167         :token,
 168         insert(:oauth_token, user: user_two, scopes: ["read:statuses", "write:conversations"])
 169       )
 170
 171     [%{"id" => direct_conversation_id, "unread" => true}] =
 172       user_two_conn
 173       |> get("/api/v1/conversations")
 174       |> json_response_and_validate_schema(200)
 175
 176     %{"unread" => false} =
 177       user_two_conn
 178       |> post("/api/v1/conversations/#{direct_conversation_id}/read")
 179       |> json_response_and_validate_schema(200)
 180
 181     assert Participation.unread_count(user_one) == 0
 182     assert Participation.unread_count(user_two) == 0
 183
 184     # The conversation is marked as unread on reply
 185     {:ok, _} =
 186       CommonAPI.post(user_two, %{
 187         status: "reply",
 188         visibility: "direct",
 189         in_reply_to_status_id: direct.id
 190       })
 191
 192     [%{"unread" => true}] =
 193       conn
 194       |> get("/api/v1/conversations")
 195       |> json_response_and_validate_schema(200)
 196
 197     assert Participation.unread_count(user_one) == 1
 198     assert Participation.unread_count(user_two) == 0
 199
 200     # A reply doesn't increment the user's unread_conversation_count if the conversation is unread
 201     {:ok, _} =
 202       CommonAPI.post(user_two, %{
 203         status: "reply",
 204         visibility: "direct",
 205         in_reply_to_status_id: direct.id
 206       })
 207
 208     assert Participation.unread_count(user_one) == 1
 209     assert Participation.unread_count(user_two) == 0
 210   end
 211
 212   test "(vanilla) Mastodon frontend behaviour", %{user: user_one, conn: conn} do
 213     user_two = insert(:user)
 214     {:ok, direct} = create_direct_message(user_one, [user_two])
 215
 216     res_conn = get(conn, "/api/v1/statuses/#{direct.id}/context")
 217
 218     assert %{"ancestors" => [], "descendants" => []} == json_response(res_conn, 200)
 219   end
 220
 221   defp create_direct_message(sender, recips) do
 222     hellos =
 223       recips
 224       |> Enum.map(fn s -> "@#{s.nickname}" end)
 225       |> Enum.join(", ")
 226
 227     CommonAPI.post(sender, %{
 228       status: "Hi #{hellos}!",
 229       visibility: "direct"
 230     })
 231   end
 232 end