git.squeep.com Git - akkoma/blob - test/pleroma/web/admin_api/controllers/instance_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.InstanceControllerTest do
   6   use Pleroma.Web.ConnCase
   7   use Oban.Testing, repo: Pleroma.Repo
   8
   9   import Pleroma.Factory
  10
  11   alias Pleroma.Repo
  12   alias Pleroma.Tests.ObanHelpers
  13   alias Pleroma.Web.CommonAPI
  14
  15   setup_all do
  16     Tesla.Mock.mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  17
  18     :ok
  19   end
  20
  21   setup do
  22     admin = insert(:user, is_admin: true)
  23     token = insert(:oauth_admin_token, user: admin)
  24
  25     conn =
  26       build_conn()
  27       |> assign(:user, admin)
  28       |> assign(:token, token)
  29
  30     {:ok, %{admin: admin, token: token, conn: conn}}
  31   end
  32
  33   test "GET /instances/:instance/statuses", %{conn: conn} do
  34     user = insert(:user, local: false, ap_id: "https://archae.me/users/archaeme")
  35     user2 = insert(:user, local: false, ap_id: "https://test.com/users/test")
  36     insert_pair(:note_activity, user: user)
  37     activity = insert(:note_activity, user: user2)
  38
  39     %{"total" => 2, "activities" => activities} =
  40       conn |> get("/api/pleroma/admin/instances/archae.me/statuses") |> json_response(200)
  41
  42     assert length(activities) == 2
  43
  44     %{"total" => 1, "activities" => [_]} =
  45       conn |> get("/api/pleroma/admin/instances/test.com/statuses") |> json_response(200)
  46
  47     %{"total" => 0, "activities" => []} =
  48       conn |> get("/api/pleroma/admin/instances/nonexistent.com/statuses") |> json_response(200)
  49
  50     CommonAPI.repeat(activity.id, user)
  51
  52     %{"total" => 2, "activities" => activities} =
  53       conn |> get("/api/pleroma/admin/instances/archae.me/statuses") |> json_response(200)
  54
  55     assert length(activities) == 2
  56
  57     %{"total" => 3, "activities" => activities} =
  58       conn
  59       |> get("/api/pleroma/admin/instances/archae.me/statuses?with_reblogs=true")
  60       |> json_response(200)
  61
  62     assert length(activities) == 3
  63   end
  64
  65   test "DELETE /instances/:instance", %{conn: conn} do
  66     user = insert(:user, nickname: "lain@lain.com")
  67     post = insert(:note_activity, user: user)
  68
  69     response =
  70       conn
  71       |> delete("/api/pleroma/admin/instances/lain.com")
  72       |> json_response(200)
  73
  74     [:ok] = ObanHelpers.perform_all()
  75
  76     assert response == "lain.com"
  77     refute Repo.reload(user).is_active
  78     refute Repo.reload(post)
  79   end
  80 end